SQL Server 2008でのビューのインデックス付けは、実際に元のデータを複製していますか？

Question

（SQL Server 2008で）インデックスビューを作成した場合、これはソーステーブルからデータをすべて別の新しいテーブルにコピーする必要があることを意味しますか？または、このビューを表すために、いくつかの小さなポインター/インデックスのみが保存されていますか？

Answer 1

はい、データはコピーされて個別に保存されるため、基礎となるテーブルを変更すると、インデックスビューが自動的に更新されます。 これにより、多くのロック競合が発生します. 。また、インデックス付きビューは、基礎となるテーブルよりも大きくなり、逆効果になる場合があります。

Answer 2

はい、データがコピーされます。 Oracleなどの他のデータベースプラットフォームは、これを 具体化されたビュー データがそうなるからです 実現します 物理的な形に。

Answer 3

ビューで一意のクラスターインデックスが作成されると、結果セットは、クラスター化されたインデックスを備えたテーブルが保存されているように、データベースに保存されます。

ベーステーブルのデータに変更が加えられると、データの変更はインデックス付きビューに保存されているデータに反映されます

〜MSDNから

Answer 4

（文書化されていないが広く使用されている）を使用できます DBCC PAGE 何が保存されているかを正確に確認するコマンド。以下は、インデックス付きビューを作成し、最初のデータページの内容を印刷します。

SET NOCOUNT ON
IF OBJECT_ID('tempdb..#dbcc_ind') IS NOT NULL
    TRUNCATE TABLE #dbcc_ind
ELSE
    CREATE TABLE #dbcc_ind
    (PageFID  TINYINT, 
    PagePID INT,   
    IAMFID   TINYINT, 
    IAMPID  INT, 
    ObjectID  INT,
    IndexID  TINYINT,
    PartitionNumber TINYINT,
    PartitionID BIGINT,
    iam_chain_type  VARCHAR(30),    
    PageType  TINYINT, 
    IndexLevel  TINYINT,
    NextPageFID  TINYINT,
    NextPagePID  INT,
    PrevPageFID  TINYINT,
    PrevPagePID INT, 
    PRIMARY KEY (PageFID, PagePID));

IF OBJECT_ID('dbo.vtest') IS NULL
CREATE TABLE dbo.vtest (
i INT IDENTITY(1,1)  NOT NULL PRIMARY KEY,
c1 CHAR(500) NOT NULL DEFAULT REPLICATE('x',500), 
c2 CHAR(500) NOT NULL DEFAULT REPLICATE('y',500) 
)
GO

INSERT INTO dbo.vtest DEFAULT VALUES
GO 10

IF OBJECT_ID('dbo.ixViewTest') IS NULL
BEGIN
EXEC('CREATE VIEW dbo.ixViewTest
WITH SCHEMABINDING
AS
SELECT i,c1,c2
FROM dbo.vtest;')
EXEC('CREATE UNIQUE CLUSTERED INDEX [cix] ON [dbo].[ixViewTest] ([i] ASC)')
END
GO


DECLARE @command VARCHAR(1000)
SET @command = 'DBCC IND(' + QUOTENAME(DB_NAME()) + ', ixViewTest,1) WITH NO_INFOMSGS;'

INSERT INTO #dbcc_ind
    EXEC ( @command );


SELECT @command= 'DBCC PAGE (' + QUOTENAME(DB_NAME()) + ',' + CAST(PageFID AS VARCHAR(5)) + ',' + CAST(PagePID AS VARCHAR(10)) + ',1) ;'
FROM #dbcc_ind
WHERE PageType=1
 AND PrevPagePID=0


DBCC TRACEON(3604)
EXEC ( @command )
DBCC TRACEOFF(3604)