Возникает ошибка при попытке использовать stage.height для размещения графики.

Question

Эй, пипз!У меня есть изображение нижнего колонтитула, которое я хочу выровнять по нижней части сцены, однако получаю ошибки.

Как видите, у меня есть прослушиватель ADDED_TO_STAGE в функции конструктора.

package src.display{

import flash.text.*;
import flash.display.*;
import flash.geom.Matrix;
import flash.events.Event;

public class Frame extends Sprite {
    private var footer:Sprite = new Sprite();

    // ☼ ------ Constructor
    public function Frame():void {
        this.addEventListener(Event.ADDED_TO_STAGE, tracer);
    }

    public function tracer(event:Event) {
        trace("Frame added to stage --- √"+"\r");
        this.removeEventListener(Event.ADDED_TO_STAGE, tracer);
    }

    // ☼ ------ Init
    public function init():void {
        footer.graphics.beginFill(0x000);
        footer.graphics.drawRect(0,0,800,56);
        footer.graphics.endFill();
        footer.y = (stage.height - footer.height); // <-- This Line

        addChild(footer);
    }

}

}

Фильм будет работать правильно, если я закомментирую строку 26 (но, конечно, я не хочу, чтобы Y был равен 0):

footer.y = (stage.height - footer.height);

Вот ошибка в окне вывода, которую я получаю:

ТипОшибка:Ошибка № 1009:Невозможно получить доступ к свойству или методу нулевой ссылки на объект.в src.display::Frame/init()[/Users/lgaban/Projects/Player/src/display/Frame.as:26]

---

ОБНОВЛЯТЬ

Ответил на свой вопрос, исправить здесь

Answer 1

Использование пользовательского события — это немного излишество, особенно если у вас уже есть прослушиватель, добавленный на сцену.Я бы сделал это так:

package src.display{

    import flash.text.*;
    import flash.display.*;
    import flash.geom.Matrix;
    import flash.events.Event;

    public class Frame extends Sprite {

        // don't instantiate your sprite here, it's weird! :)
        private var footer:Sprite;

        // this is the same as in your example
        public function Frame():void {
            this.addEventListener(Event.ADDED_TO_STAGE, handleAddedToStage);
        }

            // i renamed this to reflect what it does
        private function handleAddedToStage(event:Event) {
            trace("Frame added to stage --- √"+"\r");
            this.removeEventListener(Event.ADDED_TO_STAGE, handleAddedToStage);
            init();
        }

        // this is also essentially the same, except for private since it shouldn't be called from the outside
        private function init():void {
            footer = new Sprite();
            footer.graphics.beginFill(0x000);
            footer.graphics.drawRect(0,0,800,56);
            footer.graphics.endFill();
            footer.y = (stage.height - footer.height);

            addChild(footer);
        }

    }
}

Answer 2

Не то чтобы это полный ответ, но эта ошибка говорит вам, что стадия равна нулю.