Массив или список в Oracle, используя cfprocparam

Question

У меня есть список значений, которые я хочу вставить в таблицу с помощью сохраненной процедуры. Я подумал, что передал массив в Oracle и Loop через массив, но я не вижу, как пройти массив в Oracle. Я бы передал список, но я не вижу, как работать со списком, чтобы превратить его в массив, используя PL / SQL (я довольно новой для PL / SQL). Я приближаюсь к этому неправильно?

Используя Oracle 9i и CF8.

РЕДАКТИРОВАТЬ

Возможно, я думаю об этом неправильно? Я уверен, что я не делаю ничего нового здесь ... я подумал, что я преобразую список в ассоциативный массив, а затем циклируйте массив, потому что Oracle не работает хорошо со списками (в моем ограниченном наблюдении).

Я пытаюсь добавить продукт, затем добавить записи для команды управления.
- Таблица продукта

ProductName = 'foo' productdescription = 'Bar' ... ... etc

- Таблица ManagementTeam просто имеет идентификатор продукта и идентификатора пользователей, выбранных из выпадающего.

Идентификаторы пользователя передаются через список, как «1,3,6,20»

Как мне пойти по добавлению записей в таблицу команды управления?

---

Вот где я код

Теоретически я передаю список «1,2,3,4» для вставки .addproduct.
INSERTS.ADDPRODUCT должен вызывать инструменты .ListToArray и вернуть массив.
INSERTS.ADDPRODUCT воссоздает список с помощью * раздела в качестве теста.
Создать или заменить инструменты пакета как

  TYPE array_type is TABLE OF VARCHAR2(225) INDEX BY BINARY_INTEGER;

  FUNCTION listToArray(in_list IN VARCHAR,
                     in_delim IN VARCHAR2 DEFAULT ',') 
  RETURN array_type;

END tools;



CREATE OR REPLACE PACKAGE BODY tools
AS

FUNCTION listToArray(in_list IN VARCHAR,
                         in_delim IN VARCHAR2 DEFAULT ',') 
    RETURN array_type

    IS
    l_token_count BINARY_INTEGER := 0;
    -- l_token_tbl type_array; 
    i pls_integer;
    l_start_pos INTEGER := 1;
    l_end_pos INTEGER :=1;
    p_parsed_table array_type;

    BEGIN -- original work by John Spencer  
       WHILE l_end_pos <> 0 LOOP
          l_end_pos := instr(in_list,in_delim,l_start_pos);
          IF l_end_pos <> 0 THEN
             l_token_count  := l_token_count  + 1;
             p_parsed_table(l_token_count ) :=
                      substr(in_list,l_start_pos,l_end_pos - l_start_pos);
             l_start_pos := l_end_pos + 1;
          END IF;
       END LOOP;
       IF l_token_count = 0 THEN /* We haven't parsed anything so */ 
          l_token_count := 1;
          p_parsed_table(l_token_count) := in_list;
       ELSE  /* We need to get the last token */ 
          l_token_count := l_token_count + 1;
          p_parsed_table(l_token_count) := substr(in_list,l_start_pos);
       END If;
       RETURN p_parsed_table;
    END listToArray;  -- Procedure

END tools;



CREATE OR REPLACE PACKAGE inserts AS
    TYPE array_type is TABLE OF VARCHAR2(225) INDEX BY BINARY_INTEGER;

    PROCEDURE addProduct (inList         IN  VARCHAR2,
                          outList        OUT VARCHAR2
                         );

END inserts;  




CREATE OR REPLACE PACKAGE BODY inserts                      

    AS
    PROCEDURE addProduct (inList         IN  VARCHAR2,
                          outList        OUT VARCHAR2
                         )
    IS
    i NUMBER;
    localArray array_type := tools.listToArray(inList);
    BEGIN       
       outList := '';
       FOR i IN localArray.first .. localArray.last LOOP
          outList := outList || '*' ||localArray(i); -- return a string just to test this mess 
       END LOOP;

    END addProduct;

END inserts;

В настоящее время я получаю ошибку «PLS-00382: выражение неправильного типа» на LocalArray Array_Type: = Tools.ListToArray (InList);

---

Окончательный рабочий код (большое спасибо!)

- Создать коллекцию типа SQL

CREATE OR REPLACE TYPE array_type is TABLE OF VARCHAR2(225);
/



CREATE OR REPLACE PACKAGE tools AS

  FUNCTION listToArray(in_list IN VARCHAR,
                     in_delim IN VARCHAR2 DEFAULT ',') 
  RETURN array_type;

END tools;   
/



CREATE OR REPLACE PACKAGE BODY tools
AS

    FUNCTION listToArray(in_list IN VARCHAR,
                         in_delim IN VARCHAR2 DEFAULT ',') 
    RETURN array_type

    IS
    l_token_count BINARY_INTEGER := 0;
    i pls_integer;
    l_start_pos INTEGER := 1;
    l_end_pos INTEGER :=1;
    p_parsed_table array_type := array_type();

    BEGIN
       WHILE l_end_pos <> 0 LOOP
          l_end_pos := instr(in_list,in_delim,l_start_pos);
          IF l_end_pos <> 0 THEN
             p_parsed_table.extend(1);
             l_token_count  := l_token_count  + 1;
             p_parsed_table(l_token_count ) :=
                      substr(in_list,l_start_pos,l_end_pos - l_start_pos);
             l_start_pos := l_end_pos + 1;
          END IF;

       END LOOP;
       p_parsed_table.extend(1);
       IF l_token_count = 0 THEN /* We haven't parsed anything so */ 
          l_token_count := 1;
          p_parsed_table(l_token_count) := in_list;
       ELSE  /* We need to get the last token */ 
          l_token_count := l_token_count + 1;
          p_parsed_table(l_token_count) := substr(in_list,l_start_pos);
       END If;
       RETURN p_parsed_table;
    END listToArray;  -- Procedure

