Вопрос
Я хотел бы преобразовать табуляцию в пробелы в gVim.Я добавил следующую строку в свой _vimrc
:
set tabstop=2
Он работает, останавливаясь на двух пробелах, но по-прежнему выглядит так, будто вставлена одна клавиша tab (впоследствии я попытался использовать клавишу h для подсчета пробелов).
Я не уверен, что мне следует сделать, чтобы заставить gVim преобразовывать табуляции в пробелы?
Решение
IIRC, что-то вроде:
set tabstop=2 shiftwidth=2 expandtab
должно сработать.Если у вас уже есть табуляции, то дополните их хорошим глобальным RE, чтобы заменить их двойными пробелами.
Другие советы
После того, как вы включили expandtab в соответствии с другими ответами, чрезвычайно удобным способом преобразования существующих файлов в соответствии с вашими новыми настройками является:
:retab
Он будет работать с текущим буфером.
Попробуй
set expandtab
для мягких вкладок.
Чтобы исправить уже существующие вкладки:
:%s/\t/ /g
Я использовал два пробела, так как вы уже установили tabstop равным 2 пробелам.
У меня это сработало:
вы можете увидеть вкладки с первым выполнением этого:
:set list
затем, чтобы было возможно заменить вкладки, сделайте это:
:set expandtab
тогда
:retab
теперь все табуляции заменены пробелами затем вы можете вернуться к обычному просмотру следующим образом :
:set nolist
gg=G
переиндентирует весь файл и удалит большинство, если не все вкладки, которые я получаю в файлах от коллег.
Добавьте следующие строки в свой файл .vimrc
set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>
Откройте файл в vim и нажмите F2 Табуляции будут преобразованы в 4 пробела, и файл будет сохранен автоматически.
Если вы хотите сохранить свой \t
равно 8 пробелам, затем рассмотрите возможность установки:
set softtabstop=2 tabstop=8 shiftwidth=2
Это даст вам два пробела на каждый <TAB>
пресса, но актуальная \t
в вашем коде по-прежнему будет просматриваться 8 символов.
сначала выполните поиск вкладок в вашем файле :/^I : установить расширяемую вкладку : восстановить
будет работать.
expand
это утилита unix для преобразования табуляции в пробелы.Если вы этого не хотите set
что угодно в vim, вы можете использовать команду командной строки из vim:
:!% expand -t8
Это заставило все сработать у меня:
:set tabstop=2 shiftwidth=2 expandtab | retab
В этой статье есть отличный скрипт vimrc для обработки табуляции + пробелов и преобразования между ними.
Эти команды предоставляются:
Вкладка Space2 Преобразуйте пробелы в символы табуляции, только с отступами.
Tab2Space Таб2Space Преобразуйте символы табуляции в пробелы, только с отступами.
РетабИндент Запустите Space2Tab (если задано значение expandtab) или Tab2Space (в противном случае).
Каждая команда принимает аргумент, который указывает количество пробелов в столбце табуляции.По умолчанию используется параметр "tabstop".
Источник: http://vim.wikia.com/wiki/Super_retab#Script
" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
let spccol = repeat(' ', a:cols)
let result = substitute(a:indent, spccol, '\t', 'g')
let result = substitute(result, ' \+\ze\t', '', 'g')
if a:what == 1
let result = substitute(result, '\t', spccol, 'g')
endif
return result
endfunction
" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
let savepos = getpos('.')
let cols = empty(a:cols) ? &tabstop : a:cols
execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
call histdel('search', -1)
call setpos('.', savepos)
endfunction
command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)
Это помогло мне немного больше, чем приведенные здесь ответы, когда я впервые занялся поиском решения.