Как добавить изображения в заполнитель изображения презентации Powerpoint?

Question

Я создал некоторый код в Excel VBA для создания слайда презентации PowerPoint по 1 для каждой строки Excel и заполнения определенного текстового поля в PowerPoint.
Теперь я хочу добавить все изображения, соответствующие описанию.Это все JPEG, а не диаграммы и т. д.
Как это сделать, и лучше ли это сделать в Excel, или лучше сделать это самому в Powerpoint VBA?
В любом случае, сможет ли кто-нибудь помочь мне с кодом, как это сделать, пожалуйста?
Рамки изображений уже существуют в PowerPoint.На слайде по 2 изображения (без переходов и прочего).
Спасибо!

P.S. Я использую PowerPoint и Excel 2010 в Windows 7.

---

Есть ли способ сделать это из Excel?Остальная часть моего кода находится в Excel, и было бы здорово сделать это как часть макроса.
По сути, у меня есть местоположение файла, который я хочу использовать, например.C:\insertfoldername\imagename.jpeg отображается в столбце H электронной таблицы (около 400 строк).
Шаблон Powepoint, который я использую, имеет рамку изображения (тот, который в Powerpoint, при наведении на него курсора, говорит: «Вставить изображение из файла»).
Они уже имеют размер и находятся в нужном месте.
Что я хочу сделать, так это в Excel вставить изображение из пути к файлу, который находится в Excel, и вставить его в этот конкретный фрейм изображения.
Это вообще будет возможно?

В основном что-то, что сделает это:
PPT.ActivePresentation.Slides(2).Shapes(3)LoadImage(spath)

Ниже приведен код, который я использую.
**** Указывает путь к файлу.файл jpg установлен в качестве третьего столбца в электронной таблице Excel.

Sub CreateSlides()
'Dim the Excel objects
Dim objWorkbook As New Excel.Workbook
Dim objWorksheet As Excel.Worksheet

'Dim the File Path String
Dim strFilePath As String

'Dim the PowerPoint objects
Dim PPT As Object
Dim pptSlide As PowerPoint.Slide
Dim pptLayout As PowerPoint.CustomLayout
Dim pptNewSlide As PowerPoint.Slide
Dim str As String
Dim Title As String

Set PPT = GetObject(, "PowerPoint.Application")

PPT.Visible = True

'Get the layout of the first slide and set a CustomLayout object
Set pptLayout = PPT.ActivePresentation.Slides(1).CustomLayout

'Run the OpenFile function to get an Open File dialog box. It returns a String containing the file and path.
strFilePath = OpenFile()

'Open the Excel file
Set objWorkbook = Excel.Application.Workbooks.Open(strFilePath)

'Grab the first Worksheet in the Workbook
Set objWorksheet = objWorkbook.Worksheets(1)

'Loop through each used row in Column A
For i = 2 To objWorksheet.Range("A65536").End(xlUp).Row

Set PPT = GetObject(, "PowerPoint.Application")

Set pptNewSlide = PPT.ActivePresentation.Slides.AddSlide(PPT.ActivePresentation.Slides.Count + 1, pptLayout)

 'Get the number of columns in use on the current row
    Dim LastCol As Long
    Dim boldWords As String

    boldWords = "Line1: ,line2: ,Line3: ,Line4: "
    LastCol = objWorksheet.Rows(i).End(xlToRight).Column
    If LastCol = 16384 Then LastCol = 1 'For some reason if only column 1 has data it returns 16384, so correct it

    'Build a string of all the columns on the row
    str = ""
    str = "Line1: " & str & objWorksheet.Cells(i, 1).Value & Chr(13) & _
    "Line2: " & objWorksheet.Cells(i, 2).Value & Chr(13) & _
    "Line3: " & objWorksheet.Cells(i, 10).Value & Chr(13) & _
    "Line4: " & objWorksheet.Cells(i, 7).Value & Chr(13) & Chr(13) & _
    objWorksheet.Cells(i, 14).Value

 sfile = Cells(i, 3) & ".jpg" **** This is the jpg name

Set PPT = GetObject(, "PowerPoint.Application")

spath = "C:\test\"

