USB Flash Drive Swatch Tefetment

Question

كنت أتساءل عما إذا كان شخص ما يمكن أن يساعد. لقد كتبت برنامج Java يقوم بتحميل A .cvs على محرك أقراص فلاش USB. من المحتمل أن يتم استخدام هذا البرنامج على العديد من أجهزة الكمبيوتر المحمولة المختلفة لـ Windows ، لكن البرنامج يستخدم موقع ملف ثابت على أي: F Drive.

كنت أتساءل عما إذا كانت هناك طريقة أنه عندما يتم توصيل محرك الأقراص في فلاش في أن تخصيص الحروف يتم إصلاحه على شيء مثل محرك الأقراص: T بحيث لا يتم توصيله تلقائيًا من قبل برنامج Java. كنت أرغب في القيام بذلك في ملف دفعي على USB حتى لا يضطر المستخدم إلى تعيين الكمبيوتر يدويًا لتغيير محرك الأقراص. نظرًا لأن بعض مستخدمي البرنامج قديمون جدًا ومن غير المحتمل أن يتمكنوا من القيام بذلك حتى لو تم توفيره مع تعليمات خطوة بخطوة.

لم أكتب مطلقًا ملف دفعة من قبل ، لذا فإن أي مساعدة ستكون رائعة

أطيب التحيات

Answer 1

ستبحث هذه الدُفعة عن محرك أقراص يحتوي على ملف أو مجلد "مفتاح" ، ومجال محرك بديل #: (نعم ، هذا خطاب محرك صالح ، ونادر بما يكفي لعدم التصادم مع أي شيء) إلى محرك الأقراص الصحيح. فقط استخدم محرك الأقراص #: في برنامجك. إذا كان ملف الدُفعات قد خرج في القيام بعمله ، فسيكون errorlevel 0 ، وإلا فسيكون خطأ errore

@echo off

    setlocal enableextensions

    rem if our special drive is assigned, release it
    if exist #:\ subst #: /d >nul

    rem if there are problems, exit
    if errorlevel 1 goto endSearch

    rem search drives for "key" file/folder
    set "keyFile=\data\mySpecialFile.csv"
    for %%d in (z y x w v u t s r q p o n m l k j i h g f e d c b a) do (
        vol %%d: >nul 2>nul && if exist "%%d:%keyFile%" (
            rem map our drive
            subst #: %%d:\ > nul 2> nul
            rem if everything ok end search
            if not errorlevel 1 goto endSearch
        )
    )

:endSearch
    rem cleanup and return errorcode as necessary
    endlocal && if exist "#:%keyFile%" ( exit /b 0 ) else (exit /b 1)

Answer 2

يمكنك استخدام subst لفعل هذا:

subst T: %~d0\

طالما أنك تعرف T: ليس قيد الاستخدام. نظرًا لأنك ترسم برنامج Java الخاص بك لموقع ما ، لا أعتقد أن هذه مشكلة.