Как мне программно обновить ссылки OCX в проектах vb6?

Question

Я периодически нарушаю двоичную совместимость и мне нужно перекомпилировать все приложение vb6, состоящее в общей сложности из нескольких десятков библиотек ActiveX DLL и OCXS.Я написал скрипт для автоматизации этого процесса, но столкнулся с проблемой.

Когда OCX перекомпилируется с учетом совместимости с проектом, его версия увеличивается, и проекты, ссылающиеся на OCX, не будут перекомпилироваться до тех пор, пока их ссылка не будет обновлена до новой версии.Это проверяется автоматически, когда проект открывается в обычном режиме, и пользователю предлагается обновить ссылку, но мне нужно сделать это в скрипте.

Как мне это сделать?

Answer 1

Я предполагаю, что вам пришлось бы отредактировать файлы проекта (.vbp), файлы форм (.frm) и управляющие файлы (.ctl), которые ссылаются на библиотеки DLL и OCXS, и увеличить номер версии typelib.

Вы найдете последний номер версии typelib для control / DLL в реестре.

Это может быть проблематично в зависимости от того, сколько у вас файлов.

Взлом состоял бы в том, чтобы открыть основной проект с помощью VB6, используя ваш скрипт, и отправить ключи для подтверждения ссылок на обновление, а затем сохранить проект.

Удачи вам

Answer 2

Мой проект, поддерживаемый более десяти лет, состоит из иерархии из двух десятков библиотек ActiveX DLL и полудюжины элементов управления.Скомпилирован также с помощью скриптовой системы.

Я не рекомендую делать то, что делаете вы.

То, что мы делаем, заключается в следующем

1. Внесите наши изменения, включая дополнения и протестируйте в IDE.
2. Мы компилируем от нижней части иерархии до верхней
3. мы копируем новые соответствующие файлы в каталог редакции, например 601, затем 602 и т.д. и т.п.
4. мы создаем setup.exe
5. когда настройка завершена, мы копируем через каталог версий в наш директор по совместимости.Примечание: мы никогда не указываем на скомпилированный двоичный файл в каталоге проекта.Всегда в каталог совместимости, содержащий все библиотеки DLL.

Причина, по которой это работает, заключается в том, что если вы посмотрите на исходный код IDL с помощью инструмента OLE View, вы обнаружите, что любой элемент управления или библиотеки DLL, на которые ссылается ссылка, добавляются в интерфейс через #include.Если вы укажете на двоичный файл в каталоге вашего проекта, то включение будет выбрано из реестра, что может привести к большим странностям и совместимости.

Однако, если упомянутая библиотека DLL присутствует в каталоге, который существует в двоичном формате, при использовании для двоичной совместимости, VB6 будет использовать это вместо чего-либо в реестре.

Теперь есть одна проблема, с которой вы будете сталкиваться нечасто.Рассмотрим эту иерархию

• MyUtilityDLL
• MyObjectDLL
• Мой Гидлл
• Мое приложение

Если вы ДОБАВЛЯЕТЕ свойство или метод к классу в MyUtilityDLL, MyUIDLL может не скомпилироваться, выдавая ошибку двоичной несовместимости, если вам повезет, или странную ошибку типа [inref].В любом случае решение состоит в том, чтобы скомпилировать MyUtilityDLL, а затем немедленно скопировать MyUtilityDLL в каталог совместимости.Тогда остальная часть автоматической компиляции будет работать нормально.

Возможно, вы захотите включить этот шаг в автоматическую сборку.

Обратите внимание, что во многих случаях проекты будут нормально работать в IDE.Чтобы, если вы сейчас осознаете это, вы могли бы рвать на себе волосы.

Answer 3

Мы делаем похожие вещи, т.е.манипулируя ссылками на используемые OCXS непосредственно в файлах VB6 .vbp, в нашем Инструмент Обновления ссылок на проекты VB6 (скачать можно здесь).Обычно он используется для обновления ссылок, когда используемые ActiveX меняют свои номера версий, CLSID и т.д.

Инструменты имеют открытый исходный код, поэтому каждый, кто интересуется этой проблемой, может позаимствовать наши фрагменты кода на VB для реализации подобных задач.

Наш инструмент написан на Visual Basic 6 и использует tlbinf32.dll (TypeLib Information DLL), которая позволяет программно извлекать информацию из библиотек типов.

Answer 4

Самостоятельный ответ:Я написал некоторый код vb6 для выполнения обновления программным путем.Он не был тщательно протестирован, вероятно, тут и там есть несколько ошибок для угловых случаев, но я успешно им воспользовался.

Option Explicit

Const HKEY_LOCAL_MACHINE As Long = &H80000002
Const KEY_ENUMERATE_SUB_KEYS As Long = 8
Private Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
Private Declare Function RegEnumKeyEx Lib "advapi32.dll" Alias "RegEnumKeyExA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpName As String, lpcbName As Long, lpReserved As Long, ByVal lpClass As String, lpcbClass As Long, lpftLastWriteTime As Any) As Long
Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long