'Write the string to the slide
pptNewSlide.Shapes(2).TextFrame.TextRange.Text = objWorksheet.Cells(i, 3).Value 'This enters the film Title
PPT.ActivePresentation.Slides(PPT.ActivePresentation.Slides.Count).Shapes(1).TextFrame.TextRange.Text = str


BoldSomeWords PPT.ActivePresentation.Slides(PPT.ActivePresentation.Slides.Count).Shapes(1), str, boldWords

'This is where I want to load in the Image.
'PPT.ActivePresentation.Slides(PPT.ActivePresentation.Slides.Count).Shapes(3).Picture = LoadPicture(spath) ' & sfile)
'PPT.ActivePresentation.Slides(2).Shapes(3)LoadImage((spath))

Next
End Sub

---

Function OpenFile()
'Dim the File Dialog object and string
Dim objFileDialog As FileDialog
Dim strFile As String

'Set the objFileDialog to an instance of the FileDialog object
Set objFileDialog = Application.FileDialog(msoFileDialogFilePicker)

'Set the Properties of the objFileDialog object
objFileDialog.AllowMultiSelect = False
objFileDialog.ButtonName = "Select"
objFileDialog.InitialView = msoFileDialogViewDetails
objFileDialog.Title = "Select Excel File"
objFileDialog.InitialFileName = "C:\"
objFileDialog.Filters.Clear
objFileDialog.Filters.Add "Excel", "*.xls; *.xlsx", 1
objFileDialog.FilterIndex = 1

'Show the FileDialog box
objFileDialog.Show

'Set strFile to the first record of the SelectedItems property of our FileDialog
strFile = objFileDialog.SelectedItems(1)

'Return the File Path string
OpenFile = strFile
End Function

Answer 1

Вот как вы добавляете изображения в открытый в данный момент PPT. Picture PlaceHolders с помощью Excel.
Мы использовали Early Binding добавление Microsoft PowerPoint 14.0 Object Library ссылка.

Редактировать1: Добавление DoEvents и некоторые пояснения

Sub ImportPictureInPlaceHolderFromExcel()

    Dim oPPt As PowerPoint.Application
    Dim oPPtSlide As PowerPoint.Slide
    Dim oPPtShp As PowerPoint.Shape

    '~~> Get hold of PPt instance meaning your currently open PPT presentation
    Set oPPt = GetObject(, "Powerpoint.Application")
    '~~> Reference the first slide which should contain picture placeholders
    Set oPPtSlide = oPPt.ActivePresentation.Slides(1)

    '~~> Now check each shape in slide
    For Each oPPtShp In oPPtSlide.Shapes
        '~~> You only need to work on Picture place holders
        If oPPtShp.PlaceholderFormat.Type = ppPlaceholderPicture Then
            With oPPtShp
                '~~> Now add the Picture
                '~~> For this example, picture path is in Cell A1
                oPPtSlide.Shapes.AddPicture Range("A1").Value, msoFalse, msoTrue, _
                                .Left, .Top, .Width, .Height
                '~~> Insert DoEvents here specially for big files, or network files
                '~~> DoEvents halts macro momentarily until the 
                '~~> system finishes what it's doing which is loading the picture file
                DoEvents
            End With
        End If
    Next

    Set oPPtSlide = Nothing
    Set oPPt = Nothing

End Sub

Подводить итоги:
1.Мы получаем заявку PPT
2.Мы владеем слайдом и фигурами внутри слайда.
3.Теперь мы выбираем фигуры, которые ppPlaceholderPicture только тип
4.Мы используем Shape Object's(тип ppPlaceholderPicture) .Top, .Left, .Width and .Height собственность как аргумент в пользу Коллекция фигур .AddPicture метод.

И вот, вы добавили изображение в заполнитель изображения PPT.
Надеюсь, это то, что вам нужно.

Answer 2

Пока что выглядит как это работает, когда вы добавляете изображение на слайд с пустым изображением или содержимым заполнителем, он всегда будет вступить в этот заполнитель и изменять размер, чтобы соответствовать.

Вам просто нужно добавить его так:

osld.Shapes.AddPicture "Path", msoFalse, msoTrue, -1, -1

.