Можно ли увеличить ограничение в 256 символов в раскрывающихся списках проверки Excel?

Question

Я создаю проверку динамически и достиг ограничения в 256 символов.Моя проверка выглядит примерно так:

Level 1, Level 2, Level 3, Level 4.....

Есть ли способ обойти ограничение на количество символов, кроме указания на диапазон?

Проверка уже производится в VBA.Увеличение лимита — это самый простой способ избежать какого-либо влияния на текущую работу листа.

Answer 1

Я почти уверен, что ограничение в 256 символов невозможно обойти, Джоэл Спольски объясняет, почему здесь: http://www.joelonsoftware.com/printerFriendly/articles/fog0000000319.html.

Однако вы можете использовать VBA, чтобы приблизиться к репликации функциональности встроенной проверки, закодировав событие Worksheet_Change.Вот макет, чтобы дать вам представление.Вероятно, вы захотите провести его рефакторинг для кэширования ValidValues, обработки изменений в диапазонах ячеек и т. д.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim ValidationRange As Excel.Range
Dim ValidValues(1 To 100) As String
Dim Index As Integer
Dim Valid As Boolean
Dim Msg As String
Dim WhatToDo As VbMsgBoxResult

    'Initialise ValidationRange
    Set ValidationRange = Sheet1.Range("A:A")

    ' Check if change is in a cell we need to validate
    If Not Intersect(Target, ValidationRange) Is Nothing Then

        ' Populate ValidValues array
        For Index = 1 To 100
            ValidValues(Index) = "Level " & Index
        Next

        ' do the validation, permit blank values
        If IsEmpty(Target) Then
            Valid = True
        Else
            Valid = False
            For Index = 1 To 100
                If Target.Value = ValidValues(Index) Then
                    ' found match to valid value
                    Valid = True
                    Exit For
                End If
            Next
        End If

        If Not Valid Then

            Target.Select

            ' tell user value isn't valid
            Msg = _
                "The value you entered is not valid" & vbCrLf & vbCrLf & _
                "A user has restricted values that can be entered into this cell."

            WhatToDo = MsgBox(Msg, vbRetryCancel + vbCritical, "Microsoft Excel")

            Target.Value = ""

            If WhatToDo = vbRetry Then
                Application.SendKeys "{F2}"
            End If

        End If

    End If

End Sub