SQL Server 2008中的视图是否实际复制了原始数据？

Question

如果我创建一个索引视图（在SQL Server 2008中），这是否意味着我将所有需要的数据从源表复制到单独的新表中？还是仅保存了一些小指针/索引来表示这种观点？

Answer 1

是的，数据将单独复制和存储，因此，如果修改基础表，则索引视图将自动更新。 这引起了很多锁的争论. 。同样，索引视图可能比基础表更大，并变得适得其反。

Answer 2

是的，数据已复制。其他数据库平台（例如Oracle）将其称为 物质视图 因为数据将 实现 变成物理形式。

Answer 3

当在视图上创建唯一的群集索引时，结果集存储在数据库中，就像存储带有群集索引的表一样。

由于对基础表中的数据进行了修改，因此数据修改反映在索引视图中存储的数据中

〜来自MSDN

Answer 4

您可以使用（无证件但广泛使用） DBCC PAGE 命令确切查看存储的内容。以下将创建索引视图并打印第一个数据页的内容。

SET NOCOUNT ON
IF OBJECT_ID('tempdb..#dbcc_ind') IS NOT NULL
    TRUNCATE TABLE #dbcc_ind
ELSE
    CREATE TABLE #dbcc_ind
    (PageFID  TINYINT, 
    PagePID INT,   
    IAMFID   TINYINT, 
    IAMPID  INT, 
    ObjectID  INT,
    IndexID  TINYINT,
    PartitionNumber TINYINT,
    PartitionID BIGINT,
    iam_chain_type  VARCHAR(30),    
    PageType  TINYINT, 
    IndexLevel  TINYINT,
    NextPageFID  TINYINT,
    NextPagePID  INT,
    PrevPageFID  TINYINT,
    PrevPagePID INT, 
    PRIMARY KEY (PageFID, PagePID));

IF OBJECT_ID('dbo.vtest') IS NULL
CREATE TABLE dbo.vtest (
i INT IDENTITY(1,1)  NOT NULL PRIMARY KEY,
c1 CHAR(500) NOT NULL DEFAULT REPLICATE('x',500), 
c2 CHAR(500) NOT NULL DEFAULT REPLICATE('y',500) 
)
GO

INSERT INTO dbo.vtest DEFAULT VALUES
GO 10

IF OBJECT_ID('dbo.ixViewTest') IS NULL
BEGIN
EXEC('CREATE VIEW dbo.ixViewTest
WITH SCHEMABINDING
AS
SELECT i,c1,c2
FROM dbo.vtest;')
EXEC('CREATE UNIQUE CLUSTERED INDEX [cix] ON [dbo].[ixViewTest] ([i] ASC)')
END
GO


DECLARE @command VARCHAR(1000)
SET @command = 'DBCC IND(' + QUOTENAME(DB_NAME()) + ', ixViewTest,1) WITH NO_INFOMSGS;'

INSERT INTO #dbcc_ind
    EXEC ( @command );


SELECT @command= 'DBCC PAGE (' + QUOTENAME(DB_NAME()) + ',' + CAST(PageFID AS VARCHAR(5)) + ',' + CAST(PagePID AS VARCHAR(10)) + ',1) ;'
FROM #dbcc_ind
WHERE PageType=1
 AND PrevPagePID=0


DBCC TRACEON(3604)
EXEC ( @command )
DBCC TRACEOFF(3604)