Создание пакетного файла для резервного копирования указанной папки
-
16-09-2019 - |
Вопрос
На самом деле я довольно новичок в этой штуке с пакетными файлами.Я знаю, что важно знать хотя бы основные команды.Как мне сделать следующее?
- Архивирование указанной папки.
- Переместите папку в другое место.
- При архивировании именем ZIP-файла будет текущая дата и если существует другой архивированный файл с таким же именем, он должен называться 20090924-2.
PS: 7-Застежка-молния установлено на моем компьютере в качестве архивного программного обеспечения.
Решение
Пакетный скрипт, приведенный ниже, сделает это (я его протестировал и он работает в соответствии со спецификациями).Каталог, который нужно заархивировать и переместить, указан как его родительский каталог и имя каталога (PARENT_FOLDERTOZIP и FOLDERTOZIP в начале) - я не смог понять, как скопировать весь каталоги (я думаю, XCOPY может копировать только содержимое каталогов и подкаталогов.).Местоположение копии указано как FOLDERTARGETLOCATION, а каталог для размещения сжатые файлы указаны как ZIPDIR.
Расположение 7-Zip настраивается через SEVENZIP_EXE.
Обратите также внимание, что получение текущей даты в требуемом формате зависит от формата короткой даты в региональных настройках .Я перечислил три разные версии для ISO-8601 для стран Центральной Европы и США.Активный в списке предназначен для США.(строка "set FDATE=").Если требуется другой, то просто скопируйте и вставьте из одного из двух других.
Тем не менее, следует отметить, что такого рода вещи намного проще с Perl - язык программирования, Питон или PowerShell.
@echo off
@title=Folder zip and move...
rem Parameters
rem Folder to zip and move
set PARENT_FOLDERTOZIP=T:\to delete
set FOLDERTOZIP=Folder to Compress
rem Target folder for moving the input folder to.
set FOLDERTARGETLOCATION=s:\move Here
rem Where to place compressed folders
set ZIPDIR=D:\toDelete\2009-09-24a
rem Configuration
set SEVENZIP_EXE=D:\Program Files\7-Zip\7z.exe
rem =================== Date ==============================================
rem There is no universal way inside batch itself to get a
rem date that is independent of regional settings (but is
rem quite trivial if an external program or script
rem (Perl/Python) is available).
rem
rem For short date formats:
rem
rem -------------------------------------------------------
rem
rem ISO-8601:
rem 0123456789
rem yyyy-MM-dd/ E.g.: 2009-09-24
rem
rem set FDATE=%DATE:~0,4%%DATE:~5,2%%DATE:~8,2%
rem
rem -------------------------------------------------------
rem
rem Central european:
rem 0123456789
rem dd/MM/yyyy E.g.: 24/09/2009
rem
rem set FDATE=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
rem
rem -------------------------------------------------------
rem
rem US:
rem
rem 0123456789
rem MM/dd/yyyy E.g.: 09/24/2009
rem
rem set FDATE=%DATE:~6,4%%DATE:~0,2%%DATE:~3,2%
set FDATE=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
set ZIPFILE=%ZIPDIR%\%FDATE%.7z
set FOLDERTOZIP_FULLPATH=%PARENT_FOLDERTOZIP%\%FOLDERTOZIP%
mkdir %FOLDERTARGETLOCATION%
rem Does a zip file already exist?
if exist "%ZIPFILE%" GOTO L_ZIPFILE_EXISTS
GOTO L_ZIPFILENAME_OK
rem Find a compressed file that does not already exist.
:L_ZIPFILE_EXISTS
set RNUM=0
:L_TRYANOTHER
set /a RNUM=%RNUM% + 1
set ZIPFILE=%ZIPDIR%\%FDATE%-%RNUM%.7z
echo Candidate: %ZIPFILE% ...
if exist "%ZIPFILE%" GOTO L_TRYANOTHER
rem Zip the folder!
:L_ZIPFILENAME_OK
"%SEVENZIP_EXE%" a %ZIPFILE% "%FOLDERTOZIP_FULLPATH%"
if exist "%ZIPFILE%" GOTO L_OKZIP
GOTO L_ERROREND
:L_OKZIP
rem Move folder: copy, then delete source.
set DEST_FOLDER=%FOLDERTARGETLOCATION%\%FOLDERTOZIP%
mkdir "%DEST_FOLDER%"
xcopy /Y /S "%FOLDERTOZIP_FULLPATH%"\*.* "%DEST_FOLDER%"\
rmdir /S "%FOLDERTOZIP_FULLPATH%"
GOTO L_END
:L_ERROREND
echo 7-Zipping failed !!!
:L_END
pause