END tools;
/



CREATE OR REPLACE PACKAGE inserts AS

    PROCEDURE addProduct (inList  IN  VARCHAR2,
                             outList OUT VARCHAR2
                         );

END inserts;
/




CREATE OR REPLACE PACKAGE BODY inserts
AS
    PROCEDURE addProduct (inList  IN  VARCHAR2,
                          outList OUT VARCHAR2
                         )
    IS
    i NUMBER;
    mylist VARCHAR(100);
    localArray array_type := array_type();

    BEGIN     
    localArray := tools.listToArray(inList);
       mylist := '';
       FOR i IN localArray.first .. localArray.last LOOP
          mylist := mylist || localArray(i) || '*';
       END LOOP;
       aList := mylist;
    END addProduct;

END inserts;  
/

Answer 1

PL / SQL поддерживает массивы с Oracle 8.0. Они назывались таблицами PL / SQL, которые путают черт возьми, из всех, поэтому теперь они называются коллекциями. Узнать больше.

Проблема в том, что они реализуются как пользовательские типы (то есть объекты). Мое чтение Документы ColdFusion предполагает, что cfprocparam Поддерживает только «примитивные» типы данных (номер, varchar2 и т. д.). Таким образом, УДТ не поддерживаются.

Я не уверен, что вы подразумеваете под этим:

Я бы передал список, но я не вижу, как работать со списком, чтобы превратить его в массив, используя PL / SQL

Если вы имеете в виду, что вы хотите пройти строку ценностей разделенных запятую ....

"Fox in socks, Mr Knox, Sam-I-Am, The Lorax"

Тогда у меня есть обходной путь для вас. Oracle не обеспечивает встроенный токенизатор. Но давно Джон Спенсер опубликовал ручное решение, которое работает в Oracle 9i на форумах ОТН. Найдите это здесь.

редактировать

Но ... Oracle ненавидит меня

Не отчаивайся. Форумы ОТН были модернизированы несколько раз с тех пор, как John опубликовал это, и форматирование, кажется, повредил код где-то по пути. Была пара ошибок компиляции, которые он не использовал.

Я переписал код Джона, включая новую функцию. Основное отличие состоит в том, что вложенная таблица объявляется как тип SQL, а не типа PL / SQL.

create or replace type tok_tbl as table of varchar2(225) 
/

create or replace package parser is

    function my_parse(
          p_str_to_search in varchar2
            , p_delimiter in varchar2 default ',')
          return tok_tbl;

    procedure my_parse(
          p_str_to_search in varchar2
          , p_delimiter in varchar2 default ','
          , p_parsed_table out tok_tbl);

end parser;
/

Как видите, функция - это просто обертка для процедуры.

create or replace package body parser is

    procedure my_parse ( p_str_to_search in varchar2
                          , p_delimiter in varchar2 default ','
                          , p_parsed_table out tok_tbl)
    is
        l_token_count binary_integer := 0;
        l_token_tbl tok_tbl := tok_tbl();
        i pls_integer;
        l_start_pos integer := 1;
        l_end_pos integer :=1;   
    begin

        while l_end_pos != 0
        loop
            l_end_pos := instr(p_str_to_search,p_delimiter,l_start_pos);

            if l_end_pos  != 0 then
                l_token_count := l_token_count + 1;
                l_token_tbl.extend();
                l_token_tbl(l_token_count ) :=
                    substr(p_str_to_search,l_start_pos,l_end_pos - l_start_pos);
                l_start_pos := l_end_pos + 1;
            end if;
        end loop;

        l_token_tbl.extend();
        if l_token_count = 0 then /* we haven't parsed anything so */
            l_token_count := 1;
            l_token_tbl(l_token_count) := p_str_to_search;
        else /* we need to get the last token */
            l_token_count := l_token_count + 1;
            l_token_tbl(l_token_count) := substr(p_str_to_search,l_start_pos);
        end if;
        p_parsed_table := l_token_tbl;
    end my_parse;

    function my_parse ( p_str_to_search in varchar2
                            , p_delimiter in varchar2 default ',')
                          return tok_tbl
    is
        rv tok_tbl;
    begin
        my_parse(p_str_to_search, p_delimiter, rv);
        return rv;
    end my_parse;

end parser;
/

В силу объявления типа SQL состоит в том, что мы можем использовать его в пункте, как это:

SQL> insert into t23
  2  select trim(column_value)
  3  from table(parser.my_parse('Fox in socks, Mr Knox, Sam-I-Am, The Lorax'))
  4  /

4 rows created.

SQL> select * from t23
  2  /

TXT
------------------------------------------------------------------------------
Fox in socks
Mr Knox
Sam-I-Am
The Lorax

SQL>