Wie speichere ich ein 2D-Array in einem Hash in Perl?

Question

ich durch Objekte in Perl bin zu kämpfen, und ich versuche, einen 2D-Array zu erstellen und sie in einem Hash-Feld meines Objekts zu speichern. Ich verstehe, dass ein 2D-Array erstellen ich eine Reihe von Referenzen auf Arrays benötigen, aber wenn ich versuche, es mir diesen Fehler zu tun: Type of arg 1 to push must be array (not hash element) Der Konstruktor funktioniert gut, und set_seqs funktioniert gut, aber meine create_matrix Unter diesen Fehler wirft <. / p>

Hier ist, was ich tue:

sub new {
    my ($class) = @_;
    my $self = {};
    $self->{seq1} = undef;
    $self->{seq2} = undef;
    $self->{matrix} = ();
    bless($self, $class);
    return $self;
}
sub set_seqs {
    my $self = shift;
    $self->{seq1} = shift;
    $self->{seq2} = shift;
    print $self->{seq1};
}

sub create_matrix {
    my $self = shift;
    $self->set_seqs(shift, shift);
    #create the 2d array of scores
    #to create a matrix:
    #create a 2d array of length [lengthofseq1][lengthofseq2]
    for (my $i = 0; $i < length($self->{seq1}) - 1; $i++) {
        #push a new array reference onto the matrix
        #this line generates the error
        push(@$self->{matrix}, []);
    }
}

Jede Idee, was ich falsch mache?

Answer 1

Sie verpassen einen zusätzlichen Satz von Klammern, wenn Sie dereferenzieren $ self. Versuchen Sie push @{$self->{matrix}}, [].

Wenn Sie Zweifel haben (wenn Sie nicht sicher sind, ob Sie in einer komplizierten Datenstruktur auf den richtigen Wert sich beziehen), mehr Klammern hinzuzufügen. Siehe :) Perldoc perlreftut .

Answer 2

Perl ist eine sehr ausdrucksvoll, Sprache. Sie können unten mit der Aussage, dass alle.

$self->{matrix} = [ map { [ (0) x $seq2 ] } 1..$seq1 ];

Ist das Golf? Vielleicht, aber es auch vermeidet mit dem pingelig push Prototyp Ausmisten. Ich explodiere die Erklärung unter:

$self->{matrix} = [     # we want an array reference
    map {               # create a derivative list from the list you will pass it
        [ (0) x $seq2 ] # another array reference, using the *repeat* operator 
                        # in it's list form, thus creating a list of 0's as 
                        # long as the value given by $seq2, to fill out the  
                        # reference's values.
   } 
   1..$seq1             # we're not using the indexes as anything more than  
                        # control, so, use them base-1.
];                       # a completed array of arrays.

Ich habe ein Standard-Unterprogramm Tabellen zu machen:

sub make_matrix { 
    my ( $dim1, $dim2 ) = @_;
    my @table = map { [ ( 0 ) x $dim2 ] } 1..$dim1;
    return wantarray? @table : \@table;
}

Und hier ist eine verallgemeinerte Array-of-Arrays Funktion:

sub multidimensional_array { 
    my $dim = shift;
    return [ ( 0 ) x $dim ] unless @_; # edge case

    my @table = map { scalar multidimensional_array( @_ ) } 1..$dim;
    return wantarray ? @table : \@table;
}

Answer 3

sub create_matrix {
    my($self,$seq1,$seq2) = @_;
    $self->set_seqs($seq2, $seq2);

    #create the 2d array of scores
    #to create a matrix:
    #create a 2d array of length [$seq1][$seq2]
    for( 1..$seq1 ){
        push @{$self->{matrix}}, [ (undef) x $seq2 ];
    }
}