Удаление и замена визуального компонента во время выполнения

Question

Можно ли, например, заменить и освободить TEdit компонентом подкласса, экземпляр которого создается (условно) во время выполнения?Если да, то как и когда это следует сделать?Я пытался установить для родителя значение nil и вызвать free() в конструкторе формы и методах AfterConstruction, но в обоих случаях я получил ошибку во время выполнения.

---

Точнее, я получил ошибку нарушения прав доступа (EAccessViolation).Кажется, Франсуа прав, когда говорит, что высвобождение компонентов при построении каркаса мешает управлению формой.

Answer 1

Эта более общая процедура работает либо с формой, либо с фреймом (обновленным для использования подкласса для нового элемента управления):

function ReplaceControlEx(AControl: TControl; const AControlClass: TControlClass; const ANewName: string; const IsFreed : Boolean = True): TControl;
begin
  if AControl = nil then
  begin
    Result := nil;
    Exit;
  end;
  Result := AControlClass.Create(AControl.Owner);
  CloneProperties(AControl, Result);// copy all properties to new control
  // Result.Left := AControl.Left;   // or copy some properties manually...
  // Result.Top := AControl.Top;
  Result.Name := ANewName;
  Result.Parent := AControl.Parent; // needed for the InsertControl & RemoveControl magic
  if IsFreed then
    FreeAndNil(AControl);
end;

function ReplaceControl(AControl: TControl; const ANewName: string; const IsFreed : Boolean = True): TControl;
begin
  if AControl = nil then
    Result := nil
  else
    Result := ReplaceControlEx(AControl, TControlClass(AControl.ClassType), ANewName, IsFreed);
end;

использование этой процедуры для передачи свойств новому элементу управления

procedure CloneProperties(const Source: TControl; const Dest: TControl);
var
  ms: TMemoryStream;
  OldName: string;
begin
  OldName := Source.Name;
  Source.Name := ''; // needed to avoid Name collision
  try
    ms := TMemoryStream.Create;
    try
      ms.WriteComponent(Source);
      ms.Position := 0;
      ms.ReadComponent(Dest);
    finally
      ms.Free;
    end;
  finally
    Source.Name := OldName;
  end;
end;

используйте его как:

procedure TFrame1.AfterConstruction;
var
  I: Integer;
  NewEdit: TMyEdit;
begin
  inherited;
  NewEdit := ReplaceControlEx(Edit1, TMyEdit, 'Edit2') as TMyEdit;
  if Assigned(NewEdit) then
  begin
    NewEdit.Text := 'My Brand New Edit';
    NewEdit.Author := 'Myself';
  end;
  for I:=0 to ControlCount-1 do
  begin
    ShowMessage(Controls[I].Name);
  end;
end;

ОСТОРОЖНОСТЬ:Если вы делаете это внутри AfterConstruction фрейма, помните, что построение базовой формы еще не завершено.
Освобождение элементов управления там может вызвать множество проблем, поскольку вы запутались в управлении элементами управления формой.
Посмотрите, что вы получите, если попытаетесь прочитать новый заголовок редактирования для отображения в ShowMessage...
В этом случае вы хотели бы использовать
...ReplaceControl(Edit1, 'Edit2', ЛОЖЬ)
а затем сделай
...FreeAndNil(Edit1)
позже.

Answer 2

Вам нужно вызвать RemoveControl родительского элемента TEdit, чтобы удалить элемент управления.Используйте InsertControl, чтобы добавить новый элемент управления.

var Edit2: TEdit;
begin
  Edit2 := TEdit.Create(self);
  Edit2.Left := Edit1.Left;
  Edit2.Top := Edit2.Top;
  Edit1.Parent.Insertcontrol(Edit2);
  TWinControl(Edit1.parent).RemoveControl(Edit1);
  Edit1.Free;
end;

Замените TEdit.Create на класс, который вы хотите использовать, и скопируйте все нужные вам свойства, как я сделал с Left и Top.

Answer 3

На самом деле вы можете использовать RTTI (посмотрите в модуле TypInfo), чтобы клонировать все совпадающие свойства.Я написал код для этого некоторое время назад, но сейчас не могу его найти.Я буду продолжать искать.