Лучший способ реализации фильтрованного перечисления на TLIST

Question

Используя Delphi 2010, скажем, у меня есть класс, объявленный, как это:

TMyList = TList<TMyObject>

Для этого списка Delphi любезно дает нам перечислетель, поэтому мы можем написать это:

var L:TMyList;
    E:TMyObject;
begin
  for E in L do ;
end;

Беда в том, что я хотел бы написать это:

var L:TMyList;
    E:TMyObject;
begin
  for E in L.GetEnumerator('123') do ;
end;

То есть я хочу, чтобы способность предоставлять несколько перечисленных перечислений в том же списке, используя некоторые критерии. К сожалению, реализация for X in Z требует наличия функции Z.GetEnumerator, Без параметров, которые возвращает данный перечислитель! Чтобы обойти эту проблему, я определяю интерфейс, который реализует функцию «getEnumerator», затем я реализую класс, который реализует интерфейс и, наконец, я пишу функцию на Tmylist, который возвращает интерфейс! И я возвращаю интерфейс, потому что я не хочу, чтобы он беспокоился с вручную, освобождающую очень простой класс ... в любом случае, это требует много набора текста. Вот как это выглядит так:

TMyList = class(TList<TMyObject>)
protected

  // Simple enumerator; Gets access to the "root" list
  TSimpleEnumerator = class
  protected
  public
    constructor Create(aList:TList<TMyObject>; FilterValue:Integer);

    function MoveNext:Boolean; // This is where filtering happens
    property Current:TTipElement;
  end;

  // Interface that will create the TSimpleEnumerator. Want this
  // to be an interface so it will free itself.
  ISimpleEnumeratorFactory = interface
    function GetEnumerator:TSimpleEnumerator;
  end;

  // Class that implements the ISimpleEnumeratorFactory
  TSimpleEnumeratorFactory = class(TInterfacedObject, ISimpleEnumeratorFactory)
    function GetEnumerator:TSimpleEnumerator;
  end;

public
  function FilteredEnum(X:Integer):ISimpleEnumeratorFactory;
end;

Используя это, я могу наконец написать:

var L:TMyList;
    E:TMyObject;
begin
  for E in L.FilteredEnum(7) do ;
end;

Вы знаете лучший способ сделать это? Возможно, Delphi поддерживает способ вызовов GetEnumerator с параметром напрямую?

Позже редактировать:

Я решил использовать идею Robert Love о внедрении перечисления с использованием анонимных методов и использования завода «Record» GABR для сохранения еще другого класса. Это позволяет мне создать совершенно новый перечислетель, в комплекте с кодом, используя лишь несколько строк кода в функции, ни одно новое объявление класса не требуется.

Вот как объявлен мой универсальный enumerator, в библиотеке:

TEnumGenericMoveNext<T> = reference to function: Boolean;
TEnumGenericCurrent<T> = reference to function: T;

TEnumGenericAnonim<T> = class
protected
  FEnumGenericMoveNext:TEnumGenericMoveNext<T>;
  FEnumGenericCurrent:TEnumGenericCurrent<T>;
  function GetCurrent:T;
public
  constructor Create(EnumGenericMoveNext:TEnumGenericMoveNext<T>; EnumGenericCurrent:TEnumGenericCurrent<T>);

  function MoveNext:Boolean;
  property Current:T read GetCurrent;
end;

TGenericAnonEnumFactory<T> = record
public
  FEnumGenericMoveNext:TEnumGenericMoveNext<T>;
  FEnumGenericCurrent:TEnumGenericCurrent<T>;
  constructor Create(EnumGenericMoveNext:TEnumGenericMoveNext<T>;   EnumGenericCurrent:TEnumGenericCurrent<T>);
  function GetEnumerator:TEnumGenericAnonim<T>;
end;

И вот способ использовать его. В любом классе я могу добавить функцию, подобную этой (и я намеренно создаю перечислитель, который не использует List<T> Чтобы показать силу этой концепции):

type Form1 = class(TForm)
protected
  function Numbers(From, To:Integer):TGenericAnonEnumFactory<Integer>;  
end;

// This is all that's needed to implement an enumerator!
function Form1.Numbers(From, To:Integer):TGenericAnonEnumFactory<Integer>;
var Current:Integer;
begin
  Current := From - 1;
  Result := TGenericAnonEnumFactory<Integer>.Create(
    // This is the MoveNext implementation
    function :Boolean
    begin
      Inc(Current);
      Result := Current <= To;
    end
    ,
    // This is the GetCurrent implementation
    function :Integer
    begin
      Result := Current;
    end
  );
end;

И вот как я бы использовал этот новый перечислетель:

procedure Form1.Button1Click(Sender: TObject);
var N:Integer;
begin
  for N in Numbers(3,10) do
    Memo1.Lines.Add(IntToStr(N));
end;

Answer 1

Delphi для поддержки петли требует следующего: (От документов)

• Примитивные типы, которые распознают компилятор, такие как массивы, наборы или строки
• Типы, которые реализуют iEnumerable
• Типы, которые реализуют шаблон GetEnumerator, как документировано в руководстве языка Delphi

Если вы посмотрите на Generics.collections.pas Вы найдете реализацию для TDictionary<TKey,TValue> где он имеет три перечисленных для TKey, TValue, и TPair<TKey,TValue> Типы. Embarcadero показывает, что они использовали многолетнюю реализацию.

