Как я могу сохранить только первые пять строк в скаляре Perl?

Question

Из любого вида скаляра, какое регулярное выражение я мог бы использовать, чтобы сопоставить первые пять его строк и отбросить остальные?

Answer 1

Странный запрос, но это должно сработать:

#!/usr/bin/perl

use strict;
use warnings;

my $s = join '', map { "$_\n" } 1 .. 9;

my ($first) = $s =~ /^((?:.*\n){0,5})/;
my ($last) = $s =~ /((?:.*\n){0,5})$/;


print "first:\n${first}last:\n$last";

Более распространенным решением было бы что-то вроде этого:

#!/usr/bn/perl

use strict;
use warnings;

#fake a file for the example    
my $s = join '', map { "$_\n" } 1 .. 9;    
open my $fh, "<", \$s
    or die "could not open in memory file: $!";

my @first;
while (my $line = <$fh>) {
    push @first, $line;
    last if $. == 5;
}

#rewind the file just in case the file has fewer than 10 lines
seek $fh, 0, 0;

my @last;
while (my $line = <$fh>) {
    push @last, $line;
    #remove the earliest line if we have to many
    shift @last if @last == 6;
}

print "first:\n", @first, "last:\n", @last;

Answer 2

Почему бы тебе просто не использовать head за это?

Answer 3

Вам не нужно регулярное выражение.Просто откройте дескриптор файла по ссылке на скаляр, затем выполните те же действия, что и для любого другого типа дескриптора файла:

my $scalar = ...;

open my($fh), "<", \ $scalar or die "Could not open filehandle: $!";
foreach ( 1 .. 5 )
    {
    push @lines, scalar <$fh>;
    }
close $fh;

$scalar = join '', @lines;

Answer 4

my ($first_five) = $s =~ /\A((?:.*\n){5})/;
my ($last_five) = $s =~ /((?:.*\n){5})\z/;

Answer 5

Как говорит Брайан, вы можете использовать head или tail довольно легко для любой проблемы (первые 5 строк или последние 5 строк).

Но теперь мне интересно, правильно ли я вообще понял ваш вопрос.Когда вы говорите "для любого вида скаляра", вы имеете в виду, что (по какой-либо причине) файл уже находится в скаляре?

Если нет, я думаю, что лучшим решением будет вообще не использовать регулярные выражения.Использование $. и либо прочитайте файл обычным способом, либо в обратном направлении.Чтобы читать задом наперед, вы можете попробовать File::ReadBackwards или File::Bidirectional.

Answer 6

Людям не хватает некоторых ключевых флагов:

/(?m)((?:^.*\n?){1,5})/

Без флага многострочности он будет смотреть только на первую строку.Также путем создания \n по желанию, мы можем взять первые пять линии, независимо от перевода строки в конце пятой.

Answer 7

Почему бы просто не использовать split с ограничением, он предназначен для этой цели:

my @lines = (split /\n/, $scalar, 6)[0..4];

Если вы хотите получить это обратно в виде одного скаляра с пятью линиями, соедините его обратно:

my $scalar = join('\n', @lines) . "\n";

Answer 8

use strict;


my $line; #Store line currently being read
my $count=$ARGV[1]; # How many lines to read as passed from command line
my @last; #Array to store last count lines
my $index; #Index of the line being stored


#Open the file to read as supplied from command line
open (FILE,$ARGV[0]);
while ($line=<FILE>)
{
    $index=$.%$count;  # would help me in filter just $count records of the file
    $last[$index]=$line; #store this value
}
close (FILE);

#Output the stored lines
for (my $i=$index+1;$i<$count;$i++)
{
    print ("$last[$i]");
}
for (my $i=$0;$i<=$index;$i++)
{
    print ("$last[$i]");
}