'''Returns the expected major version of a GUID if it exists, and otherwise returns the highest registered major version.
Public Function GetOcxMajorVersion(ByVal guid As String, Optional ByVal expected_version As Long) As Long
    Const BUFFER_SIZE As Long = 255
    Dim reg_key As Long
    Dim ret As Long
    Dim enum_index As Long
    Dim max_version As Long: max_version = -1

    ret = RegOpenKeyEx(HKEY_LOCAL_MACHINE, "SOFTWARE\Classes\TypeLib\{" & guid & "}", 0, KEY_ENUMERATE_SUB_KEYS, reg_key)
    If ret <> 0 Then Err.Raise ret, , "Failed to open registry key."
    Do
        'Store next subkey name in buffer
        Dim buffer As String: buffer = Space(BUFFER_SIZE)
        Dim cur_buffer_size As Long: cur_buffer_size = BUFFER_SIZE
        ret = RegEnumKeyEx(reg_key, enum_index, buffer, cur_buffer_size, ByVal 0&, vbNullString, ByVal 0&, ByVal 0&)
        If ret <> 0 Then Exit Do
        buffer = Left(buffer, cur_buffer_size)

        'Keep most likely version
        buffer = Split(buffer, ".")(0)
        If Not buffer Like "*[!0-9A-B]*" And Len(buffer) < 4 Then
            Dim v As Long: v = CLng("&H" & buffer) 'convert from hex
            If v = expected_version Then
                max_version = v
                Exit Do
            ElseIf max_version < v Then
                max_version = v
            End If
        End If

        enum_index = enum_index + 1
    Loop
    RegCloseKey reg_key

    If max_version = -1 Then Err.Raise -1, , "Failed to enumerate any viable subkeys."
    GetOcxMajorVersion = max_version
End Function

Public Function RemoveFilename(ByVal path As String) As String
    Dim folders() As String: folders = Split(Replace(path, "/", "\"), "\")
    RemoveFilename = Left(path, Len(path) - Len(folders(UBound(folders))))
End Function

'''Changes any invalid OCX references to newer registered version
Public Sub UpdateFileOCXReferences(ByVal path As String)
    Dim file_data As String
    Dim changes_made As Boolean

    'Read
    Dim fn As Long: fn = FreeFile
    Open path For Input As fn
        While Not EOF(fn)
            Dim line As String
            Line Input #fn, line

            'check for ocx reference line
            If LCase(line) Like "object*=*{*-*-*-*-*}[#]*#.#*[#]#*;*.ocx*" Then
                'get guid
                Dim guid_start As Long: guid_start = InStr(line, "{") + 1
                Dim guid_end As Long: guid_end = InStr(line, "}")
                Dim guid As String: guid = Mid(line, guid_start, guid_end - guid_start)

                'get reference major version
                Dim version_start As Long: version_start = InStr(line, "#") + 1
                Dim version_end As Long: version_end = InStr(version_start + 1, line, ".")
                Dim version_text As String: version_text = Mid(line, version_start, version_end - version_start)

                'play it safe
                If Len(guid) <> 32 + 4 Then Err.Raise -1, , "GUID has unexpected length."
                If Len(version_text) > 4 Then Err.Raise -1, , "Major version is larger than expected."
                If guid Like "*[!0-9A-F-]*" Then Err.Raise -1, , "GUID has unexpected characters."
                If version_text Like "*[!0-9]*" Then Err.Raise -1, , "Major version isn't an integer."

                'get registry major version
                Dim ref_version As Long: ref_version = CLng(version_text)
                Dim reg_version As Long: reg_version = GetOcxMajorVersion(guid, ref_version)

                'change line if necessary
                If reg_version < ref_version Then
                    Err.Raise -1, , "Registered version precedes referenced version."
                ElseIf reg_version > ref_version Then
                    line = Left(line, version_start - 1) & CStr(reg_version) & Mid(line, version_end)
                    changes_made = True
                End If
            End If

            file_data = file_data & line & vbNewLine
        Wend
    Close fn

    'Write
    If changes_made Then
        Kill path
        Open path For Binary As fn
            Put fn, , file_data
        Close fn
    End If
End Sub

'''Changes any invalid in included files to newer registered version
Public Sub UpdateSubFileOCXReferences(ByVal path As String)
    Dim folder As String: folder = RemoveFilename(path)
    Dim fn As Long: fn = FreeFile
    Open path For Input As fn
        While Not EOF(fn)
            Dim line As String
            Line Input #fn, line

            If LCase(line) Like "form=*.frm" _
                            Or LCase(line) Like "usercontrol=*.ctl" Then
                Dim file As String: file = folder & Mid(line, InStr(line, "=") + 1)
                If Dir(file) <> "" Then
                    UpdateFileOCXReferences file
                End If
            End If
        Wend
    Close fn
End Sub