Почему мой скрипт не может создавать zip-файлы?

Question

#include <File.au3>
#include <Zip.au3>
#include <Array.au3>

; bad file extensions
Local $extData = "ade|adp|app|asa|ashx|asp|bas|bat|cdx|cer|chm|class|cmd|com|cpl|crt|csh|der|exe|fxp|gadget|hlp|hta|htr|htw|ida|idc|idq|ins|isp|its|jse|ksh|lnk|mad|maf|mag|mam|maq|mar|mas|mat|mau|mav|maw|mda|mdb|mde|mdt|mdw|mdz|msc|msh|msh1|msh1xml|msh2|msh2xml|mshxml|msi|msp|mst|ops|pcd|pif|prf|prg|printer|pst|reg|rem|scf|scr|sct|shb|shs|shtm|shtml|soap|stm|url|vb|vbe|vbs|ws|wsc|wsf|wsh"
Local $extensions = StringSplit($extData, "|")

; What is the root directory?
$rootDirectory = InputBox("Root Directory", "Please enter the root directory...")

archiveDir($rootDirectory)

Func archiveDir($dir)

    $goDirs = True
    $goFiles = True
    ; Get all the files under the current dir
    $allOfDir = _FileListToArray($dir)
    $tmax = UBound($allOfDir)

    For $t = 0 To $tmax - 1
    Next

    Local $countDirs = 0
    Local $countFiles = 0

    $imax = UBound($allOfDir)
    For $i = 0 To $imax - 1
        If StringInStr(FileGetAttrib($dir & "\" & $allOfDir[$i]), "D") Then
            $countDirs = $countDirs + 1
        ElseIf StringInStr(($allOfDir[$i]), ".") Then
            $countFiles = $countFiles + 1
        EndIf
    Next

    If ($countDirs > 0) Then
        Local $allDirs[$countDirs]
        $goDirs = True
    Else
        $goDirs = False
    EndIf

    If ($countFiles > 0) Then
        Local $allFiles[$countFiles]
        $goFiles = True
    Else
        $goFiles = False
    EndIf

    $dirCount = 0
    $fileCount = 0

    For $i = 0 To $imax - 1
        If (StringInStr(FileGetAttrib($dir & "\" & $allOfDir[$i]), "D")) And ($goDirs == True) Then
            $allDirs[$dirCount] = $allOfDir[$i]
            $dirCount = $dirCount + 1
        ElseIf (StringInStr(($allOfDir[$i]), ".")) And ($goFiles == True) Then
            $allFiles[$fileCount] = $allOfDir[$i]
            $fileCount = $fileCount + 1
        EndIf
    Next

    ; Zip them if need be in current spot using 'ext_zip.zip' as file name, loop through each file ext.
    If ($goFiles == True) Then
        $fmax = UBound($allFiles)
        For $f = 0 To $fmax - 1
            $currentExt = getExt($allFiles[$f])
            $position = _ArraySearch($extensions, $currentExt)
            If @error Then
                MsgBox(0, "Not Found", "Not Found")
            Else
                $zip = _Zip_Create($dir & "\" & $currentExt & "_zip.zip")
                _Zip_AddFile($zip, $dir & "\" & $allFiles[$f])
            EndIf
        Next
    EndIf

    ; Get all dirs under current DirCopy
    ; For each dir, recursive call from step 2
    If ($goDirs == True) Then
        $dmax = UBound($allDirs)
        $rootDirectory = $rootDirectory & "\"
        For $d = 0 To $dmax - 1
            archiveDir($rootDirectory & $allDirs[$d])
        Next
    EndIf

EndFunc

Func getExt($filename)

    $pos = StringInStr($filename, ".")
    $retval = StringTrimLeft($filename, $pos - 1)
    Return $retval

EndFunc

У меня есть список расширений файлов. Этот скрипт должен пройти через каталог (и подкаталоги), zip up (отдельные zip-файлы для каждого расширения) все файлы с участием эти расширения.

Почему это не создает zip-файлы?

Answer 1

В функции StringTrimleft («String», Count) Count - количество символов для обрезки.

$filename = "filename.zip"

$pos = StringInStr($filename, ".") ; $pos will be equal to 9

так...

$retval = StringTrimLeft($filename, $pos + 1); this will remove 10 characters = ip

Answer 2

Два предложения:

1. Добавлять MsgBox(0, "Zip", "Got here") Внутри вашего If ($currentExt == $extensions[$e]) Then. Отказ Вы должны увидеть, что вы никогда не попадаете туда.
2. Связанные с вышеизложенным, ваш getExt Функция не возвращает правильное значение для расширения файла.
   
   

ОБНОВИТЬ

Вы пошли слишком далеко с вашим редактированием getExt.

Попробуй это:

Func getExt($filename)
  $pos = StringInStr($filename, ".")
  $retval = StringTrimLeft($filename, $pos)
  Return $retval
EndFunc  

Обновление 2.

Что касается вашей проблемы, где она не обрабатывает папки за 2-го уровня, ваша проблема вы используете $rootDirectory В вашем рекурсивом звонке, где вам нужно использовать $dir.

Изменить последнюю часть вашего archiveDir Функция к этому:

  ; For each dir, recursive call from step 2
  If ($goDirs == True) Then
    $dmax = UBound($allDirs)
    $dir = $dir & "\"
    For $d = 0 to $dmax - 1
      archiveDir($dir & $allDirs[$d])
    Next
  EndIf

Answer 3

Я попытался запустить ваш код как есть, и конечно, не удалось. Я тогда положил

MsgBox(0, "error", @error & " " & $currentExt)

В блоке «если @error», чтобы увидеть, сможем ли я узнать, почему он не удалось. Результатом был @Error вернулся в качестве 6. Глядя в документацию, он говорит, что код ошибки из 6 означает, что значение, ищенное, не было найдено в массиве. И тогда $ uterentext сказал мне, что это значение было установлено на ".asp".

Причина, по которой оно не может быть найдено, было потому, что в растягивающих именах в массиве нет периодов. Если вы смотрите ближе к функции Getext (), прежде чем добавляли 1 к стоимости $ Position ... И теперь вы вычитаете 1 из стоимости ... вот иллюстрация, как Stringtrimleft () работает ...

$filename = "filename.txt"

$pos = StringInStr($filename, ".") ; $pos will be equal to 9

$retval = StringTrimLeft($filename, $pos + 1); this will remove 10 characters = xt, that's too much.
$retval = StringTrimLeft($filename, $pos - 1); this will remove 8 characters = .txt, that's not enough.
$retval = StringTrimLeft($filename, $pos); this will remove 9 characters = txt, that's juuuuuuust right!

Таким образом, решение для добавления «». Перед всеми расширениями в вашем массиве или измените функцию Getext ():

Func getExt($filename)
    $pos = StringInStr($filename, ".")
    $retval = StringTrimLeft($filename, $pos)
    Return $retval
EndFunc

Есть еще один вариант, который вы можете посмотреть, и это использует функцию _pathsplit (), найденную в файле.au3, но поскольку ваш скрипт настолько близко к работе на данный момент, я бы не беспокоился об этом, но, возможно, в Будущее, которое вы могли бы использовать вместо этого.

И одна последняя записка ... После того, как я изменил getext (), чтобы бросить ".", Ваш скрипт побежал великолепно.