Groovy выполнение команд оболочки

Question

Groovy добавляет execute метод String сделать выполнение оболочек достаточно простым;

println "ls".execute().text

но если произойдет ошибка, результирующего вывода не будет. Есть ли простой способ получить как стандартную ошибку, так и стандартный вывод? (кроме создания кучи кода для;создать два потока для чтения обоих входных потоков, затем использовать родительский поток, чтобы дождаться их завершения, а затем преобразовать строки обратно в текст?)

Было бы неплохо иметь что-то вроде;

 def x = shellDo("ls /tmp/NoFile")
 println "out: ${x.out} err:${x.err}"

Answer 1

Хорошо, решил это сам;

def sout = new StringBuilder(), serr = new StringBuilder()
def proc = 'ls /badDir'.execute()
proc.consumeProcessOutput(sout, serr)
proc.waitForOrKill(1000)
println "out> $sout err> $serr"

отображает:

out> err> ls: cannot access /badDir: No such file or directory

Answer 2

"ls".execute() возвращает Process объект, вот почему "ls".execute().text работает.Вы должны иметь возможность просто прочитать поток ошибок, чтобы определить, были ли какие-либо ошибки.

Есть дополнительный метод Process которые позволяют вам пройти StringBuffer чтобы получить текст: consumeProcessErrorStream(StringBuffer error).

Пример:

def proc = "ls".execute()
def b = new StringBuffer()
proc.consumeProcessErrorStream(b)

println proc.text
println b.toString()

Answer 3

// a wrapper closure around executing a string                                  
// can take either a string or a list of strings (for arguments with spaces)    
// prints all output, complains and halts on error                              
def runCommand = { strList ->
  assert ( strList instanceof String ||
           ( strList instanceof List && strList.each{ it instanceof String } ) \
)
  def proc = strList.execute()
  proc.in.eachLine { line -> println line }
  proc.out.close()
  proc.waitFor()

  print "[INFO] ( "
  if(strList instanceof List) {
    strList.each { print "${it} " }
  } else {
    print strList
  }
  println " )"

  if (proc.exitValue()) {
    println "gave the following error: "
    println "[ERROR] ${proc.getErrorStream()}"
  }
  assert !proc.exitValue()
}

Answer 4

Чтобы добавить еще одну важную информацию к приведенным выше ответам -

Для процесса

def proc = command.execute();

всегда старайтесь использовать

def outputStream = new StringBuffer();
proc.waitForProcessOutput(outputStream, System.err)
//proc.waitForProcessOutput(System.out, System.err)

скорее, чем

def output = proc.in.text;

для захвата выходных данных после выполнения команд в groovy, поскольку последний является блокирующим вызовом (ТАК вопрос по причине).

Answer 5

Мне кажется это более идиоматическим:

def proc = "ls foo.txt doesnotexist.txt".execute()
assert proc.in.text == "foo.txt\n"
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n"

Как упоминается в другом сообщении, это блокирующие вызовы, но поскольку мы хотим работать с выходными данными, это может быть необходимо.

Answer 6

def exec = { encoding, execPath, execStr, execCommands ->

def outputCatcher = new ByteArrayOutputStream()
def errorCatcher = new ByteArrayOutputStream()

def proc = execStr.execute(null, new File(execPath))
def inputCatcher = proc.outputStream

execCommands.each { cm ->
    inputCatcher.write(cm.getBytes(encoding))
    inputCatcher.flush()
}

proc.consumeProcessOutput(outputCatcher, errorCatcher)
proc.waitFor()

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)]

}

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"])

println "OUT:\n" + out[0]
println "ERR:\n" + out[1]

Answer 7

command = "ls *"

def execute_state=sh(returnStdout: true, script: command)

но в случае сбоя команды процесс завершится