Как я могу анализировать даты и преобразовывать часовые пояса в Perl?
Вопрос
Я использовал местное время функция в Perl позволяет получить текущую дату и время, но для этого необходимо выполнить синтаксический анализ по существующим датам.У меня есть дата по Гринвичу в следующем формате:"20090103 12:00" Я хотел бы разобрать его в объект date, с которым я могу работать, а затем преобразовать время / дату GMT в мой текущий часовой пояс, который в настоящее время соответствует восточному стандартному времени.Поэтому я хотел бы преобразовать "20090103 12:00" в "20090103 7:00", я был бы весьма признателен за любую информацию о том, как это сделать.
Решение
Поскольку встроенные в Perl интерфейсы обработки дат выглядят неуклюже, и вы передаете около полудюжины переменных, лучше использовать DateTime или Time :: Piece а>. DateTime - это поющий, все танцующий объект даты Perl, и вы, вероятно, в конечном итоге захотите его использовать, но Time :: Piece более прост и идеально подходит для этой задачи, имеет преимущество доставки с 5.10, а техника в основном то же самое для обоих.
Вот простой и гибкий способ использования Time :: Piece и strptime . р>
#!/usr/bin/perl
use 5.10.0;
use strict;
use warnings;
use Time::Piece;
# Read the date from the command line.
my $date = shift;
# Parse the date using strptime(), which uses strftime() formats.
my $time = Time::Piece->strptime($date, "%Y%m%d %H:%M");
# Here it is, parsed but still in GMT.
say $time->datetime;
# Create a localtime object for the same timestamp.
$time = localtime($time->epoch);
# And here it is localized.
say $time->datetime;
А вот и способ для контраста.
Поскольку формат фиксированный, регулярное выражение будет работать нормально, но если формат изменится, вам придется настроить регулярное выражение.
my($year, $mon, $day, $hour, $min) =
$date =~ /^(\d{4}) (\d{2}) (\d{2})\ (\d{2}):(\d{2})$/x;
Затем преобразуйте его в время эпохи Unix (секунды с 1 января 1970 года)
use Time::Local;
# Note that all the internal Perl date handling functions take month
# from 0 and the year starting at 1900. Blame C (or blame Larry for
# parroting C).
my $time = timegm(0, $min, $hour, $day, $mon - 1, $year - 1900);
А потом вернемся к вашему местному времени.
(undef, $min, $hour, $day, $mon, $year) = localtime($time);
my $local_date = sprintf "%d%02d%02d %02d:%02d\n",
$year + 1900, $mon + 1, $day, $hour, $min;
Другие советы
Вот пример, использующий Дата - время и его strptime ( время ожидания ) модуль форматирования.
use DateTime;
use DateTime::Format::Strptime;
my $val = "20090103 12:00";
my $format = new DateTime::Format::Strptime(
pattern => '%Y%m%d %H:%M',
time_zone => 'GMT',
);
my $date = $format->parse_datetime($val);
print $date->strftime("%Y%m%d %H:%M %Z")."\n";
$date->set_time_zone("America/New_York"); # or "local"
print $date->strftime("%Y%m%d %H:%M %Z")."\n";
$ perl dates.pl
20090103 12:00 UTC
20090103 07:00 EST
Если бы вы хотели проанализировать localtime, вот как бы вы это сделали :)
use DateTime;
my @time = (localtime);
my $date = DateTime->new(year => $time[5]+1900, month => $time[4]+1,
day => $time[3], hour => $time[2], minute => $time[1],
second => $time[0], time_zone => "America/New_York");
print $date->strftime("%F %r %Z")."\n";
$date->set_time_zone("Europe/Prague");
print $date->strftime("%F %r %Z")."\n";
Я бы так и сделал ...
#!/usr/bin/perl
use Date::Parse;
use POSIX;
$orig = "20090103 12:00";
print strftime("%Y%m%d %R", localtime(str2time($orig, 'GMT')));
Вы также можете использовать Time :: ParseDate
и parsedate ()
вместо Date :: Parse
и str2time () код>. Обратите внимание, что де-факто стандартный атм. похоже, DateTime (но вы можете не использовать синтаксис OO только для преобразования временной метки).
Делай свой выбор:
- Дата - время::* (в качестве альтернативы, на datetime.perl.org)
- Дата::Манипуляция
- Дата::Calc (последнее обновление в 2004 году)
Без сомнения, есть миллион других, но они, вероятно, главные претенденты.
use strict;
use warnings;
my ($sec,$min,$hour,$day,$month,$year)=localtime();
$year+=1900;
$month+=1;
$today_time = sprintf("%02d-%02d-%04d %02d:%02d:%02d",$day,$month,$year,$hour,$min,$sec);
print $today_time;