SQL Server:جعل كل حالة العلوي السليم القضية/عنوان القضية

https://stackoverflow.com/questions/230138

04-07-2019
|

سؤال

لدي الجدول الذي تم استيرادها في كل حالة العلوي أود أن تتحول إلى السليم القضية.ما النصي هل تستخدم لإكمال هذا ؟

المحلول

وفيما يلي UDF من شأنها أن تفعل خدعة ...

create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
  declare @Reset bit;
  declare @Ret varchar(8000);
  declare @i int;
  declare @c char(1);

  if @Text is null
    return null;

  select @Reset = 1, @i = 1, @Ret = '';

  while (@i <= len(@Text))
    select @c = substring(@Text, @i, 1),
      @Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
      @Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
      @i = @i + 1
  return @Ret
end

وسوف لا يزال لديك لاستخدامها لتحديث البيانات الخاصة بك على الرغم من.

نصائح أخرى

هذه الدالة:

"الحالات المناسبة" كل "حالة العلوي" الكلمات التي هي محددة من قبل المساحة البيضاء
يترك "بأحرف الكلمات" وحده
يعمل بشكل صحيح حتى بالنسبة لغير الحروف الهجائية الانجليزية
هو محمول في أنه لا يستخدم الميزات الفاخرة الأخيرة إصدارات SQL server
يمكن تغييرها بسهولة إلى استخدام NCHAR و NVARCHAR من أجل دعم يونيكود ، وكذلك أي معلمة طول تراه مناسبا
مساحة بيضاء تعريف يمكن تكوين

CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
  DECLARE @i INT           -- index
  DECLARE @l INT           -- input length
  DECLARE @c NCHAR(1)      -- current char
  DECLARE @f INT           -- first letter flag (1/0)
  DECLARE @o VARCHAR(255)  -- output string
  DECLARE @w VARCHAR(10)   -- characters considered as white space

  SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
  SET @i = 1
  SET @l = LEN(@string)
  SET @f = 1
  SET @o = ''

  WHILE @i <= @l
  BEGIN
    SET @c = SUBSTRING(@string, @i, 1)
    IF @f = 1 
    BEGIN
     SET @o = @o + @c
     SET @f = 0
    END
    ELSE
    BEGIN
     SET @o = @o + LOWER(@c)
    END

    IF @c LIKE @w SET @f = 1

    SET @i = @i + 1
  END

  RETURN @o
END

النتيجة:

