Как мне сохранить 2d-массив в хэше в Perl?

Question

Я пытаюсь разобраться с объектами в perl и пытаюсь создать 2d-массив и сохранить его в хэш-поле моего объекта.Я понимаю, что для создания 2d-массива мне нужен массив ссылок на массивы, но когда я пытаюсь это сделать, я получаю эту ошибку: Type of arg 1 to push must be array (not hash element) Конструктор работает нормально, и set_seqs работает нормально, но мой create_matrix sub выдает эти ошибки.

Вот что я делаю:

sub new {
    my ($class) = @_;
    my $self = {};
    $self->{seq1} = undef;
    $self->{seq2} = undef;
    $self->{matrix} = ();
    bless($self, $class);
    return $self;
}
sub set_seqs {
    my $self = shift;
    $self->{seq1} = shift;
    $self->{seq2} = shift;
    print $self->{seq1};
}

sub create_matrix {
    my $self = shift;
    $self->set_seqs(shift, shift);
    #create the 2d array of scores
    #to create a matrix:
    #create a 2d array of length [lengthofseq1][lengthofseq2]
    for (my $i = 0; $i < length($self->{seq1}) - 1; $i++) {
        #push a new array reference onto the matrix
        #this line generates the error
        push(@$self->{matrix}, []);
    }
}

Есть какие-нибудь идеи о том, что я делаю не так?

Answer 1

Вам не хватает дополнительного набора фигурных скобок, когда вы разыменовываете $self.Попробуй push @{$self->{matrix}}, [].

Если вы сомневаетесь (если вы не уверены, что ссылаетесь на правильное значение в сложной структуре данных), добавьте еще фигурные скобки.:) Смотрите perldoc перлрефтут.

Answer 2

Perl - это очень выразительный язык.Вы можете сделать все это с помощью приведенного ниже заявления.

$self->{matrix} = [ map { [ (0) x $seq2 ] } 1..$seq1 ];

Это гольф?Может быть, но это также избегает возни с привередливыми push прототип.Я приводлю приведенное ниже заявление:

$self->{matrix} = [     # we want an array reference
    map {               # create a derivative list from the list you will pass it
        [ (0) x $seq2 ] # another array reference, using the *repeat* operator 
                        # in it's list form, thus creating a list of 0's as 
                        # long as the value given by $seq2, to fill out the  
                        # reference's values.
   } 
   1..$seq1             # we're not using the indexes as anything more than  
                        # control, so, use them base-1.
];                       # a completed array of arrays.

У меня есть стандартная подпрограмма для создания таблиц:

sub make_matrix { 
    my ( $dim1, $dim2 ) = @_;
    my @table = map { [ ( 0 ) x $dim2 ] } 1..$dim1;
    return wantarray? @table : \@table;
}

А вот более обобщенная функция "массив из массивов":

sub multidimensional_array { 
    my $dim = shift;
    return [ ( 0 ) x $dim ] unless @_; # edge case

    my @table = map { scalar multidimensional_array( @_ ) } 1..$dim;
    return wantarray ? @table : \@table;
}

Answer 3

sub create_matrix {
    my($self,$seq1,$seq2) = @_;
    $self->set_seqs($seq2, $seq2);

    #create the 2d array of scores
    #to create a matrix:
    #create a 2d array of length [$seq1][$seq2]
    for( 1..$seq1 ){
        push @{$self->{matrix}}, [ (undef) x $seq2 ];
    }
}