SQL Server: Faça todas as letras maiúsculas para maiúscula adequada Case /
-
04-07-2019 - |
Pergunta
Eu tenho uma tabela que foi importado como todos UPPER CASE e gostaria de transformá-lo em caso adequado. O roteiro se algum de vós tem usado para completar isso?
Solução
Aqui está um UDF que irá fazer o truque ...
create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
declare @Reset bit;
declare @Ret varchar(8000);
declare @i int;
declare @c char(1);
if @Text is null
return null;
select @Reset = 1, @i = 1, @Ret = '';
while (@i <= len(@Text))
select @c = substring(@Text, @i, 1),
@Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
@Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
@i = @i + 1
return @Ret
end
Você ainda vai ter que usá-lo para atualizar seus dados embora.
Outras dicas
Esta função:
- "Casos apropriado" Todas as palavras "UPPER caso" que são delimitados por espaços em branco
- folhas "palavras minúscula" por si só
- funciona corretamente mesmo para alfabetos não-inglês
- é portátil em que ele não usa características extravagantes de versões recentes do servidor SQL
- pode ser facilmente alterado para usar NCHAR e NVARCHAR para suporte a Unicode, bem como qualquer comprimento parâmetro você vê o ajuste
- definição espaço em branco pode ser configurado
CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
DECLARE @i INT -- index
DECLARE @l INT -- input length
DECLARE @c NCHAR(1) -- current char
DECLARE @f INT -- first letter flag (1/0)
DECLARE @o VARCHAR(255) -- output string
DECLARE @w VARCHAR(10) -- characters considered as white space
SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
SET @i = 1
SET @l = LEN(@string)
SET @f = 1
SET @o = ''
WHILE @i <= @l
BEGIN
SET @c = SUBSTRING(@string, @i, 1)
IF @f = 1
BEGIN
SET @o = @o + @c
SET @f = 0
END
ELSE
BEGIN
SET @o = @o + LOWER(@c)
END
IF @c LIKE @w SET @f = 1
SET @i = @i + 1
END
RETURN @o
END
Resultado:
dbo.ToProperCase('ALL UPPER CASE and SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and Some lower Ää Öö Üü Éé Øø Cc Ææ
UPDATE titles
SET title =
UPPER(LEFT(title, 1)) +
LOWER(RIGHT(title, LEN(title) - 1))
http://sqlmag.com/t-sql/how- título de caso de colunas de valor
Se você pode permitir que o CLR em SQL Server (requer 2005 ou posterior), então você poderia criar um função CLR que usa o TextInfo.ToTitleCase built-in função que lhe permitiria criar uma maneira cultura-consciente de fazer isso em apenas algumas linhas de código.
Eu sou um pouco tarde no jogo, mas acredito que esta é mais funcional e funciona com qualquer linguagem, incluindo russo, alemão, tailandês, vietnamita etc. Isso fará com que qualquer coisa maiúscula após "ou - ou. ou (ou) ou espaço (obviamente:).
CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos int = 1
, @pos2 int
if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
set @name = lower(rtrim(@name))
while (1 = 1)
begin
set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
set @pos += @pos2
if (isnull(@pos2, 0) = 0 or @pos > len(@name))
break
end
end
return @name
END
GO
Eu sei que este é posto no final desta discussão, mas, vale a pena olhar. Esta função funciona para mim sempre tempo. Então pensei em compartilhá-lo.
CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)
SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))
WHILE @Index <= LEN(@InputString)
BEGIN
SET @Char = SUBSTRING(@InputString, @Index, 1)
IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
IF @Index + 1 <= LEN(@InputString)
BEGIN
IF @Char != ''''
OR
UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
SET @OutputString =
STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
SET @Index = @Index + 1
END
RETURN ISNULL(@OutputString,'')
END
Test chama:
select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test
Resultado:
Se você estiver no SSIS importar dados que tem misturado encaixotado e necessidade de fazer uma pesquisa sobre uma coluna com a caixa adequada, você vai notar que a pesquisa falhar onde a fonte é misturado e a fonte de pesquisa é adequada. Você também vai notar que você não pode usar as funções direita e esquerda é SSIS para SQL Server 2008r2 para colunas derivadas. Aqui está uma solução que funciona para mim:
UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))
O link que eu postei acima é uma ótima opção que aborda a questão principal: que nunca podemos representam programaticamente para todos os casos (Smith-Jones, von Haussen, John Smith M.D.), pelo menos não de uma forma elegante. Tony introduz o conceito de um caráter de exceção / break para lidar com esses casos. De qualquer forma, com base na ideia de Cervo (superior todos caracteres menores precedido por espaço), as demonstrações substituir poderia ser embrulhado em uma única tabela com base substituir vez. Realmente, qualquer baixo / up caráter combinação poderia ser inserido em @alpha ea declaração não mudaria:
declare @str nvarchar(8000)
declare @alpha table (low nchar(1), up nchar(1))
set @str = 'ALL UPPER CASE and SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'
-- stage the alpha (needs number table)
insert into @alpha
-- A-Z / a-z
select nchar(n+32),
nchar(n)
from dbo.Number
where n between 65 and 90 or
n between 192 and 223
-- append space at start of str
set @str = lower(' ' + @str)
-- upper all lower case chars preceded by space
select @str = replace(@str, ' ' + low, ' ' + up)
from @Alpha
select @str
Aqui está uma versão que usa uma seqüência ou números de tabela em vez de um loop. Você pode modificar a cláusula WHERE que atendam às suas regras pessoais para quando converter um caractere para maiúsculas. Acabo incluiu um conjunto simples que irá superior caso de qualquer carta que é precedido por um não-carta com exceção de apóstrofos. Isso faz como sempre significam que 123apple teria um jogo no "a" porque "3" não é uma carta. Se você quer apenas white-space (espaço, guia, transporte de retorno, alimentação de linha), você pode substituir o '[^a-z]'
padrão com '[' + Char(32) + Char(9) + Char(13) + Char(10) + ']'
.
CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN
-- 1. Convert all letters to lower case
DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);
-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
FROM (
SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
FROM (SELECT 0 AS n UNION SELECT 1 UNION SELECT 2 UNION SELECT 3 UNION SELECT 4 UNION SELECT 5 UNION SELECT 6 UNION SELECT 7 UNION SELECT 8 UNION SELECT 9) AS n1
CROSS JOIN (SELECT 0 AS n UNION SELECT 10 UNION SELECT 20 UNION SELECT 30 UNION SELECT 40 UNION SELECT 50 UNION SELECT 60 UNION SELECT 70 UNION SELECT 80 UNION SELECT 90) AS n10
CROSS JOIN (SELECT 0 AS n UNION SELECT 100 UNION SELECT 200 UNION SELECT 300 UNION SELECT 400 UNION SELECT 500 UNION SELECT 600 UNION SELECT 700 UNION SELECT 800 UNION SELECT 900) AS n100
CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000) AS n1000
) AS Sequence
WHERE
n BETWEEN 1 AND Len( @InitCap )
AND SubString( @InitCap, n, 1 ) LIKE '[a-z]' /* this character is a letter */
AND (
n = 1 /* this character is the first `character` */
OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]' /* the previous character is NOT a letter */
)
AND (
n < 3 /* only test the 3rd or greater characters for this exception */
OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
)
-- 3. Return the modified version of the input
RETURN @InitCap
END
Não faria sentido manter uma pesquisa de exceções para cuidar de O von Neumann, McCain, DeGuzman de, e da Johnson-Smith.
Eu acho que você vai achar que o seguinte é mais eficiente:
IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
@str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
SET @str = ' ' + @str
SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
A declaração substituir poderia ser cortado e colado diretamente em uma consulta SQL. É ultra feio, no entanto, substituindo @str com a coluna que você está interessado, você não vai pagar um preço para um cursor implícito como você vai com as udfs assim postou. Acho que mesmo usando meu UDF é muito mais eficiente.
Oh e, em vez de gerar a declaração substituir pelo uso da mão com isto:
-- Code Generator for expression
DECLARE @x INT,
@c CHAR(1),
@sql VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
SET @c = CHAR(ASCII('a') + @x)
SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+ ''', '' ' + UPPER(@c) + ''')'
SET @x = @x + 1
END
PRINT @sql
De qualquer forma isso depende do número de linhas. Eu desejo que você poderia apenas fazer s / \ b ([a-z]) / uc $ 1 /, mas oh bem nós trabalhar com as ferramentas que temos.
NOTA você teria que usar isso como você teria que usá-lo como .... SELECIONAR dbo.ProperCase (INFERIOR (coluna)) desde que a coluna está em maiúsculas. Ele realmente funciona muito rápido na minha mesa de 5.000 entradas (nem mesmo um segundo), mesmo com a menor.
Em resposta à enxurrada de comentários sobre internacionalização eu apresento a seguinte implementação que lida com todos os caracteres ASCII contando apenas com Implementação de alta do SQL Server e abaixar. Lembre-se, as variáveis ??que estamos usando aqui estão VARCHAR o que significa que eles só podem conter valores ASCII. Para utilizar outros alfabetos internacionais, você tem que usar NVARCHAR. A lógica seria semelhante, mas você precisa usar Unicode e NCHAR no lugar de ASCII E CHAR ea declaração substituir seria muito mais enorme ....
-- Code Generator for expression
DECLARE @x INT,
@c CHAR(1),
@sql VARCHAR(8000),
@count INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
SET @c = CHAR(@x)
-- Only generate replacement expression for characters where upper and lowercase differ
IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
BEGIN
SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+ ''', '' ' + UPPER(@c) + ''')'
SET @count = @count + 1
END
SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)
Basicamente, a premissa do meu método está negociando pré-computação para a eficiência. A implementação ASCII completa é a seguinte:
IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
@str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
SET @str = ' ' + @str
SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
É tarde demais para voltar e obter os dados uppercased-un?
O von do de sua base de clientes Neumann, McCain, DeGuzman de, ea Johnson-Smith podem não gostar do resultado de seu processamento de ...
Além disso, eu estou supondo que este se destina a ser uma atualização em tempo um dos dados? Pode ser mais fácil para a exportação, filtro / modificar e re-importar os nomes corrigidos no db, e então você pode usar não-SQL se aproxima para citar fixação ...
Aqui é uma outra variação que encontrei na SQLTeam.com Fóruns @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID= 47.718
create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END
--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int
--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90
WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END
END
RETURN @output
END
GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO
Eu sei que o diabo está nos detalhes (especialmente no que se refere dados pessoais das pessoas), e que seria muito bom ter nomes adequadamente capitalizadas, mas o tipo acima de problemas é por isso que a pragmática, tempo consciente entre nós use o seguinte:
SELECT UPPER('Put YoUR O'So oddLy casED McWeird-nAme von rightHERE here')
Em minha experiência, as pessoas são muito bem ver que seu nome ... mesmo quando está a meio de uma frase.
Consulte: os russos usaram um lápis
Apenas aprendeu sobre InitCap()
.
Aqui está um código de exemplo:
SELECT ID
,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable
Isso funcionou no SSMS:
Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]
Borrowed e melhorado em resposta @ Richard Sayakanit. Este lida com várias palavras. Como sua resposta, este não usa nenhum UDFs, Only Built-in funções (STRING_SPLIT
e STRING_AGG
) e é muito rápido. STRING_AGG
requer SQL Server 2017, mas você sempre pode usar o truque STUFF/XML
. não vai lidar com cada exceção, mas pode funcionar muito bem para muitas exigências.
SELECT StateName = 'North Carolina'
INTO #States
UNION ALL
SELECT 'Texas'
;WITH cteData AS
(
SELECT
UPPER(LEFT(value, 1)) +
LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
FROM #States op
CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT
STRING_AGG(value, ' ')
FROM cteData c
GROUP BY StateName
Se você sabe todos os dados é apenas uma única palavra aqui é uma solução. Primeiro atualizar a coluna a todos inferior e, em seguida, execute o seguinte
update tableName set columnName =
upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName
Uma pequena modificação @ resposta de Galwegian - que se transforma por exemplo St Elizabeth's
em St Elizabeth'S
.
Esta modificação mantém apóstrofe-s como minúsculas onde o s vem no final da cadeia ou fornecida a s é seguido por um espaço (e só nestas condições).
create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
declare @reset int;
declare @ret varchar(8000);
declare @i int;
declare @c char(1);
declare @d char(1);
if @text is null
return null;
select @reset = 1, @i = 1, @ret = '';
while (@i <= len(@text))
select
@c = substring(@text, @i, 1),
@d = substring(@text, @i+1, 1),
@ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
@reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
@i = @i + 1
return @ret
end
Acontece:
-
st elizabeth's
emSt Elizabeth's
-
o'keefe
emO'Keefe
-
o'sullivan
emO'Sullivan
comentários Outro que diferentes soluções são preferíveis para a entrada de não-Inglês permanecem o caso.