Help to understand Pixelate effect

Question

I'm new a HLSL and I'm trying to understand a pixelate sample. However, I haven't been able to find a reference about how a couple of operations are. Here is the shader example:

//--------------------------------------------------------------------------------------
// 
// WPF ShaderEffect HLSL -- PixelateEffect
//
//--------------------------------------------------------------------------------------

//-----------------------------------------------------------------------------------------
// Shader constant register mappings (scalars - float, double, Point, Color, Point3D, etc.)
//-----------------------------------------------------------------------------------------

float HorizontalPixelCounts : register(C0);
float VerticalPixelCounts : register(C1);

//--------------------------------------------------------------------------------------
// Sampler Inputs (Brushes, including ImplicitInput)
//--------------------------------------------------------------------------------------

sampler2D implicitInputSampler : register(S0);


//--------------------------------------------------------------------------------------
// Pixel Shader
//--------------------------------------------------------------------------------------

float4 main(float2 uv : TEXCOORD) : COLOR
{
  float2 brickCounts = { HorizontalPixelCounts, VerticalPixelCounts };
  float2 brickSize = 1.0 / brickCounts;

  // Offset every other row of bricks
  float2 offsetuv = uv;
  bool oddRow = floor(offsetuv.y / brickSize.y) % 2.0 >= 1.0;
  if (oddRow)
  {
      offsetuv.x += brickSize.x / 2.0;
  }

  float2 brickNum = floor(offsetuv / brickSize);
  float2 centerOfBrick = brickNum * brickSize + brickSize / 2;
  float4 color = tex2D(implicitInputSampler, centerOfBrick);

  return color;
}

I haven't been able to understand what computation is happening in:

float2 brickNum = floor(offsetuv / brickSize);

I'm not sure what how to compute the division between the two vectors, and also I don't know how to compute the floor of a vector. (I'm assuming that division of two float2 returns a float2).

Any idea?

Answer 1

HLSL operators and functions often work with structures like float2 which has an x and y.

The division inside the floor returns a float2 where the x and y are the result of dividing the x with x and y with y. And floor will return a float2 where the x and y of the result are the floored value of the x and y of the input (the result of the division).

The same is true for float3 and other similar structures.