Как применить буквенно-цифровую сортировку в XSLT

Question

Основываясь на следующем XML, каков наилучший способ добиться буквенно-цифровой сортировки в XSL?

Редактировать:чтобы пояснить, приведенный ниже XML - это всего лишь простой образец, реальный XML содержал бы гораздо больше значений variant.

<colors>
  <item>
    <label>Yellow 100</label>
  </item>
  <item>
    <label>Blue 12</label>
  </item>
  <item>
    <label>Orange 3</label>
  </item>
  <item>
    <label>Yellow 10</label>
  </item>
  <item>
    <label>Orange 26</label>
  </item>
  <item>
    <label>Blue 117</label>
  </item>
</colors>

Например.Я хочу получить окончательный результат в таком порядке:

Blue 12, Blue 117, Orange 3, Orange 26, Yellow 10, Yellow 100

Это "эффективно" чего бы я хотел.

<xsl:apply-templates select="colors/item">
  <xsl:sort select="label" data-type="text" order="ascending"/><!--1st sort-->
  <xsl:sort select="label" data-type="number" order="ascending"/><!--2nd sort-->
</xsl:apply-templates>   

<xsl:template match="item">
  <xsl:value-of select="label"/>
  <xsl:if test="position() != last()">,</xsl:if>
</xsl:template>

Answer 1

Разделение текста метки на текстовую и числовую части с помощью substring-before и substring-after будет сделано в вашем примере (однако, это не общий подход, но вы поняли идею):

<xsl:template match="/">
    <xsl:apply-templates select="colors/item">
      <xsl:sort select="substring-before(label, ' ')" data-type="text" order="ascending"/>
      <!--1st sort-->
      <xsl:sort select="substring-after(label, ' ')" data-type="number" order="ascending"/>
      <!--2nd sort-->
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="item">
    <xsl:value-of select="label"/>
    <xsl:if test="position() != last()">, </xsl:if>
  </xsl:template>

Это дает следующий результат:

Blue 12, Blue 117, Orange 3, Orange 26, Yellow 10, Yellow 100

---

Обновить

Более общим способом решения вашей проблемы сортировки было бы иметь select атрибут xls:sort элемент содержит строку, которая может быть отсортирована в соответствии с ожидаемыми вами правилами сортировки.Например.в этой строке все числа могут быть дополнены начальными 0, чтобы лексикографически сортировать их как data-type="text" приведет к правильному алфавитно-цифровому порядку.

Если вы используете движок XSLT .NET, вы могли бы использовать простую функцию расширения в C #, чтобы дополнять числа начальными 0:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:myExt="urn:myExtension"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"
                exclude-result-prefixes="msxsl myExt">
  <xsl:output method="xml" indent="yes" />

  <msxsl:script language="C#" implements-prefix="myExt">

    <![CDATA[
        private static string PadMatch(Match match)
        {
            // pad numbers with zeros to a maximum length of the largest int value 
            int maxLength = int.MaxValue.ToString().Length;
            return match.Value.PadLeft(maxLength, '0');
        }

        public string padNumbers(string text)
        {
            return System.Text.RegularExpressions.Regex.Replace(text, "[0-9]+", new System.Text.RegularExpressions.MatchEvaluator(PadMatch));
        }
    ]]>

  </msxsl:script>
  <xsl:template match="/">
    <sorted>
      <xsl:apply-templates select="colors/item">
        <xsl:sort select="myExt:padNumbers(label)" data-type="text" order="ascending"/>
      </xsl:apply-templates>
    </sorted>
  </xsl:template>

  <xsl:template match="item">
    <xsl:value-of select="label"/>
    <xsl:if test="position() != last()">, </xsl:if>
  </xsl:template>

</xsl:stylesheet>