Как получить все вставленные строки за данный месяц с помощью T-Sql

Question

Я пытаюсь извлечь все строки, вставленные в течение определенного месяца.

SELECT 
    dbo.Post.UserId, 
    dbo.Post.Tags, 
    dbo.Post.CommentCount, 
    dbo.Post.Status,  
    dbo.Post.PostDate, 
    dbo.Post.[Content], 
    dbo.Post.Title, 
    dbo.Post.PostId, 
    dbo.[User].DisplayName 
FROM  
    dbo.Post INNER JOIN
    dbo.[User] ON dbo.Post.UserId = dbo.[User].UserId 
Where PostDate >=  DATEADD(mm, 0, DATEDIFF(mm, 0, '01/28/2009')) 
    AND  PostDate <=  DATEADD(mm, 0, DATEDIFF(mm, 0, '01/28/2009')) 

Есть какие-нибудь идеи?

Answer 1

 WHERE PostDate >=  DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), 0)
   AND PostDate <  DATEADD(mm, 1 + DATEDIFF(mm, 0, '01/28/2009'), 0)

Answer 2

Вы упоминаете "данный месяц", я предполагаю, что номер месяца от 1 до 12.Если вы начинаете с даты и просто хотите получить все, что попадает в этот месяц:

@month = datepart(mm, 'given date');
@year  = datepart(yy, 'given date');

Then use:

Where 
   datepart(mm, Post.Postdate) = @month
   and datepart(yy, Post.PostDate) = @year

вот так.

(Я добавил год на случай, если вас это волнует.:-))

Answer 3

Вы хотите создать начальный момент этого месяца и начальный момент следующего месяца, затем взять даты, начиная с начального момента и включая его, и до следующего начального момента, но не включая его.

То есть.результат должен быть эквивалентен:

Where PostDate >= '01/01/2009' and PostDate < '02/01/2009'

Таким образом, вы получите именно этот месяц и не будете накладываться на следующий месяц.

Выражение DATEDIFF(mm, 0, '2009-01-28') даст вам количество месяцев с 01/01/1900, поэтому вы должны использовать эту дату в качестве третьего параметра в DATEADD:

DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), '01/01/1900')

Чтобы получить начальный момент следующего месяца, вы просто используете '02/01/1900' как смещение.Давайте включим это в условие:

Where
  PostDate >= DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), '01/01/1900') and
  PostDate < DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), '02/01/1900')

Answer 4

Это сделает это.

Where PostDate >=  DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), 0) 
    AND  PostDate <  DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009') + 1, 0)

Кроме того, я обычно настраиваю свой диапазон дат перед запросом, поэтому мне не нужно помещать функции даты в предложение where.

declare @from datetime;
declare @thru datetime;

set @from = DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), 0);
set @thru = DATEADD(mm, 1, @from);

...
Where PostDate >=  @from 
        AND  PostDate <  @thru

Answer 5

@dtInput = '01/28/2009'

-- subtract current days (less one) to get to start of month
set @dtStart = dateadd( dd, 1 - datepart( dd, @dtInput ), @dtInput )

-- add a month, then subtract 1 sec to get 23:59:59 on last day of month
set @dtEnd = dateadd( ss, -1, dateadd( mm, 1, @dtStart ))

SELECT ... WHERE PostDate between @dtStart and @dtEnd