Почему использование последовательности намного медленнее, чем использование списка в этом примере

Question

Фон: у меня есть последовательность смежных, сменных времени данных. В последовательности данных есть отверстия в нем, некоторые большие, другие, лишь единственное недостающее значение.
Всякий раз, когда отверстие является лишь единственным отсутствующим значением, я хочу исправить отверстия, используя фиктивное значение (более крупные отверстия будут проигнорированы).

Я хотел бы использовать ленивое поколение исправленной последовательности, и поэтому я использую seq.unfold.

Я сделал две версии метода для исправления отверстий в данных.

Первый потребляет последовательность данных с отверстиями в нем и производит исправленные последовательность. Анкет Это то, что я хочу, но методы работают ужасно медленным, когда количество элементов в входной последовательности возрастает выше 1000, и становится все хуже, чем больше элементов содержит входная последовательность.

Второй метод потребляет список данных с отверстиями и создает исправленную последовательность И он работает быстро. Однако это не то, что я хочу, поскольку это заставляет экземпляр всего входного списка в памяти.

Я хотел бы использовать метод (последовательность -> последовательность), а не метод (списка -> последовательность), чтобы избежать того, чтобы весь входной список в памяти одновременно.

Вопросы:

1) Почему первый метод настолько медленное (постепенно становится все хуже с большими списками ввода) (я подозреваю, что он связан с неоднократно созданием новых последовательностей с Seq.skip 1, но я не уверен)

2) Как я могу быстро исправить отверстия в данных при использовании ввода последовательность а не вход список?

Код:

open System

// Method 1 (Slow)
let insertDummyValuesWhereASingleValueIsMissing1 (timeBetweenContiguousValues : TimeSpan) (values : seq<(DateTime * float)>) =
    let sizeOfHolesToPatch = timeBetweenContiguousValues.Add timeBetweenContiguousValues // Only insert dummy-values when the gap is twice the normal
    (None, values) |> Seq.unfold (fun (prevValue, restOfValues) ->  
        if restOfValues |> Seq.isEmpty then
            None // Reached the end of the input seq
        else
            let currentValue = Seq.hd restOfValues
            if prevValue.IsNone then
                Some(currentValue, (Some(currentValue), Seq.skip 1 restOfValues  )) // Only happens to the first item in the seq
            else
                let currentTime = fst currentValue
                let prevTime = fst prevValue.Value
                let timeDiffBetweenPrevAndCurrentValue = currentTime.Subtract(prevTime)
                if timeDiffBetweenPrevAndCurrentValue = sizeOfHolesToPatch then
                    let dummyValue = (prevTime.Add timeBetweenContiguousValues, 42.0) // 42 is chosen here for obvious reasons, making this comment superfluous
                    Some(dummyValue, (Some(dummyValue), restOfValues))
                else
                    Some(currentValue, (Some(currentValue), Seq.skip 1 restOfValues))) // Either the two values were contiguous, or the gap between them was too large to patch

// Method 2 (Fast)
let insertDummyValuesWhereASingleValueIsMissing2 (timeBetweenContiguousValues : TimeSpan) (values : (DateTime * float) list) =
    let sizeOfHolesToPatch = timeBetweenContiguousValues.Add timeBetweenContiguousValues // Only insert dummy-values when the gap is twice the normal
    (None, values) |> Seq.unfold (fun (prevValue, restOfValues) ->  
        match restOfValues with
        | [] -> None // Reached the end of the input list
        | currentValue::restOfValues -> 
            if prevValue.IsNone then
                Some(currentValue, (Some(currentValue), restOfValues  )) // Only happens to the first item in the list
            else
                let currentTime = fst currentValue
                let prevTime = fst prevValue.Value
                let timeDiffBetweenPrevAndCurrentValue = currentTime.Subtract(prevTime)
                if timeDiffBetweenPrevAndCurrentValue = sizeOfHolesToPatch then
                    let dummyValue = (prevTime.Add timeBetweenContiguousValues, 42.0) 
                    Some(dummyValue, (Some(dummyValue), currentValue::restOfValues))
                else
                    Some(currentValue, (Some(currentValue), restOfValues))) // Either the two values were contiguous, or the gap between them was too large to patch

// Test data
let numbers = {1.0..10000.0}
let contiguousTimeStamps = seq { for n in numbers -> DateTime.Now.AddMinutes(n)}

let dataWithOccationalHoles = Seq.zip contiguousTimeStamps numbers |> Seq.filter (fun (dateTime, num) -> num % 77.0 <> 0.0) // Has a gap in the data every 77 items

let timeBetweenContiguousValues = (new TimeSpan(0,1,0))

// The fast sequence-patching (method 2)
dataWithOccationalHoles |> List.of_seq |> insertDummyValuesWhereASingleValueIsMissing2 timeBetweenContiguousValues |> Seq.iter (fun pair -> printfn "%f %s" (snd pair) ((fst pair).ToString()))

// The SLOOOOOOW sequence-patching (method 1)
dataWithOccationalHoles |> insertDummyValuesWhereASingleValueIsMissing1 timeBetweenContiguousValues |> Seq.iter (fun pair -> printfn "%f %s" (snd pair) ((fst pair).ToString()))

Answer 1

SEQ.SKIP конструирует новую последовательность. Я думаю, именно поэтому ваш первоначальный подход медленный.

Моя первая склонность - использовать выражение последовательности и seq.pairwise. Это быстро и легко читать.

let insertDummyValuesWhereASingleValueIsMissingSeq (timeBetweenContiguousValues : TimeSpan) (values : seq<(DateTime * float)>) =
  let sizeOfHolesToPatch = timeBetweenContiguousValues.Add timeBetweenContiguousValues // Only insert dummy-values when the gap is twice the normal
  seq {
    yield Seq.hd values
    for ((prevTime, _), ((currentTime, _) as next)) in Seq.pairwise values do
      let timeDiffBetweenPrevAndCurrentValue = currentTime.Subtract(prevTime)
      if timeDiffBetweenPrevAndCurrentValue = sizeOfHolesToPatch then
        let dummyValue = (prevTime.Add timeBetweenContiguousValues, 42.0) // 42 is chosen here for obvious reasons, making this comment superfluous
        yield dummyValue
      yield next
  }

Answer 2

Каждый раз, когда вы разбиваете SEQ, используя Seq.hd а также Seq.skip 1 Вы почти наверняка попадаете в ловушку, когда я шел (n^2). IEnumerable<T> это ужасный тип для рекурсивных алгоритмов (включая EG Seq.unfold), поскольку эти алгоритмы почти всегда имеют структуру «первого элемента» и «оставшихся элементов», и нет эффективного способа создать новый IEnumerable Это представляет «остаток элементов». (IEnumerator<T> работоспособна, но его модель программирования API не так уж и простой/легко работать.)

Если вам нужны исходные данные, чтобы «оставаться ленивыми», то вам следует использовать лазилист (в F# PowerPack). Если вам не нужна лень, то вам следует использовать конкретный тип данных, например, «список», в который вы можете «хвостовать» в O (1).

(Вы также должны проверить Избегание переполнения стека (с F# Infinite последовательностями последовательностей) Как к вашему сведению, хотя это только касательно применимо к этой проблеме).)