Вы могли бы сделать что-то вроде этого:

unit Generics.AnonEnum;
interface
uses
 SysUtils,
 Generics.Defaults,
 Generics.Collections;

type

  TAnonEnumerator<T> = class(TEnumerator<T>)
  protected
    FGetCurrent : TFunc<TAnonEnumerator<T>,T>;
    FMoveNext : TFunc<TAnonEnumerator<T>,Boolean>;
    function DoGetCurrent: T; override;
    function DoMoveNext: Boolean; override;
  public
    Constructor Create(aGetCurrent : TFunc<TAnonEnumerator<T>,T>;
                       aMoveNext : TFunc<TAnonEnumerator<T>,Boolean>);
  end;

  TAnonEnumerable<T> = class(TEnumerable<T>)
  protected
    FGetCurrent : TFunc<TAnonEnumerator<T>,T>;
    FMoveNext : TFunc<TAnonEnumerator<T>,Boolean>;
    function DoGetEnumerator: TEnumerator<T>; override;
  public
    Constructor Create(aGetCurrent : TFunc<TAnonEnumerator<T>,T>;
                       aMoveNext : TFunc<TAnonEnumerator<T>,Boolean>);
  end;

implementation

{ TEnumerable<T> }

constructor TAnonEnumerable<T>.Create(aGetCurrent: TFunc<TAnonEnumerator<T>, T>;
  aMoveNext: TFunc<TAnonEnumerator<T>, Boolean>);
begin
  FGetCurrent := aGetCurrent;
  FMoveNext := aMoveNext;
end;

function TAnonEnumerable<T>.DoGetEnumerator: TEnumerator<T>;
begin
 result := TAnonEnumerator<T>.Create(FGetCurrent,FMoveNext);
end;


{ TAnonEnumerator<T> }

constructor TAnonEnumerator<T>.Create(aGetCurrent: TFunc<TAnonEnumerator<T>, T>;
  aMoveNext: TFunc<TAnonEnumerator<T>, Boolean>);
begin
  FGetCurrent := aGetCurrent;
  FMoveNext := aMoveNext;
end;

function TAnonEnumerator<T>.DoGetCurrent: T;
begin
  result := FGetCurrent(self);
end;

function TAnonEnumerator<T>.DoMoveNext: Boolean;
begin
 result := FMoveNext(Self);
end;

end.

Это позволит вам объявить ваши текущие и MOVENEXT методы анонимно.

Answer 2

Увидеть dehl ( http://code.google.com/p/delphilhlplib/ ). Вы можете написать код, который выглядит так:

for E in List.Where(...).Distinct.Reversed.Take(10).Select(...)... etc. 

Как вы можете сделать в .NET (без синтаксиса linq конечно).

Answer 3

Вы подходе в порядке. Я не знаю лучше.

Фабрика перечисления также может быть реализована как запись вместо интерфейса.

Может быть, вы получите некоторые идеи здесь.

Answer 4

Вы можете покончить с заводом и интерфейсом, если вы добавите GetEnumerator() Функция для вашего перечислетеля, как это:

TFilteredEnum = class
public
  constructor Create(AList:TList<TMyObject>; AFilterValue:Integer);

  function GetEnumerator: TFilteredEnum;

  function MoveNext:Boolean; // This is where filtering happens
  property Current: TMyObject;
end;

И просто верните себя:

function TFilteredEnum.GetEnumerator: TSimpleEnumerator;
begin
  result := Self;
end;

И Delphi удобно очистит ваш экземпляр для вас, так же, как он делает какой-либо другой перечислетель:

var 
  L: TMyList;
  E: TMyObject;
begin
  for E in TFilteredEnum.Create(L, 7) do ;
end;

Затем вы можете расширить свой перечислетель для использования анонимного метода, который вы можете пройти в конструкторе:

TFilterFunction = reference to function (AObject: TMyObject): boolean;

TFilteredEnum = class
private
  FFilterFunction: TFilterFunction;
public
  constructor Create(AList:TList<TMyObject>; AFilterFunction: TFilterFunction);

  ...
end;

...

function TFilteredEnum.MoveNext: boolean;
begin
  if FIndex >= FList.Count then
    Exit(False);
  inc(FIndex);
  while (FIndex < FList.Count) and not FFilterFunction(FList[FIndex]) do
    inc(FIndex);
  result := FIndex < FList.Count;
end;

Назовите это так:

var 
  L:TMyList;
  E:TMyObject;
begin
  for E in TFilteredEnum.Create(L, function (AObject: TMyObject): boolean
                                   begin
                                     result := AObject.Value = 7;
                                   end;
                                ) do 
  begin
    //do stuff here
  end
end;

Затем Вы могли бы даже сделать это универсальным, но я не сделаю это здесь, мой ответ достаточно длинный, как есть.

N @

Answer 5

Я использую этот подход ... где aproc выполняет тест фильтра.

TForEachDataItemProc = reference to procedure ( ADataItem: TDataItem; var AFinished: boolean );

procedure TDataItems.ForEachDataItem(AProc: TForEachDataItemProc);
var
  AFinished: Boolean;
  ADataItem: TDataItem;
begin
  AFinished:= False;
  for ADataItem in FItems.Values do
  begin
    AProc( ADataItem, AFinished );
    if AFinished then
      Break;
  end;
end;