Как проверить, является ли файл каталогом в пакетном скрипте?

Question

Есть ли способ узнать, является ли файл каталогом?

У меня есть имя файла в переменной.В Perl я могу сделать это:

if(-d $var) { print "it's a directory\n" }

Answer 1

Вы можете сделать это так:

IF EXIST %VAR%\NUL ECHO It's a directory

Однако это работает только для каталогов, в именах которых нет пробелов.Когда вы добавляете кавычки вокруг переменной для обработки пробелов, она перестает работать.Чтобы обрабатывать каталоги с пробелами, преобразуйте имя файла в короткий формат 8.3 следующим образом:

FOR %%i IN (%VAR%) DO IF EXIST %%~si\NUL ECHO It's a directory

А %%~si преобразует %%i к имени файла 8.3.Чтобы увидеть все другие трюки, которые вы можете выполнить FOR переменные вводятся HELP FOR в командной строке.

(Примечание: приведенный выше пример имеет формат для работы в пакетном файле.Чтобы заставить его работать в командной строке, замените %% с % в обоих местах.)

Answer 2

Это работает:

if exist %1\* echo Directory

Работает с именами каталогов, содержащими пробелы:

C:\>if exist "c:\Program Files\*" echo Directory
Directory

Обратите внимание, что кавычки необходимы, если каталог содержит пробелы:

C:\>if exist c:\Program Files\* echo Directory

Также может быть выражено как:

C:\>SET D="C:\Program Files"
C:\>if exist %D%\* echo Directory
Directory

Это безопасно попробовать дома, дети!

Answer 3

Недавно не удалось использовать разные подходы из вышеперечисленных.Совершенно уверен, что они работали раньше, возможно, здесь это связано с dfs.Теперь, используя атрибуты файлов и вырезать первый символ

@echo off
SETLOCAL ENABLEEXTENSIONS
set ATTR=%~a1
set DIRATTR=%ATTR:~0,1%
if /I "%DIRATTR%"=="d" echo %1 is a folder
:EOF

Answer 4

В дополнение к моему предыдущему предложению я считаю, что это также работает:

if exist %1\ echo Directory

Кавычки вокруг %1 не нужны, поскольку их предоставит вызывающая сторона.Это экономит одно нажатие клавиши по сравнению с моим ответом годичной давности ;-)

Answer 5

Вот сценарий, который использует FOR для создания полного пути, а затем pushd для проверки того, является ли этот путь каталогом.Обратите внимание, как это работает для путей с пробелами, а также для сетевых путей.

@echo off
if [%1]==[] goto usage

for /f "delims=" %%i in ("%~1") do set MYPATH="%%~fi"
pushd %MYPATH% 2>nul
if errorlevel 1 goto notdir
goto isdir

:notdir
echo not a directory
goto exit

:isdir
popd
echo is a directory
goto exit

:usage
echo Usage:  %0 DIRECTORY_TO_TEST

:exit

Пример вывода, сохраненный как «isdir.bat» выше:

C:\>isdir c:\Windows\system32
is a directory

C:\>isdir c:\Windows\system32\wow32.dll
not a directory

C:\>isdir c:\notadir
not a directory

C:\>isdir "C:\Documents and Settings"
is a directory

C:\>isdir \
is a directory

C:\>isdir \\ninja\SharedDocs\cpu-z
is a directory

C:\>isdir \\ninja\SharedDocs\cpu-z\cpuz.ini
not a directory

Answer 6

Это отлично работает

if exist "%~1\" echo Directory

нам нужно использовать %~1, чтобы удалить кавычки из %1, и добавить обратную косую черту в конце.Затем снова поместите целое в кавычки.

Answer 7

Похоже, что метод NUL работает только с именами файлов, совместимыми с версией 8.3.

(Другими словами, `D:\Documents and Settings` — «плохо», а `D:\DOCUME~1` — «хорошо».)

---

Я думаю, что есть некоторые трудности с использованием метода «NUL», когда в имени каталога есть ПРОБЕЛЫ, например «Документы и настройки».

Я использую пакет обновления 2 для Windows XP и запускаю командную строку cmd из %SystemRoot%\system32\cmd.exe.

Вот несколько примеров того, что НЕ сработало и что у меня РАБОТАЕТ:

(Все эти демонстрации проводятся «вживую» с помощью интерактивной подсказки.Я считаю, что вам следует заставить все работать там, прежде чем пытаться отлаживать их в сценарии.)

Это НЕ сработало:

D:\Documents and Settings>if exist "D:\Documents and Settings\NUL" echo yes

Это НЕ сработало:

D:\Documents and Settings>if exist D:\Documents and Settings\NUL echo yes

