在商务类中使用财产与获取器/设定器

Question

在处理Buisness类时，例如典型的客户和员工课程，最好仅使用Getters和Setter或使用属性？

我正在转化Delphi（用于自学习）中的一些OO示例中的一些OO示例，在这些示例中，总是有getName（）和setName（），不使用属性。

现在，我可以看到，如果我创建具有已发布属性的组件，我有一个很好的理由使用属性，但是在正常类中，哪种方法更好？代码是否可以使用Getter和Setter（强调我们正在阅读/编写属性的事实）或属性（一见一见钟情可以与无参数方法混淆）更易读？

Answer 1

不。Getters和Setter仅在Java中出现，因为它没有属性。它为使用属性提供了更干净的代码。然后，如果您需要Getter或Setter，则可以将其构建到该属性中，但是您不必使用一堆功能调用用访问代码。

Answer 2

哇。属性比“他们只是为getter和setter方法包装”要多得多。

属性是一种优雅但功能强大的方法，可用于探索对课堂字段的控制。

访问字段

如前所述，您可以直接访问类字段。这确实非常好，并且使代码更清晰。这也是实现班级可行的第一版的非常好方法。

TMyClass = class
private
  FValue: String;
public
  property Value: String read FValue write FValue;
end; 

稍后，您可以重新设计课程以使用方法来验证和操纵字段访问。公共界面将仍然相同。

TMyClass = class
private
  FValue: String;
  procedure SetValue(AValue: String);
public
  property Value: String read FValue write SetValue;
end; 

procedure TMyClass.SetValue(AValue: String);
begin
  if AValue = '' 
  then FValue := 'No value!'
  else FValue := AValue;
end;

控制访问

属性为您提供了可读/写入字段的简单概述。例如，可读/不变的类：

TClient = class
private
  FName: String;
  FSite: String;
  FMail: String;
public
  constructor Create(AName, ASite, AMail: String);
  property Name: String read FName;
  property Site: String read FSite;
  property Mail: String read FMail;
end; 

多态性

TClient = class
private
  FName: String;
protected
  function GetName: String; virtual; abstract;
public
  property Name: String read GetName write FName;
end; 

TImportantClient = class(TClient)
protected
  function GetName: String; override;
end; 

TArgumentativeClient = class(TClient)
protected
  function GetName: String; override; 
end; 

function TImportantClient.GetName: String; 
begin
  Result := '+++ ' + FName;
end; 

function TArgumentativeClient.GetName: String; 
begin
  Result := ':-( ' + FName;
end; 

{----- ----- ----- ----- -----}
var
  ClientA,
  ClientB: TClient;
begin
  ClientA := TImportantClient.Create;
  ClientB := TArgumentativeClient.Create;

  ClientA.Name := 'Mr. Nice';
  ClientB.Name := 'Mr. Dumbhead';

  ShowMessage(ClientA.Name);
  ShowMessage(ClientB.Name);
end;
{----- ----- ----- ----- -----}

默认属性

在您的课程中，您可以定义默认类字段，这意味着您可以直接访问该字段而无需指定属性名称。

A := MyStringList[i]:
MyStringList[i] := B;

{ instead of }

A := MyStringList.Strings[i];
MyStringList.Strings[i] := B;

{ or }

A := MyStringList.GetString(i);
MyStringList.SetString(i, B);

指数

与 Index 关键字，Delphi将将常数值作为参数传递给Getter/Setter方法。

TMyRect = class
private
  FValues: Array[0..3] of Integer;
  function GetProperty(Index: Integer): Integer;
public
  property Top    : Integer  Index 0  read GetProperty;
  property Left   : Integer  Index 1  read GetProperty;
  property Width  : Integer  Index 2  read GetProperty;
  property Height : Integer  Index 3  read GetProperty;
end;


function TMyRect.GetProperty(Index: Integer): Integer;
begin
  Result := FValues[Index];
end; 

一些资源

仍然有一些涵盖的主题（实现接口，存储的值，RTTI/Design Time属性等），但是这篇文章开始越来越长...

可以在这些网站上阅读更多内容：

• http://www.delphibasics.co.uk
• http://delphi.about.com
• http://mc-computing.com

Answer 3

属性是Delphi的重要优势。我自己做了很多Java和Delphi，肯定会属于财产。实际上，两种方法最终都会做同样的事情，唯一的区别是，属性看起来比Getters/setters更加整洁。

我建议您获得财产，并充分利用它们！

Answer 4

这确实是一种口味和使用问题。

对于像程序员这样的Pascal，很明显，您是否正在阅读或编写一个值，因此我认为，如果您不以Java的方式使用getxxx或setxxx，则代码更可读您的程序。

对我而言，我假设大多数Pascal程序员，如果您只包含您正在阅读/写作的属性名称，则代码更可读，我们都知道将调用Getter或Setter方法（如有必要） 。

另外，我认为这是Delphi属性模型的巨大好处（和优雅），您可以直接从字段获得/设置属性值，以使用仅使用该值的代码行的许多GET/设置方法从字段分配或阅读的是浪费时间/时间。