dbo.ToProperCase('ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and      Some lower Ää Öö Üü Éé Øø Cc Ææ

UPDATE titles
  SET title =
      UPPER(LEFT(title, 1)) +
        LOWER(RIGHT(title, LEN(title) - 1))

http://sqlmag.com/t-sql/how- عنوان حدة عمود القيمة

إذا يمكنك تمكين CLR في SQL Server (يتطلب 2005 أو في وقت لاحق) ثم هل يمكن أن <لأ href = "http://msdn.microsoft.com/en-us/library/w2kae45k.aspx" يختلط = "noreferrer "> إنشاء دالة CLR يستخدم TextInfo.ToTitleCase المدمج في وظيفة التي من شأنها أن تسمح لك لخلق وسيلة ثقافة علم القيام بذلك إلا في بضعة أسطر من التعليمات البرمجية.

وأنا قليلا في وقت متأخر من المباراة، ولكن أعتقد أن هذا هو أكثر وظيفية، وأنه يعمل مع أي لغة، بما في ذلك الروسية والألمانية والتايلاندية والفيتنامية الخ وسوف تقدم أي شيء الأحرف الكبيرة بعد 'أو - أو. أو (أو) أو الفضاء (من الواضح:).

CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos    int = 1
      , @pos2   int

if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
    set @name = lower(rtrim(@name))
    while (1 = 1)
    begin
        set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
        set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
        set @pos += @pos2
        if (isnull(@pos2, 0) = 0 or @pos > len(@name))
            break
    end
end

return @name
END
GO

وأنا أعلم أن هذه هي آخر في وقت متأخر من هذا الموضوع، ولكن يستحق النظر. تعمل هذه الوظيفة بالنسبة لي من أي وقت مضى الوقت. لذلك فكرت في تقاسمها.

CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char = SUBSTRING(@InputString, @Index, 1)
    IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
    IF @Index + 1 <= LEN(@InputString)
BEGIN
    IF @Char != ''''
    OR
    UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
    SET @OutputString =
    STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
    SET @Index = @Index + 1
END

RETURN ISNULL(@OutputString,'')
END

والمكالمات الاختبار:

select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test

والنتائج:

إذا كنت في SSIS استيراد البيانات التي تمت مختلطة فتش وتحتاج إلى القيام البحث على عمود مع حالة سليمة، ستلاحظ أن فشل البحث حيث المصدر المختلط ومصدر بحث هو الصحيح. ستلاحظ أيضا لا يمكنك استخدام اليمين واليسار وظائف وSSIS ل SQL Server 2008R2 للأعمدة مشتقة. وهنا الحل الذي يعمل بالنسبة لي:

UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))

والارتباط نشرت لي أعلاه هو خيار كبير الذي يعالج المشكلة الرئيسية: أننا لا يمكن أبدا أن حساب برمجيا لجميع الحالات (سميث جونز، فون Haussen، جون سميث M.D.)، على الأقل ليس بطريقة أنيقة. توني يدخل مفهوم الطابع استثناء / استراحة للتعامل مع هذه الحالات. على أي حال، بناء على فكرة سيرفو ل(العلوي كل حرف أقل يسبقه الفضاء)، يمكن أن تكون ملفوفة البيانات استبدال حتى في جدول واحد يستند استبدال بدلا من ذلك. حقا، يمكن إدراج أي / أعلى تركيبة أحرف منخفضة إلىalpha وأن البيان لم تتغير:

declare @str    nvarchar(8000)
declare @alpha  table (low nchar(1), up nchar(1))


set @str = 'ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'

-- stage the alpha (needs number table)
insert into @alpha
    -- A-Z / a-z
    select      nchar(n+32),
                nchar(n)
    from        dbo.Number
    where       n between 65 and 90 or
                n between 192 and 223

-- append space at start of str
set @str = lower(' ' + @str)

-- upper all lower case chars preceded by space
select  @str = replace(@str, ' ' + low, ' ' + up) 
from    @Alpha

select @str

وهنا هو الإصدار الذي يستخدم تسلسل أو أرقام الجدول بدلا من حلقة. يمكنك تعديل جملة WHERE التي تناسب قواعد الشخصية لحين تحويل الحرف إلى الحالة العليا. ولقد تضمنت فقط مجموعة بسيطة من شأنها أن حالة العليا أي حرف التي شرع من قبل غير أحرف باستثناء الفواصل العليا. هذا لا يعني أن اي وقت مضى كيف 123apple سيكون له مباراة على "أ" لأن "3" ليست الرسالة. إذا كنت ترغب فقط أبيض الفضاء (الفضاء، التبويب، حرف إرجاع، خط تغذية)، يمكنك استبدال '[^a-z]' النمط مع '[' + Char(32) + Char(9) + Char(13) + Char(10) + ']'.

CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN

-- 1. Convert all letters to lower case
    DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);

-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
    SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
    FROM (
        SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
        FROM       (SELECT 0 AS n UNION SELECT    1 UNION SELECT    2 UNION SELECT    3 UNION SELECT    4 UNION SELECT    5 UNION SELECT    6 UNION SELECT    7 UNION SELECT    8 UNION SELECT    9) AS    n1
        CROSS JOIN (SELECT 0 AS n UNION SELECT   10 UNION SELECT   20 UNION SELECT   30 UNION SELECT   40 UNION SELECT   50 UNION SELECT   60 UNION SELECT   70 UNION SELECT   80 UNION SELECT   90) AS   n10
        CROSS JOIN (SELECT 0 AS n UNION SELECT  100 UNION SELECT  200 UNION SELECT  300 UNION SELECT  400 UNION SELECT  500 UNION SELECT  600 UNION SELECT  700 UNION SELECT  800 UNION SELECT  900) AS  n100
        CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000)                                                                                                             AS n1000
        ) AS Sequence
    WHERE 
        n BETWEEN 1 AND Len( @InitCap )
    AND SubString( @InitCap, n, 1 ) LIKE '[a-z]'                 /* this character is a letter */
    AND (
        n = 1                                                    /* this character is the first `character` */
        OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]'           /* the previous character is NOT a letter */
        )
    AND (
        n < 3                                                    /* only test the 3rd or greater characters for this exception */
        OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
        )

-- 3. Return the modified version of the input
    RETURN @InitCap

END

وسيكون من المنطقي أن الحفاظ على بحث الاستثناءات لرعاية وفون نيومان، ماكين، في DeGuzman، وجونسون-سميث.

وأعتقد أنك سوف تجد أن ما يلي هو أكثر كفاءة:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
    SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

ويمكن قطع استبدال البيان ولصق مباشرة في استعلام SQL. ومن جدا قبيحة، ولكن عن طريق استبدالstr مع العمود كنت مهتما، أنك لن تدفع ثمنا لمؤشر ضمني مثلك ومع UDFS بالتالي نشرها. أجد أنه حتى باستخدام بلدي UDF هو أكثر كفاءة بكثير.

ويا وبدلا من إنشاء بيان استبدال عن طريق استخدام اليد هذا:

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
    SET @c = CHAR(ASCII('a') + @x)
    SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
    SET @x = @x + 1
END
PRINT @sql

وعلى أي حال فإنه يعتمد على عدد من الصفوف. أتمنى أن تفعل ق / \ ب ([أ-ي]) / 1 / جامعة كاليفورنيا $، ولكن يا جيدا ونحن نعمل مع أدوات لدينا.

ملحوظة قد تضطر إلى استخدام هذا ما عملتم لاستخدامه بمثابة .... dbo.ProperCase SELECT (السفلى (عمود)) منذ العمود في الأحرف الكبيرة. في الواقع يعمل بسرعة جدا على مائدتي من 5000 إدخالات (ولا حتى ثانية واحدة) حتى مع أقل.

في استجابة لموجة من التعليقات بشأن تدويل أقدم تنفيذ التالية التي يعالج كل حرف أسكي الاعتماد فقط على تنفيذ SQL خادم للالعلوي والسفلي. تذكر، والمتغيرات التي نستخدمها هنا VARCHAR الأمر الذي يعني أنها يمكن أن تعقد فقط قيم ASCII. من أجل استخدام المزيد من الحروف الهجائية الدولية، لديك لاستخدام NVARCHAR. ان المنطق أن يكون مماثلا ولكن كنت بحاجة إلى استخدام UNICODE وNCHAR في مكان ASCII وCHAR واستبدال البيان سيكون أكثر ضخمة من ذلك بكثير ....

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000),
    @count  INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
    SET @c = CHAR(@x)
    -- Only generate replacement expression for characters where upper and lowercase differ
    IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
    BEGIN
        SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
        SET @count = @count + 1
    END
    SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)

وأساسا فرضية لي طريقة يتداول قبل الحوسبة للكفاءة. تنفيذ ASCII الكامل هو كما يلي:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
SET @str =     REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

هل فات الأوان على العودة الأمم المتحدة uppercased البيانات ؟

فون نيومان, ماكين, DeGuzman ، و جونسون-سميث من قاعدة العملاء الخاصة بك قد لا تحب نتيجة معالجة الخاص بك...

أيضا, أعتقد أن هذا هو المقصود أن يكون لمرة واحدة الترقية من البيانات ؟ قد يكون من الأسهل إلى التصدير, فلتر/أو تعديل و إعادة استيراد تصحيح أسماء في db ثم يمكنك استخدام SQL نهج تحديد اسم...

وهنا هو اختلاف آخر وجدت على منتديات SQLTeam.com @ http://www.sqlteam.com/forums/topic.asp؟TOPIC_ID= 47718

create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END

--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int

--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90

WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END

IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END

SET @ctr = @ctr + 1

WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END

END
RETURN @output
END



GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO

وأنا أعلم أن الشيطان يكمن في التفاصيل (وخصوصا حيث البيانات الشخصية الشعب هو المعني)، وأنه سيكون من الجميل جدا أن يكون رسملة صحيح أسماء، ولكن هذا النوع أعلاه من المتاعب هو السبب في عملي، والوقت واعية بيننا استخدم ما يلي:

وSELECT UPPER('Put YoUR O'So oddLy casED McWeird-nAme von rightHERE here')

في تجربتي، والناس على ما يرام رؤية اسمهم ... حتى عندما يكون في منتصف الطريق من خلال الجملة.

والرجوع إلى: الروس استخدام قلم رصاص

وعلمت للتو عن InitCap().

وهنا بعض التعليمات البرمجية:

SELECT ID
      ,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable

وهذا يعمل في SSMS:

Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]

والمقترضة وتحسنت علىRichard Sayakanit الجواب. هذا يتعامل مع كلمات متعددة. مثل جوابه، وهذا لا تستخدم أي UDFS، فقط المدمج في وظائف (STRING_SPLIT وSTRING_AGG) وانها سريعة جدا. يتطلب STRING_AGG SQL خادم 2017 ولكن يمكنك دائما استخدام خدعة STUFF/XML. لن التعامل مع كل استثناء ولكن يمكن العمل العظيم للعديد من المتطلبات.

SELECT StateName = 'North Carolina' 
INTO #States
UNION ALL
SELECT 'Texas'


;WITH cteData AS 
(
    SELECT 
        UPPER(LEFT(value, 1)) +
            LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
    FROM   #States op
    CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT 
    STRING_AGG(value, ' ')
FROM cteData c 
GROUP BY StateName

إذا كنت تعرف جميع البيانات هو مجرد كلمة واحدة هنا هو الحل. أولا تحديث العمود إلى كل الدنيا وثم تشغيل التالية

    update tableName set columnName = 
    upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName

تعديل طفيف إلى @Galwegian الجواب - الذي يتحول مثلا St Elizabeth's في St Elizabeth'S.

هذا التعديل يبقى الفاصلة-s كما صغيرة حيث s يأتي في نهاية السلسلة المقدمة أو s تليها مساحة (فقط في تلك الظروف).

create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
    declare @reset int;
    declare @ret varchar(8000);
    declare @i int;
    declare @c char(1);
    declare @d char(1);

    if @text is null
    return null;

    select @reset = 1, @i = 1, @ret = '';

    while (@i <= len(@text))
    select
        @c = substring(@text, @i, 1),
        @d = substring(@text, @i+1, 1),
        @ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
        @reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
        @i = @i + 1
    return @ret
end

فإنه يتحول:

st elizabeth's في St Elizabeth's
o'keefe في O'Keefe
o'sullivan في O'Sullivan

تعليقات الآخرين أن الحلول المختلفة من الأفضل عدم إدخال اللغة الإنجليزية تبقى هذه القضية.

مرخصة بموجب: CC-BY-SA مع الإسناد

لا تنتمي إلى StackOverflow