Использование одного ключа для Flymake и Flyspell

Question

Я использую Flymake с pyflakes для проверки кода Python и Flyspell для проверки строк и комментариев.Я хочу иметь одну функцию, которая будет переходить к следующей ошибке или отображать информацию об ошибке, если в данный момент произошла ошибка.Как бы мне написать эту функцию?

Answer 1

Этот код обеспечивает функциональность, которая перенаправляет вас к следующей ошибке, и если это ошибка Flymake, отображает информацию о ней, если это ошибка Flyspell, он исправляет ее за вас.Если вам не нужна автокоррекция, раскомментируйте строку, которая вызывает 'my-flyspell-message и удалите строку перед той, которая вызывает 'flyspell-auto-correct-word - и вы просто получите сообщение о том, что слово написано с ошибкой.

Первая строка связывает это с привязкой клавиш C-c н.Дополнительную информацию о привязке клавиш см. на информационной странице. Ключевые привязки.

(global-set-key (kbd "C-c n") 'my-display-error-or-next-error)
(defun my-display-error-or-next-error ()
  "display information for current error, or go to next one"
  (interactive)
  (when (or (not (my-at-flymake-error))
            (not (my-at-flyspell-error)))
    ;; jump to error if not at one
    (my-goto-next-error))

  (cond ((my-at-flymake-error)
         ;; if at flymake error, display menu
         (flymake-display-err-menu-for-current-line))
        ((my-at-flyspell-error)
         ;; if at flyspell error, fix it
         (call-interactively 'flyspell-auto-correct-word)
         ;; or, uncomment the next line to just get a message
         ;; (my-flyspell-message)
         )))

(defun my-at-flyspell-error ()
  "return non-nill if at flyspell error"
  (some 'flyspell-overlay-p (overlays-at (point))))

(defun my-at-flymake-error ()
  "return non-nil if at flymake error"
  (let* ((line-no             (flymake-current-line-no))
         (line-err-info-list  (nth 0 (flymake-find-err-info flymake-err-info line-no))))
    line-err-info-list))

(defun my-goto-next-error ()
  "jump to next flyspell or flymake error"
  (interactive)
  (let* ((p (point))
         (spell-next-error-function '(lambda ()
                                 (forward-word) (forward-char)
                                 (flyspell-goto-next-error)))
         (spell-pos (save-excursion
                      (funcall spell-next-error-function)
                      (point)))
         (make-pos (save-excursion
                     (flymake-goto-next-error)
                     (point))))
    (cond ((or (and (< p make-pos) (< p spell-pos))
               (and (> p make-pos) (> p spell-pos)))
           (funcall (if (< make-pos spell-pos)
                        'flymake-goto-next-error
                      spell-next-error-function)))
          ((< p make-pos)
           (flymake-goto-next-error))

          ((< p spell-pos)
           (funcall spell-next-error-function)))))

(defun my-flyspell-message ()
  (interactive)
  (let ((word (thing-at-point 'word)))
    (set-text-properties 0 (length word) nil word)
    (message "Missspelled word: %s" word)))