Как я могу создавать каталоги во время копирования в bash / zsh / ksh?

Question

Я часто получаю следующие сообщения, например, при переносе файлов разработчика в главную ветку

cp: /Users/Masi/gitHub/shells/zsh/dvorak: No such file or directory
cp: /Users/Masi/gitHub/shells/zsh/dvorak2: No such file or directory

Я хотел бы, чтобы меня спросили о создании данных папок таким образом, чтобы моя начальная команда была запущена, если я отвечу утвердительно на вопрос (ы).

Моя попытка в псевдокоде, когда я пытаюсь скопировать файл в каталог, который не существует

if no such a directory exists, then asks users about to create it:
   if yes, then mkdir directory AND run the initial command again
   else do noting

Проблемы

1. Чтобы изменить предупреждающее сообщение: Какой файл управляет командой "Такого файла или каталога нет"?
2. Чтобы очистить Путь в начальной команде И путь mkidr без файла:Как бы очистить Путь в начальной команде?
3. Чтобы очистить текст с конца с помощью выбранного вами языка, такого как AWK: Как бы вы удалили последнее совпадение в Пути, когда / является разделителем полей? Я не уверен, как вы можете очищать буквы, начинающиеся с конца, с помощью AWK.

Answer 1

Вот функция, которую я написал, которая будет работать в zsh, bash или ksh.

Примечание: У него включена отладка (он повторяет команды, которые он будет запускать, а не выполняет их).Если вы закомментируете эту строку, она действительно запустит их.

Осторожно: Это не было тщательно протестировано.

Чтобы использовать его, поместите этот скрипт в файл под названием cpmd в /usr/local/bin (или в другом месте на вашем пути).Чтобы активировать его, в командной строке введите следующую команду (или добавьте ее в свой сценарий запуска - для bash это было бы ~/.bashrc):

source cpmd

Затем вы можете скопировать файл, используя команду, подобную этой:

cpmd carparts /home/dave/Documents/nonexistent/newdir/

Ни каталога "nonexistent", ни "newdir" пока не существует.Создаются оба каталога, после чего файл с именем "carparts" копируется в "newdir".

Если вы не добавляете косую черту ("/") в конце, последняя часть обрабатывается как имя файла и создаются все несуществующие каталоги до этого:

cpmd supplies /home/dave/Documents/anothernew/consumables

Создается каталог "anothernew", затем копируется "расходные материалы" с новым именем файла "consumers".

Если все каталоги в пункте назначения уже существуют, cpmd ведет себя как обычный cp команда.

function cpmd {
    # copies files and makes intermediate dest. directories if they don't exist
    # for bash, ksh or zsh
    # by Dennis Williamson - 2009-06-14
    # http://stackoverflow.com/questions/993266/unable-to-make-nosuchdirectory-message-useful-in-zsh

    # WARNING: no validation is performed on $1 and $2

    # all cp commands below are hardcoded with -i (interactive) to prevent overwriting

   if [[ -n $KSH_VERSION ]]
   then
       alias local=typeset
       local func="$0"
       local lastchar="${2: -1}"
       readcmd () { read "$2?$1"; }
    elif [[ -n $ZSH_VERSION ]]
    then
        local func="$0"
        # the following two lines are split up instead of doing "${2[-1]}"
        # to keep ksh from complaining when the function is loaded
        local dest="$2"
        local lastchar="${dest[-1]}"
        readcmd () { read "$2?$1"; }
    elif [[ -n $BASH_VERSION ]]
    then
    local func="$FUNCNAME"
        local lastchar="${2:(-1)}"
        readcmd () { read -p "$1" $2; }
    else
        echo "cpmd has only been tested in bash, ksh and zsh." >&2
        return 1
    fi

    local DEBUG='echo' # COMMENT THIS OUT to make this function actually work

    if [[ ${#@} != 2 ]]
    then
        echo "$func: invalid number of parameters
Usage:
  $func source destination

  where 'destination' can include nonexistent directories (which will
  be created). You must end 'destination' with a / in order for it to
  specify only directories. Without the final slash, the 'source' will
  be copied with a new name (the last portion of 'destination'). If you
  are copying multiple files and 'destination' is not a directory, the
  copy will fail." >&2
        return 1
    fi

    local dir=$(dirname "$2")
    local response
    local nl=$'\n'

    # destination ($2) is presumed to be in one of the following formats:
    # .../existdir              test 1  (-d "$2")
    # .../existdir/existfile    test 2  (-f "$2")
    # .../existdir/newfile      test 3  (-d "$dir" && $lastchar != '/')
    # .../existdir/newdir/      (else)
    # .../newdir/newdir/        (else)
    # .../newdir/newfile        (else)

    if [[ -d "$2" || -f "$2" || (-d "$dir" && $lastchar != '/') ]]
    then
        $DEBUG cp -i "$1" "$2"
    else
        if [[ $lastchar == '/' ]]
        then
            dir="$2"
        fi
        local prompt="$func: The destination directory...${nl}  ${dir}${nl}...does not exist. Create? (y/n): "
        while [[ -z $response ]]
        do
            readcmd "$prompt" response
            case $response in
                y|Y) response="Y" ;;
                n|N) ;;
                *) response=
                   prompt="$func: Invalid response.${nl}  Create destination directory? (y/n): ";;
            esac
        done
        if [[ $response == "Y" ]]
        then
            $DEBUG mkdir -p "$dir" && $DEBUG cp -i "$1" "$2"
        else
            echo "$func: Cancelled." >&2
        fi
    fi
}

Answer 2

Это сообщение об ошибке поступает от cp команда, а не zsh.Если вы хотите улучшить результат, вам придется написать логику для усечения и изучения пути вместе с проверкой, существует ли он или нет.

Есть команды, которые помогут в этом, взгляните на basename(1) и dirname(1).