Выделение непустых ячеек в Excel с помощью VBA

Question

Я только начинаю погружаться в VBA и столкнулся с небольшим препятствием.

У меня есть лист с более чем 50 столбцами и более чем 900 строками данных.Мне нужно переформатировать около 10 из этих столбцов и вставить их в новую рабочую книгу.

Как мне программно выделить каждую непустую ячейку в столбце book1, запустить ее с помощью некоторых функций и перенести результаты в book2?

Answer 1

Следующий код VBA должен помочь вам начать работу.Он скопирует все данные из исходной книги в новую книгу, но добавит 1 к каждому значению, а все пустые ячейки будут проигнорированы.

Option Explicit

Public Sub exportDataToNewBook()
    Dim rowIndex As Integer
    Dim colIndex As Integer
    Dim dataRange As Range
    Dim thisBook As Workbook
    Dim newBook As Workbook
    Dim newRow As Integer
    Dim temp

    '// set your data range here
    Set dataRange = Sheet1.Range("A1:B100")

    '// create a new workbook
    Set newBook = Excel.Workbooks.Add

    '// loop through the data in book1, one column at a time
    For colIndex = 1 To dataRange.Columns.Count
        newRow = 0
        For rowIndex = 1 To dataRange.Rows.Count
            With dataRange.Cells(rowIndex, colIndex)

            '// ignore empty cells
            If .value <> "" Then
                newRow = newRow + 1
                temp = doSomethingWith(.value)
                newBook.ActiveSheet.Cells(newRow, colIndex).value = temp
                End If

            End With
        Next rowIndex
    Next colIndex
End Sub

Private Function doSomethingWith(aValue)

    '// This is where you would compute a different value
    '// for use in the new workbook
    '// In this example, I simply add one to it.
    aValue = aValue + 1

    doSomethingWith = aValue
End Function

Answer 2

Я знаю, что очень опаздываю с этим, но вот несколько полезных примеров:

'select the used cells in column 3 of worksheet wks
wks.columns(3).SpecialCells(xlCellTypeConstants).Select

или

'change all formulas in col 3 to values
with sheet1.columns(3).SpecialCells(xlCellTypeFormulas)
    .value = .value
end with

Чтобы найти последнюю использованную строку в столбце, никогда не полагайтесь на lastCell, которая ненадежна (она не сбрасывается после удаления данных).Вместо этого я использую что-то вроде

 lngLast = cells(rows.count,3).end(xlUp).row

Answer 3

Если вы ищете последнюю строку столбца, используйте:

Sub SelectFirstColumn()
   SelectEntireColumn (1)
End Sub

Sub SelectSecondColumn()
    SelectEntireColumn (2)
End Sub

Sub SelectEntireColumn(columnNumber)
    Dim LastRow
    Sheets("sheet1").Select
    LastRow = ActiveSheet.Columns(columnNumber).SpecialCells(xlLastCell).Row

    ActiveSheet.Range(Cells(1, columnNumber), Cells(LastRow, columnNumber)).Select
End Sub

Другие команды, с которыми вам нужно ознакомиться, это команды копирования и вставки:

Sub CopyOneToTwo()
    SelectEntireColumn (1)
    Selection.Copy

    Sheets("sheet1").Select
    ActiveSheet.Range("B1").PasteSpecial Paste:=xlPasteValues
End Sub

Наконец, вы можете ссылаться на листы в других книгах, используя следующий синтаксис:

Dim book2
Set book2 = Workbooks.Open("C:\book2.xls")
book2.Worksheets("sheet1")

Answer 4

Это может быть совершенно не по основанию, но вы не можете просто скопировать весь столбец в новую электронную таблицу, а затем отсортировать столбец? Я предполагаю, что вам не нужно поддерживать целостность заказа.