Как мне прочитать содержимое каталога в Perl?

Question

Как заставить Perl читать содержимое заданного каталога в массив?

обратные кавычки могу это сделать, но есть ли какой-нибудь метод, использующий «скандир» или аналогичный термин?

Answer 1

opendir(D, "/path/to/directory") || die "Can't open directory: $!\n";
while (my $f = readdir(D)) {
    print "\$f = $f\n";
}
closedir(D);

РЕДАКТИРОВАТЬ:Ой, извините, пропустил часть "в массив":

my $d = shift;

opendir(D, "$d") || die "Can't open directory $d: $!\n";
my @list = readdir(D);
closedir(D);

foreach my $f (@list) {
    print "\$f = $f\n";
}

РЕДАКТИРОВАТЬ2:Большинство других ответов действительны, но я хотел прокомментировать этот ответ конкретно, в котором предлагается это решение:

opendir(DIR, $somedir) || die "Can't open directory $somedir: $!";
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR);
closedir DIR;

Во-первых, чтобы задокументировать, что он делает, поскольку плакат этого не сделал:он передает возвращенный список из каталог чтения() через грэп() который возвращает только те значения, которые являются файлами (в отличие от каталогов, устройств, именованных каналов и т. д.) и которые не начинаются с точки (что делает имя списка @dots вводит в заблуждение, но это связано с изменением, которое он внес при копировании из документации readdir()).Поскольку он ограничивает содержимое возвращаемого каталога, я не думаю, что это технически правильный ответ на этот вопрос, но он иллюстрирует распространенную идиому, используемую для фильтрации имен файлов в Перл, и я подумал, что было бы полезно задокументировать.Другой часто встречающийся пример:

@list = grep !/^\.\.?$/, readdir(D);

Этот фрагмент считывает все содержимое из дескриптора каталога D. кроме '.' и «..», так как они очень редко желают использовать в списке.

Answer 2

Быстрое и грязное решение — использовать шарик

@files = glob ('/path/to/dir/*');

Answer 3

IO::Дир хорош и также предоставляет связанный хеш-интерфейс.

Из перлдока:

use IO::Dir;
$d = IO::Dir->new(".");
if (defined $d) {
    while (defined($_ = $d->read)) { something($_); }
    $d->rewind;
    while (defined($_ = $d->read)) { something_else($_); }
    undef $d;
}

tie %dir, 'IO::Dir', ".";
foreach (keys %dir) {
    print $_, " " , $dir{$_}->size,"\n";
}

Итак, вы можете сделать что-то вроде:

tie %dir, 'IO::Dir', $directory_name;
my @dirs = keys %dir;

Answer 4

Это сделает это в одной строке (обратите внимание на подстановочный знак «*» в конце)

@files = </path/to/directory/*>;
# To demonstrate:
print join(", ", @files);

Answer 5

Вы могли бы использовать DirHandle:

use DirHandle;
$d = new DirHandle ".";
if (defined $d)
{
    while (defined($_ = $d->read)) { something($_); }
    $d->rewind;
    while (defined($_ = $d->read)) { something_else($_); }
    undef $d;
}

DirHandle предоставляет альтернативный, более чистый интерфейс для opendir(), closedir(), readdir(), и rewinddir() функции.

Answer 6

Вот пример рекурсивного обхода структуры каталогов и копирования файлов из написанного мной сценария резервного копирования.

sub copy_directory {
my ($source, $dest) = @_;
my $start = time;

# get the contents of the directory.
opendir(D, $source);
my @f = readdir(D);
closedir(D);

# recurse through the directory structure and copy files.
foreach my $file (@f) {
    # Setup the full path to the source and dest files.
    my $filename = $source . "\\" . $file;
    my $destfile = $dest . "\\" . $file;

    # get the file info for the 2 files.
    my $sourceInfo = stat( $filename );
    my $destInfo = stat( $destfile );

    # make sure the destinatin directory exists.
    mkdir( $dest, 0777 );

    if ($file eq '.' || $file eq '..') {
    } elsif (-d $filename) { # if it's a directory then recurse into it.
        #print "entering $filename\n";
        copy_directory($filename, $destfile); 
    } else { 
        # Only backup the file if it has been created/modified since the last backup 
        if( (not -e $destfile) || ($sourceInfo->mtime > $destInfo->mtime ) ) {
            #print $filename . " -> " . $destfile . "\n";
            copy( $filename, $destfile ) or print "Error copying $filename: $!\n";
        } 
    } 
}

print "$source copied in " . (time - $start) . " seconds.\n";       
}

Answer 7

Аналогично предыдущему, но я думаю, что лучшая версия (слегка измененная) из "perldoc -f readdir":

opendir(DIR, $somedir) || die "can't opendir $somedir: $!";
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR);
closedir DIR;

Answer 8

от: http://perlmeme.org/faqs/file_io/directory_listing.html

#!/usr/bin/perl
use strict;
use warnings;

my $directory = '/tmp';

opendir (DIR, $directory) or die $!;

while (my $file = readdir(DIR)) {
    next if ($file =~ m/^\./);
    print "$file\n";
}

В следующем примере (основанном на примере кода из perldoc -f readdir) все файлы (не каталоги), начинающиеся с точки, получаются из открытого каталога.Имена файлов находятся в массиве @dots.

#!/usr/bin/perl

use strict;
use warnings;

my $dir = '/tmp';

opendir(DIR, $dir) or die $!;

my @dots 
    = grep { 
        /^\./             # Begins with a period
    && -f "$dir/$_"   # and is a file
} readdir(DIR);

# Loop through the array printing out the filenames
foreach my $file (@dots) {
    print "$file\n";
}

closedir(DIR);
exit 0;


closedir(DIR);
exit 0;