SQL Server: Stellen Sie alle Großbuchstaben Proper Case / Titel Case
-
04-07-2019 - |
Frage
Ich habe eine Tabelle, die als Großbuchstaben importiert wurde, und ich möchte es in Proper Case einzuschalten. Was Skript haben von euch verwendet, um dieses zu vollenden?
Lösung
Hier ist ein UDF, die den Trick tun ...
create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
declare @Reset bit;
declare @Ret varchar(8000);
declare @i int;
declare @c char(1);
if @Text is null
return null;
select @Reset = 1, @i = 1, @Ret = '';
while (@i <= len(@Text))
select @c = substring(@Text, @i, 1),
@Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
@Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
@i = @i + 1
return @Ret
end
Sie werden nach wie vor, es benutzen müssen, obwohl Ihre Daten zu aktualisieren.
Andere Tipps
Diese Funktion:
- "Proper Cases" alle "UPPER CASE" Wörter, die durch Leerzeichen begrenzt sind
- Blätter "Kleinbuchstaben Worte" allein
- funktioniert auch für nicht-englische Buchstaben
- ist tragbar, dass sie keine Lust Funktionen der letzten SQL Server-Versionen verwenden, ist
- kann leicht geändert werden NCHAR und NVARCHAR für Unicode-Unterstützung zu verwenden, sowie alle Parameter Länge, die Sie für richtig halten
- weiß Raumdefinition kann so konfiguriert werden
CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
DECLARE @i INT -- index
DECLARE @l INT -- input length
DECLARE @c NCHAR(1) -- current char
DECLARE @f INT -- first letter flag (1/0)
DECLARE @o VARCHAR(255) -- output string
DECLARE @w VARCHAR(10) -- characters considered as white space
SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
SET @i = 1
SET @l = LEN(@string)
SET @f = 1
SET @o = ''
WHILE @i <= @l
BEGIN
SET @c = SUBSTRING(@string, @i, 1)
IF @f = 1
BEGIN
SET @o = @o + @c
SET @f = 0
END
ELSE
BEGIN
SET @o = @o + LOWER(@c)
END
IF @c LIKE @w SET @f = 1
SET @i = @i + 1
END
RETURN @o
END
Ergebnis:
dbo.ToProperCase('ALL UPPER CASE and SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and Some lower Ää Öö Üü Éé Øø Cc Ææ
UPDATE titles
SET title =
UPPER(LEFT(title, 1)) +
LOWER(RIGHT(title, LEN(title) - 1))
Wenn Sie die CLR in SQL Server aktivieren (erfordert 2005 oder später), dann könnten Sie TextInfo.ToTitleCase integrierte Funktion mit dem Sie eine Kultur-aware Art und Weise, dies zu tun in nur wenigen Zeilen Code zu erstellen erlauben würde.
Ich bin ein wenig spät im Spiel, aber ich glaube, das ist mehr funktionsfähig ist und es funktioniert mit jeder Sprache, einschließlich Russisch, Deutsch, Thai, Vietnamesisch usw. Es wird alles in Großbuchstaben machen, nachdem "oder - oder. oder (oder) oder Raum (natürlich:).
CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos int = 1
, @pos2 int
if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
set @name = lower(rtrim(@name))
while (1 = 1)
begin
set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
set @pos += @pos2
if (isnull(@pos2, 0) = 0 or @pos > len(@name))
break
end
end
return @name
END
GO
Ich weiß, das Ende der Post in diesem Thread ist aber, einen Blick wert. Diese Funktion ist für mich immer Zeit. So dachte, es zu teilen.
CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)
SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))
WHILE @Index <= LEN(@InputString)
BEGIN
SET @Char = SUBSTRING(@InputString, @Index, 1)
IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
IF @Index + 1 <= LEN(@InputString)
BEGIN
IF @Char != ''''
OR
UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
SET @OutputString =
STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
SET @Index = @Index + 1
END
RETURN ISNULL(@OutputString,'')
END
Test Anrufe:
select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test
Ergebnisse:
Wenn Sie in SSIS-Daten importieren, die verrohrte gemischt hat und brauchen einen Nachschlag auf einer Säule mit dem richtigen Fall zu tun, werden Sie feststellen, dass die Suche fehlschlägt, wo die Quelle gemischt und die Lookup-Quelle ist richtig. Sie werden auch bemerken Sie nicht die rechten und linken Funktionen verwenden können SSIS für SQL Server 2008r2 für abgeleitete Spalten. Hier ist eine Lösung, die funktioniert für mich:
UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))
Der Link, den ich oben geschrieben ist eine gute Option, die das Haupt-Problem behebt: dass wir nie programmatisch für alle Fälle erklären können (Smith-Jones, von Haussen, John Smith M. D.), zumindest nicht auf elegante Weise. Tony führt das Konzept einer Ausnahme / Pause-Zeichen mit diesen Fällen zu befassen. Wie auch immer, auf Cervo Idee Gebäude (oberer alle unteren Zeichen durch Leerzeichen vorangestellt), konnten die ersetzen Anweisungen in einer einzigen Tabelle eingewickelt werden, anstatt auf Basis ersetzen. Wirklich, jede low / up Zeichenkombination in @alpha eingeführt werden könnte und die Anweisung nicht ändern würde:
declare @str nvarchar(8000)
declare @alpha table (low nchar(1), up nchar(1))
set @str = 'ALL UPPER CASE and SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'
-- stage the alpha (needs number table)
insert into @alpha
-- A-Z / a-z
select nchar(n+32),
nchar(n)
from dbo.Number
where n between 65 and 90 or
n between 192 and 223
-- append space at start of str
set @str = lower(' ' + @str)
-- upper all lower case chars preceded by space
select @str = replace(@str, ' ' + low, ' ' + up)
from @Alpha
select @str
Hier ist eine Version, die eine Sequenz oder Nummern-Tabelle verwendet, anstatt eine Schleife. Sie können die WHERE-Klausel ändern Sie Ihre persönlichen Regeln für Hotel, wenn ein Zeichen in Großbuchstaben zu konvertieren. Ich habe enthalten nur einen einfachen Satz, das werden Großbuchstaben jeden Buchstaben, die von einem Nicht-Brief mit Ausnahme von Apostrophe ablaufen. Dies gilt, wie immer bedeutet, dass 123apple ein Spiel auf dem „a“ haben würde, weil „3“ nicht ein Brief. Wenn Sie nur white-space (Leerzeichen, Tabulator, Wagenrücklauf, Zeilenvorschub) möchten, können Sie das Muster '[^a-z]'
mit '[' + Char(32) + Char(9) + Char(13) + Char(10) + ']'
ersetzen.
CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN
-- 1. Convert all letters to lower case
DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);
-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
FROM (
SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
FROM (SELECT 0 AS n UNION SELECT 1 UNION SELECT 2 UNION SELECT 3 UNION SELECT 4 UNION SELECT 5 UNION SELECT 6 UNION SELECT 7 UNION SELECT 8 UNION SELECT 9) AS n1
CROSS JOIN (SELECT 0 AS n UNION SELECT 10 UNION SELECT 20 UNION SELECT 30 UNION SELECT 40 UNION SELECT 50 UNION SELECT 60 UNION SELECT 70 UNION SELECT 80 UNION SELECT 90) AS n10
CROSS JOIN (SELECT 0 AS n UNION SELECT 100 UNION SELECT 200 UNION SELECT 300 UNION SELECT 400 UNION SELECT 500 UNION SELECT 600 UNION SELECT 700 UNION SELECT 800 UNION SELECT 900) AS n100
CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000) AS n1000
) AS Sequence
WHERE
n BETWEEN 1 AND Len( @InitCap )
AND SubString( @InitCap, n, 1 ) LIKE '[a-z]' /* this character is a letter */
AND (
n = 1 /* this character is the first `character` */
OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]' /* the previous character is NOT a letter */
)
AND (
n < 3 /* only test the 3rd or greater characters for this exception */
OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
)
-- 3. Return the modified version of the input
RETURN @InitCap
END
Es wäre sinnvoll, einen Nachschlag von Ausnahmen zu halten, um kümmern sich um den von Neumanns, McCains, DeGuzman ist, und der Johnson-Smith.
Ich glaube, Sie werden feststellen, dass die folgende ist effizienter:
IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
@str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
SET @str = ' ' + @str
SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
Die ersetzen Anweisung geschnitten werden kann und direkt in eine SQL-Abfrage eingefügt. Es ist extrem hässlich, aber indem sie mit der Säule ersetzt @str Sie interessiert sind, werden Sie nicht einen Preis für einen impliziten Cursor zahlen, wie Sie mit der udfs werden so geschrieben. Ich finde, dass mein UDF selbst benutzen es viel effizienter ist.
Oh, und statt der ersetzen Anweisung von Hand Verwendung Erzeugung folgt aus:
-- Code Generator for expression
DECLARE @x INT,
@c CHAR(1),
@sql VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
SET @c = CHAR(ASCII('a') + @x)
SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+ ''', '' ' + UPPER(@c) + ''')'
SET @x = @x + 1
END
PRINT @sql
Auf jeden Fall hängt es von der Anzahl der Zeilen. Ich wünschte, Sie könnten nur tun s / \ b ([a-z]) / uc $ 1 /, aber na ja wir mit den Werkzeugen arbeiten wir haben.
HINWEIS würden Sie dies nutzen, wie Sie verwenden, müssten sie als .... SELECT dbo.ProperCase (LOWER (Spalte)), da die Spalte in Großbuchstaben ist. Es funktioniert tatsächlich ziemlich schnell auf meinem Tisch von 5000 Einträgen (nicht einmal eine Sekunde) auch mit dem unteren.
Als Reaktion auf die Flut von Kommentaren in Bezug auf Internationalisierung ich die folgende Implementierung vorstellen, die jede ASCII-Zeichen verarbeitet nur auf SQL Server Implementierung der oberen und unteren verlassen. Denken Sie daran, die Variablen verwenden wir hier VARCHAR sind, was bedeutet, dass sie nur ASCII-Werte halten kann. Um weitere internationale Alphabete zu verwenden, müssen Sie NVARCHAR verwenden. Die Logik wäre ähnlich, aber Sie würden verwenden müssen UNICODE und NCHAR anstelle von ASCII und Saibling und die Anweisung ersetzen wäre viel riesig ....
-- Code Generator for expression
DECLARE @x INT,
@c CHAR(1),
@sql VARCHAR(8000),
@count INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
SET @c = CHAR(@x)
-- Only generate replacement expression for characters where upper and lowercase differ
IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
BEGIN
SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+ ''', '' ' + UPPER(@c) + ''')'
SET @count = @count + 1
END
SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)
Grundsätzlich ist die Prämisse der meine Methode ist der Handel Pre-Computing für Effizienz. Die vollständige ASCII-Implementierung ist wie folgt:
IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
@str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
SET @str = ' ' + @str
SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
Ist es zu spät zurück zu gehen und die un-groß geschrieben Daten?
Der von Neumanns, McCains, DeGuzman ist, und der Johnson-Smith Ihre Kundenbasis kann das Ergebnis Ihrer Bearbeitung nicht mögen ...
Auch ich nehme an, dass dies beabsichtigt ist, eine einmalige Aktualisierung der Daten zu sein? Es könnte einfacher sein, zu exportieren, Filter / ändern, und Re-Import der korrigierten Namen in die db, und dann können Sie nicht-SQL Ansätze Namen Festsetzung verwenden ...
Hier ist eine weitere Variation ich auf den SQLTeam.com Forum gefunden @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID= 47718
create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END
--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int
--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90
WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END
END
RETURN @output
END
GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO
weiß, dass ich der Teufel im Detail ist (vor allem, wenn persönliche Daten des Menschen betreffen), und dass es wäre sehr schön, richtig Namen aktiviert hat, aber die obige Art von Ärger ist, warum die pragmatische und zeitbewussten unter uns verwenden Sie die folgenden Schritte aus:
SELECT UPPER('Put YoUR O'So oddLy casED McWeird-nAme von rightHERE here')
Nach meiner Erfahrung, die Menschen sind in Ordnung ihre Namen zu sehen ... auch wenn es auf halben Weg durch einen Satz.
Siehe: die Russen einen Bleistift benutzt
So gut wie InitCap()
gelernt.
Hier ist ein Beispielcode:
SELECT ID
,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable
Das funktionierte in SSMS:
Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]
Borrowed und verbessert auf @ Richard Sayakanit Antwort. Diese Griffe mehrere Wörter. Wie seine Antwort, diese verwendet keine UDF, nur integrierte Funktionen (STRING_SPLIT
und STRING_AGG
) und es ist ziemlich schnell. STRING_AGG
erfordert SQL Server 2017, aber Sie können immer den STUFF/XML
Trick verwenden. Wird nicht jede Ausnahme behandeln, kann aber für viele Anforderungen große Arbeit.
SELECT StateName = 'North Carolina'
INTO #States
UNION ALL
SELECT 'Texas'
;WITH cteData AS
(
SELECT
UPPER(LEFT(value, 1)) +
LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
FROM #States op
CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT
STRING_AGG(value, ' ')
FROM cteData c
GROUP BY StateName
Wenn Sie wissen alle Daten ist nur ein einziges Wort ist hier eine Lösung. Zuerst aktualisieren Sie die Spalte an alle unteren und führen Sie den folgenden
update tableName set columnName =
upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName
Eine leichte Modifikation @ Galwegian Antwort - die beispielsweise dreht St Elizabeth's
in St Elizabeth'S
.
Diese Modifikation hält Apostroph-s als Klein wo die s am Ende der Schnur vorgesehen kommt oder das S ist durch einen Raum (und nur unter diesen Umständen) gefolgt.
create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
declare @reset int;
declare @ret varchar(8000);
declare @i int;
declare @c char(1);
declare @d char(1);
if @text is null
return null;
select @reset = 1, @i = 1, @ret = '';
while (@i <= len(@text))
select
@c = substring(@text, @i, 1),
@d = substring(@text, @i+1, 1),
@ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
@reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
@i = @i + 1
return @ret
end
Es stellt sich:
-
st elizabeth's
inSt Elizabeth's
-
o'keefe
inO'Keefe
-
o'sullivan
inO'Sullivan
Andere Kommentare, dass verschiedene Lösungen bevorzugt, nicht-englischen Eingang sind noch der Fall ist.