Это ДЕЙСТВИТЕЛЬНО работает (для меня):

D:\Documents and Settings>cd ..

D:\>REM get the short 8.3 name for the file

D:\>dir /x

Volume in drive D has no label. Volume Serial Number is 34BE-F9C9

Directory of D:\
09/25/2008 05:09 PM <DIR> 2008
09/25/2008 05:14 PM <DIR> 200809~1.25 2008.09.25
09/23/2008 03:44 PM <DIR> BOOST_~3 boost_repo_working_copy
09/02/2008 02:13 PM 486,128 CHROME~1.EXE ChromeSetup.exe
02/14/2008 12:32 PM <DIR> cygwin

[[Посмотрите сюда !!!!]]
09/25/2008 08:34 AM <DIR> DOCUME~1 Documents and Settings

09/11/2008 01:57 PM 0 EMPTY_~1.TXT empty_testcopy_file.txt
01/21/2008 06:58 PM <DIR> NATION~1 National Instruments Downloads
10/12/2007 11:25 AM <DIR> NVIDIA
05/13/2008 09:42 AM <DIR> Office10
09/19/2008 11:08 AM <DIR> PROGRA~1 Program Files
12/02/1999 02:54 PM 24,576 setx.exe
09/15/2008 11:19 AM <DIR> TEMP
02/14/2008 12:26 PM <DIR> tmp
01/21/2008 07:05 PM <DIR> VXIPNP
09/23/2008 12:15 PM <DIR> WINDOWS
02/21/2008 03:49 PM <DIR> wx28
02/29/2008 01:47 PM <DIR> WXWIDG~2 wxWidgets
3 File(s) 510,704 bytes
20 Dir(s) 238,250,901,504 bytes free

D:\>REM now use the \NUL test with the 8.3 name

D:\>if exist d:\docume~1\NUL echo yes

yes

Это работает, но это немного глупо, потому что точка уже означает, что я нахожусь в каталоге:

D:\Documents and Settings>if exist .\NUL echo yes

Answer 8

Это работает, а также обрабатывает пути с пробелами:

dir "%DIR%" > NUL 2>&1

if not errorlevel 1 (
    echo Directory exists.
) else (
    echo Directory does not exist.
)

Вероятно, не самое эффективное, но, по моему мнению, его легче читать, чем другие решения.

Answer 9

Вариант подхода @batchman61 (проверка атрибута Directory).

На этот раз я использую внешнюю команду «найти».

(О, и обратите внимание на && обманывать.Это чтобы избежать долгого скучного IF ERRORLEVEL синтаксис.)

@ECHO OFF
SETLOCAL EnableExtentions
ECHO.%~a1 | find "d" >NUL 2>NUL && (
    ECHO %1 is a directory
)

Выходы да включены:

• Каталоги.
• Символические ссылки или соединения каталогов.
• Сломанный символические ссылки или соединения каталогов.(Не пытается разрешить ссылки.)
• Каталоги, для которых у вас нет разрешения на чтение (например.«C:\Информация о системном томе»)

Answer 10

Я использую это:

if not [%1] == [] (
  pushd %~dpn1 2> nul
  if errorlevel == 1 pushd %~dp1
)

Answer 11

Очень простой способ — проверить, существует ли дочерний элемент.

Если у ребенка нет ребенка, exist команда вернет false.

IF EXIST %1\. (
  echo %1 is a folder
) else (
  echo %1 is a file
)

У вас может быть ложноотрицательный результат, если у вас недостаточно прав доступа (я не проверял).

Answer 12

На основе Эта статья под названием «Как пакетный файл может проверить существование каталога» он «не совсем надежен».

НО я только что проверил это:

@echo off
IF EXIST %1\NUL goto print
ECHO not dir
pause
exit
:print
ECHO It's a directory
pause

и кажется, это работает

Answer 13

Вот мое решение:

REM make sure ERRORLEVEL is 0
TYPE NUL

REM try to PUSHD into the path (store current dir and switch to another one)
PUSHD "insert path here..." >NUL 2>&1

REM if ERRORLEVEL is still 0, it's most definitely a directory
IF %ERRORLEVEL% EQU 0 command...

REM if needed/wanted, go back to previous directory
POPD

Answer 14

Если вы можете cd в него это каталог:

set cwd=%cd%

cd /D "%1" 2> nul
@IF %errorlevel%==0 GOTO end

cd /D "%~dp1"
@echo This is a file.

@goto end2
:end
@echo This is a directory
:end2

@REM restore prior directory
@cd %cwd%

Answer 15

