Сортировка коллекции в классическом ASP
-
03-07-2019 - |
Вопрос
Это довольно простой вопрос: как отсортировать коллекцию?
У меня есть файл CSV со строками в случайном порядке.Я хотел бы отсортировать строки по дате в одном столбце.Добавлять ли строки в набор записей?Могу ли я сортировать с помощью Scripting.Dictionary?
Я явно был избалован .NET и Linq, и теперь я снова оказался в стране классического asp, понимая, что, должно быть, знал это 7 лет назад, и мне очень не хватает дженериков.Я чувствую себя полным нубом.
Решение
В этом случае мне бы помог старший брат .net.Можно использовать System.Collections.Sortedlist в вашем приложении ASP и отсортируйте пары «ключ-значение».
set list = server.createObject("System.Collections.Sortedlist")
with list
.add "something", "YY"
.add "something else", "XX"
end with
for i = 0 to list.count - 1
response.write(list.getKey(i) & " = " & list.getByIndex(i))
next
Кстати, если также доступны следующие классы .net:
- System.Collections.Queue
- System.Collections.Stack
- System.Collections.ArrayList
- System.Collections.SortedList
- System.Collections.Hashtable
- System.IO.StringWriter
- Система.IO.MemoryStream;
Также см: Чудеса взаимодействия COM .NET
Другие советы
Я бы выбрал подход RecordSet.Используйте текстовый драйвер.Вам нужно будет изменить каталог в строке подключения и имя файла в операторе выбора.Расширенное свойство «HDR=Да» указывает, что в CSV есть строка заголовка, которую я предлагаю, поскольку это облегчит написание псевдоSQL.
<%
Dim strConnection, conn, rs, strSQL
strConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=c:\inetpub\wwwroot\;Extended Properties='text;HDR=Yes;FMT=Delimited';"
Set conn = Server.CreateObject("ADODB.Connection")
conn.Open strConnection
Set rs = Server.CreateObject("ADODB.recordset")
strSQL = "SELECT * FROM test.csv order by date desc"
rs.open strSQL, conn, 3,3
WHILE NOT rs.EOF
Response.Write(rs("date") & "<br/>")
rs.MoveNext
WEND
rs.Close
Set rs = Nothing
conn.Close
Set conn = Nothing
%>
Для меня тоже прошло много времени.IIRC, у вас нет опции «из коробки».
На вашем месте я бы поместил все данные в массив, а затем отсортировал его.Я нашел реализацию QuickSort здесь: http://www.4guysfromrolla.com/webtech/012799-3.shtml
Также обратите внимание на «Сортировку пузырьком», которая отлично работает с классическим облаком тегов asp.
Поздний, поздний ответ на этот вопрос, но все еще ценный.
Я работал с небольшими коллекциями, поэтому мог позволить себе подход, при котором каждый раз вставлял элемент в нужное место, эффективно реконструируя коллекцию при каждом добавлении.
Класс VBScript выглядит следующим образом:
'Simple collection manager class.
'Performs the opration of adding/setting a collection item.
'Encapulated off here in order to delegate responsibility away from the collection class.
Class clsCollectionManager
Public Sub PopulateCollectionItem(collection, strKey, Value)
If collection.Exists(strKey) Then
If (VarType(Value) = vbObject) Then
Set collection.Item(strKey) = Value
Else
collection.Item(strKey) = Value
End If
Else
Call collection.Add(strKey, Value)
End If
End Sub
'take a collection and a new element as input parameters, an spit out a brand new collection
'with the new item iserted into the correct location by order
'This works on the assumption that the collection it is receiving is already ordered
'(which it should be if we always use this method to populate the item)
'This mutates the passed collection, so we highlight this by marking it as byref
'(this is not strictly necessary as objects are passed by reference anyway)
Public Sub AddCollectionItemInOrder(byref existingCollection, strNewKey, Value)
Dim orderedCollection: Set orderedCollection = Server.CreateObject("Scripting.Dictionary")
Dim strExistingKey
'If there is something already in our recordset then we need to add it in order.
'There is no sorting available for a collection (or an array) in VBScript. Therefore we have to do it ourself.
'First, iterate over eveything in our current collection. We have to assume that it is itself sorted.
For Each strExistingKey In existingCollection
'if the new item doesn't exist AND it occurs after the current item, then add the new item in now
'(before adding in the current item.)
If (Not orderedCollection.Exists(strNewKey)) And (strExistingKey > strNewKey) Then
Call PopulateCollectionItem(orderedCollection, strNewKey, Value)
End If
Call PopulateCollectionItem(orderedCollection, strExistingKey, existingCollection.item(strExistingKey))
Next
'Finally check to see if it still doesn't exist.
'It won't if the last place for it is at the very end, or the original collection was empty
If (Not orderedCollection.Exists(strNewKey)) Then
Call PopulateCollectionItem(orderedCollection, strNewKey, Value)
End If
Set existingCollection = orderedCollection
End Sub
End Class