USB -флэш -накопитель

Question

Мне было интересно, может ли кто -нибудь помочь. Я написал программу Java, которая загружает .CVS на USB -накопитель. Эта программа, вероятно, будет использоваться на нескольких разных ноутбуках Windows, но в программе используется фиксированный файл локата, т.е. F Drive.

Мне было интересно, есть ли способ, когда флэш -накопитель подключен к назначению букв, прикреплен к чему -то вроде диска: t, чтобы независимо от того, какой порт или компьютер подключен к нему, можно автоматически прочитать программу Java. Я хотел сделать это в пакетном файле на USB, чтобы пользователю не нужно было вручную устанавливать компьютер, чтобы изменить флэш -накопитель. Поскольку некоторые пользователи программы очень стары и вряд ли смогут сделать это, даже если они предоставляются пошаговыми инструкциями.

Я никогда раньше не писал пакетный файл, поэтому любая помощь была бы отличной

с уважением

Answer 1

Эта партия будет искать диск, содержащий файл или папку «ключа», и SUP -диск #: (да, это действительная буква диска, и достаточно редко, чтобы ни с чем столкнуться с чем -либо) с правильным диском. Просто используйте Drive #: в вашей программе. Если пакетный файл имеет выход при выполнении своей работы, ErrorLevel будет 0, в противном случае ErrorLevel будет 1

@echo off

    setlocal enableextensions

    rem if our special drive is assigned, release it
    if exist #:\ subst #: /d >nul

    rem if there are problems, exit
    if errorlevel 1 goto endSearch

    rem search drives for "key" file/folder
    set "keyFile=\data\mySpecialFile.csv"
    for %%d in (z y x w v u t s r q p o n m l k j i h g f e d c b a) do (
        vol %%d: >nul 2>nul && if exist "%%d:%keyFile%" (
            rem map our drive
            subst #: %%d:\ > nul 2> nul
            rem if everything ok end search
            if not errorlevel 1 goto endSearch
        )
    )

:endSearch
    rem cleanup and return errorcode as necessary
    endlocal && if exist "#:%keyFile%" ( exit /b 0 ) else (exit /b 1)

Answer 2

Вы можете использовать subst сделать это:

subst T: %~d0\

Пока вы знаете T: не используется. Поскольку вы жестко кодируете свою программу Java для места, я не думаю, что это проблема.