Я хотел бы опубликовать свой собственный сценарий функции на эту тему, надеюсь, однажды он будет кому-то полезен.

@pushd %~dp1
@if not exist "%~nx1" (
        popd
        exit /b 0
) else (
        if exist "%~nx1\*" (
                popd
                exit /b 1
        ) else (
                popd
                exit /b 3
        )
)

Этот пакетный сценарий проверяет, существует ли файл/папка и является ли это файлом или папкой.

Использование:

script.bat "ПУТЬ"

Код(ы) выхода:

0:файл/папка не существует.

1:существует, и это папка.

3:существует, и это файл.

Answer 16

CD возвращает EXIT_FAILURE когда указанный каталог не существует.И ты получил символы условной обработки, поэтому вы можете сделать для этого то, что показано ниже.

SET cd_backup=%cd%
(CD "%~1" && CD %cd_backup%) || GOTO Error

:Error
CD %cd_backup%

Answer 17

В Windows 7 и XP я не могу заставить его отличать файлы от файлов.dirs на подключенных дисках.Следующий скрипт:

@echo off
if exist c:\temp\data.csv echo data.csv is a file
if exist c:\temp\data.csv\ echo data.csv is a directory
if exist c:\temp\data.csv\nul echo data.csv is a directory
if exist k:\temp\nonexistent.txt echo nonexistent.txt is a file
if exist k:\temp\something.txt echo something.txt is a file
if exist k:\temp\something.txt\ echo something.txt is a directory
if exist k:\temp\something.txt\nul echo something.txt is a directory

производит:

data.csv is a file
something.txt is a file
something.txt is a directory
something.txt is a directory

Поэтому будьте осторожны, если вашему сценарию может быть предоставлен сопоставленный или UNC-путь.Приведенное ниже решение pushd кажется наиболее надежным.

Answer 18

Это код, который я использую в своих BATCH-файлах.

```
@echo off
set param=%~1
set tempfile=__temp__.txt
dir /b/ad > %tempfile%
set isfolder=false
for /f "delims=" %%i in (temp.txt) do if /i  "%%i"=="%param%" set isfolder=true
del %tempfile%
echo %isfolder%
if %isfolder%==true echo %param% is a directory

```

Answer 19

Хорошо...трюк с «nul» не работает, если вы используете кавычки в именах, что составляет большинство файлов с длинными именами или пробелами.

Например,

if exist "C:\nul" echo Directory

ничего не делает, но

if exist C:\nul echo Directory

работает.

Наконец я придумал это, которое, казалось, работало во всех случаях:

for /f %%i in ('DIR /A:D /B %~dp1 ^| findstr /X /c:"%~nx1"') do echo Directory

или, если вы можете гарантировать, что соответствуете всем требованиям для «nul», решение:

if exist %~sf1\nul echo Directory

Поместите их в пакетный файл, например «test.bat», и выполните «test.bat MyFile».

Answer 20

Вот мое решение после многих тестов с if существует, pushd, dir/AD и т. д.

@echo off
cd /d C:\
for /f "delims=" %%I in ('dir /a /ogn /b') do (
    call :isdir "%%I"
    if errorlevel 1 (echo F: %%~fI) else echo D: %%~fI
)
cmd/k

:isdir
echo.%~a1 | findstr /b "d" >nul
exit /b %errorlevel%

:: Errorlevel
:: 0 = folder
:: 1 = file or item not found

• Работает с файлами без расширения.
• Он работает с папками с именемfolder.ext.
• Он работает с путем UNC
• Он работает с полным путем в двойных кавычках или только с именем каталога или именем файла.
• Это работает, даже если у вас нет прав на чтение
• Он работает со ссылками каталога (переходами).
• Он работает с файлами, путь которых содержит ссылку на каталог.

Answer 21

Одна проблема с использованием %%~si\NUL Метод заключается в том, что существует вероятность того, что он угадает неправильно.Возможно сокращение имени файла до неправильного файла.я не думаю %%~si разрешает имя файла 8.3, но угадывает его, но использует манипуляции со строками для сокращения пути к файлу.Я считаю, что если у вас одинаковые пути к файлам, это может не сработать.

Альтернативный метод:

dir /AD %F% 2>&1 | findstr /C:"Not Found">NUL:&&(goto IsFile)||(goto IsDir)

:IsFile
  echo %F% is a file
  goto done

:IsDir
  echo %F% is a directory
  goto done

:done

Вы можете заменить (goto IsFile)||(goto IsDir) с другими пакетными командами:
(echo Is a File)||(echo is a Directory)

Answer 22

Разве мы не можем просто протестировать это:

IF [%~x1] == [] ECHO Directory

Кажется, это работает для меня.