Enforce a DITA version for DITA Open Toolkit 1.5.2 XSLT stylesheet

StackOverflow https://stackoverflow.com/questions/4221109

Question

I have a .xsl that transforms xml from docbook to DITA. A problem that I'm running into, is that the .dita file thats created destroys xrefs. To fix that, I want to try to enforce a dita version during the transform ( I hope thats possible). So my question is: How do I have the transformed document respect DITA 1.2 when it is being transformed.

The transformation is from the DITA Open Toolkit 1.5.2 using the docbook2dita plugin Here's the current .xsl:

<?xml version="1.0" ?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" >
<xsl:import href="./xslt/ditabaseOutput.xsl"/>
<xsl:import href="./xslt/dbReader.xsl"/>

<xsl:output
    method="xml"
    indent="yes"
    omit-xml-declaration="no"
    standalone="no"
    doctype-public="-//OASIS//DTD DITA Composite//EN"
/>
<xsl:template match="/">
    <xsl:apply-templates select="." mode="topic.topic.in"/> 
</xsl:template>

</xsl:stylesheet>
Was it helpful?

Solution

XSLT 2.0 is ideal for validating the result of the transformation to a specific XML Schema. DTD validation isn't supported.

So, if you find an XML Schema for DITA (and there seems to be some DITA schema existing), you can validate it easily. Here is an example, taken from Michael Kay's book "XSLT 2.0 and XPath 2.0", how to perform validation of the result-document:

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="2.0" 
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
      xmlns="http://www.w3.org/1999/xhtml">

<xsl:import-schema namespace="http://www.w3.org/1999/xhtml" 
   schema-location="http://www.w3.org/2002/08/xhtml/xhtml1-strict.xsd"/>
<xsl:output method="xhtml" indent="yes"/>                   
<xsl:template match="/">
  <xsl:result-document validation="strict">
    <html>
      <head>
        <title><xsl:value-of select="poem/title"/></title>
      </head>
      <body>
        <h1 align="center"><xsl:value-of select="poem/title"/></h1>
        <p align="center"><i>by </i><xsl:value-of select="poem/author/name"/> 
          (<xsl:value-of select="poem/author/(birth,death)" separator="-"/>)</p>
        <xsl:for-each select="poem/stanza">
          <p>
            <xsl:for-each select="line">
              <xsl:value-of select="."/>
              <xsl:if test="position() != last()"><br/></xsl:if>
            </xsl:for-each>
          </p>
        </xsl:for-each>
      </body>
    </html>
  </xsl:result-document>
</xsl:template>                   
</xsl:stylesheet>

when this transformation is applied on the following XML document:

<?xml version="1.0"?>
<poem xmlns="http://poetry.org/ns" 
      xsi:schemaLocation="http://poetry.org/ns poem.xsd"
      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
   <author>
     <name>Rupert Brooke</name>
     <birth>1887-08-03</birth>
     <death>1915-04-23</death>
   </author>
   <date>1912</date>
   <title>The Hill</title>
   <stanza>
      <line>Breathless, we flung us on the windy hill,</line>
      <line>Laughed in the sun, and kissed the lovely grass.</line>
      <line>You said "Through glory and ecstasy we pass;</line>
      <line>Wind, sun, and earth remain, and birds sing still,</line>
      <line>When we are old, are old...." "And when we die</line>
      <line>All's over that is ours; and life burns on</line>
      <line>Through other lovers, other lips" said I,</line>
      <line>"Heart of my heart, our heaven is now, is won!"</line>
   </stanza>
   <stanza>
      <line>We are Earth's best, that learnt her lesson here.</line>
      <line>Life is our cry. We have kept the faith!" we said;</line>
      <line>"We shall go down with unreluctant tread</line>
      <line>Rose-crowned into the darkness!".... Proud we were,</line>
      <line>And laughed, that had such brave true things to say.</line>
      <line>-- And then you suddenly cried, and turned away.</line>
  </stanza>
</poem>

the Saxon EE 9.2.1.2 processor produces the following error messages:

SystemID: C:\Books\XSLT 2.0 and XPath 2.0\Downloads\Chapter4\ch04\poem-to-xhtml.xsl
Engine name: Saxon-EE 9.2.1.2
Severity: error
Description: Failed to compile stylesheet. 1 error detected.

SystemID: C:\Books\XSLT 2.0 and XPath 2.0\Downloads\Chapter4\ch04\poem-to-xhtml.xsl
Engine name: Saxon-EE 9.2.1.2
Severity: fatal
Description: Attribute align is not permitted in the content model of the complex type of element h1
Start location: 16:0
URL: http://www.w3.org/TR/xslt20/#err-XTTE1510

Here is a summary how to achieve XML Schema validation of the result document:

.1. Import at least one schema, for example:

<xsl:import-schema namespace="http://www.w3.org/1999/xhtml" 
   schema-location="http://www.w3.org/2002/08/xhtml/xhtml1-strict.xsd"/>

.2. On the <xsl:result-document> element specify strict validation, like this:

  <xsl:result-document validation="strict">
Licensed under: CC-BY-SA with attribution
Not affiliated with StackOverflow
scroll top