Получение текущего узла XSLT, отформатированного как запрос XPath?

Question

У меня есть следующий блок кода, который получает имена узлов вниз по дереву, вот так:

section/page/subPage

Но я хотел бы иметь возможность свести это к следующему (просто придумываю это):

section[@id='someId']/page/subPage[@user='UserA']/@title

Я нашел следующий код из одного из этих сообщений StackOverflow:

<xsl:attribute name="path">
  <xsl:for-each select="ancestor-or-self::*">
    <xsl:if test="name() != 'root'">
      <xsl:value-of select="name()">
        <xsl:if test="not(position()=last())">
          <xsl:text>/</xsl:text>
        </xsl:if>
      </xsl:value-of>
    </xsl:if>
  </xsl:for-each>
</xsl:attribute>

Это дает мне прямой путь, но я хотел бы применить к нему больше логики, чтобы сделать так, чтобы он включал @id (или соответствующий атрибут), и, возможно, еще кое-что, о чем я не могу думать в данный момент.

Каков наилучший способ сделать это?

Я проверил функции EXSLT, которые могут сработать, но, возможно, вы, ребята, уже решили эту проблему лучшим способом.

Есть какие-нибудь идеи?

Я использую nokogiri от ruby для синтаксического анализа xml / xslt, если это поможет.

Большое спасибо, Лэнс

Answer 1

Это решение делает то, что вы хотите:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="yes" />

  <xsl:template match="/">
    <root>
      <xsl:attribute name="path">
        <xsl:apply-templates select="(//@title)[1]" mode="make-path" />
      </xsl:attribute>
    </root>
  </xsl:template>

  <xsl:template match="*|@*" mode="make-path">
    <xsl:apply-templates select="parent::*" mode="make-path" />
    <xsl:text>/</xsl:text>
    <xsl:apply-templates select="." mode="make-name" />
    <xsl:choose>
      <xsl:when test="self::section">
        <xsl:apply-templates select="@id" mode="make-predicate" />
      </xsl:when>
      <xsl:when test="self::subPage">
        <xsl:apply-templates select="@user" mode="make-predicate" />
      </xsl:when>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="*|@*" mode="make-predicate">
    <xsl:text>[</xsl:text>
    <xsl:apply-templates select="." mode="make-name" />
    <xsl:text> = '</xsl:text>
    <xsl:value-of select="." />
    <xsl:text>']</xsl:text>
  </xsl:template>

  <xsl:template match="*" mode="make-name">
    <xsl:value-of select="name()" />
  </xsl:template>

  <xsl:template match="@*" mode="make-name">
    <xsl:text>@</xsl:text>
    <xsl:value-of select="name()" />
  </xsl:template>

</xsl:stylesheet>

При применении к

<section id="someId">
  <page>
    <subPage user="UserA" title="test" />
    <subPage user="UserB" title="blah" />
  </page>
  <page>
    <subPage user="UserC" title="fooh" />
  </page>
</section>

вы получаете:

<root path="/section[@id = 'someId']/page/subPage[@user = 'UserA']/@title" />

Тот Самый <xsl:choose> является настраиваемым местом (добавьте как можно больше <xsl:when>как вам будет угодно):

<!-- test for element name -->
<xsl:when test="self::section">
  <!-- make predicates out of selected attributes -->
  <xsl:apply-templates select="@id" mode="make-predicate" />
</xsl:when>

также возможно:

<xsl:when test="self::section">
  <xsl:apply-templates select="@name|@category|subElement" mode="make-predicate" />
</xsl:when>

что привело бы к

<root path="/section[@name = 'someName'][@category = 'somecat'][subElement = 'xyz']/..." />

Единственная проблема, которую я вижу, связана со значениями предикатов, которые содержат одинарные кавычки.Они нарушили бы XPath.

Answer 2

Для каждого узла-предка вы можете перебирать все атрибуты с помощью простого xsl:for-each

<xsl:for-each select="@*">

Затем вы могли бы использовать атрибуты для создания строки XPath

<xsl:for-each select="ancestor-or-self::*">
   <xsl:if test="name() != 'root'">
      <xsl:value-of select="name()"/>
      <xsl:if test="@*">
         <xsl:text>[</xsl:text>
         <xsl:for-each select="@*">
            <xsl:text>@</xsl:text>
            <xsl:value-of select="name()"/>
            <xsl:text>='</xsl:text>
            <xsl:value-of select="."/>
            <xsl:text>'</xsl:text>
            <xsl:if test="not(position()=last())">
               <xsl:text> and </xsl:text>
            </xsl:if>
         </xsl:for-each>
         <xsl:text>]</xsl:text>
      </xsl:if>
      <xsl:if test="not(position()=last())">
         <xsl:text>/</xsl:text>
      </xsl:if>
   </xsl:if>
</xsl:for-each>