Выберите регистр для типа объекта в VB.NET.

Question

Я не уверен, что это допустимый C#, но, надеюсь, вы поняли идею.:)

switch (msg.GetType()) {
    case ClassA:
        // blah
    case ClassB:
        // blah 2
    case ClassC:
        // blah 3
}

Как мне включить тип объекта, но используя VB.NET? Select Case?

Я знаю, что некоторые могут предложить использовать полиморфизм, но я использую иерархию небольших классов сообщений, так что в моем случае это не сработает.

Answer 1

В VB 2010 для проектов, ориентированных на .NET Framework 4 и более поздних версий, вы можете сделать следующее:

Select Case msg.GetType()
    Case GetType(ClassA)
End Select

В более ранних версиях VB это не работало, поскольку нельзя было сравнивать два типа на равенство.Вам придется проверить, указывают ли они на одну и ту же ссылку, используя ключевое слово Is.Это невозможно сделать в случае выбора, если только вы не используете для сравнения свойство типа Name или FullName, как предложил Майкл.Однако вы можете использовать комбинацию If и ElseIf:

Dim type = msg.GetType()
If type Is GetType(ClassA)
    ...
ElseIf type Is GetType(ClassB)
    ...
...
End If

Answer 2

Что ж, если вы настаиваете на использовании Select Case, вы всегда можете использовать:

Select Case True
    Case TypeOf msg Is ClassA
        ' do something '
    Case TypeOf msg Is ClassB
        ' do something else '
    Case Else
        ' and so on '
End Select

Но я предполагаю, что большинству людей хотелось бы избегать подобных вещей.If/ElseIf, вероятно, было бы яснее.

Answer 3

Это способ обработки событий нажатия Button1 и Button2 в одном и том же подпрограмме (я начинал как программист VB6, поэтому это хорошая замена обработке массивов элементов управления в VB6).

Private Sub Button1_Click(ByVal sender As System.Object, _
ByVal e As System.EventArgs) Handles Button1.Click, Button2.Click
                Select Case True
                    Case sender Is Me.Button1
                        ' Do Button1 stuff '
                    Case sender Is Me.Button2
                        ' Do Button2 stuff '
                End Select
            End Sub

Answer 4

я бы никогда не select case true, но вы можете сделать это:

Select Case msg.GetType.Name
    Case GetType(ClassA).Name
        ...
    Case GetType(ClassB).Name
        ...
    Case Else
        ...
End Select

Это выглядит немного чище, чем это:

If msg.GetType Is GetType(ClassA) Then
    ...
ElseIf msg.GetType Is GetType(ClassB) Then
    ...
Else
    ...
End If

Answer 5

Этот:

Dim a As Object = New TextBox

Select Case True
    Case TypeOf a Is TextBox
        MsgBox("aaa")

    Case TypeOf a Is ComboBox

    Case TypeOf a Is ListBox

End Select