Perl archivo de lectura de un bucle while, a continuación, tratando de agregar los datos en el mes en un bucle foreach

Question

Tengo un espacio de archivo de texto delimitado estoy leyendo y estoy tratando de agregar los datos basándose en el mes, los datos se parece a esto:

Lun Abr 04 08:00:00 MDT 2011 120.72 0.3 0.707 25.609 25.609

Lun Abr 04 07:45:00 MDT 2011 119.94 0.3 0.707 25.443 25.443

Estoy tratando sume los totales mensuales:

#!/usr/bin/perl 

use strict;
use warnings;
use diagnostics;
use vars;

my $line;
my @data;
my @months;

my ($day, $month, $date, $time, $gmt, $year, $volt, $amp, $pf, $watt, $voltamp, 
    $voltsum, $wattsum, $count, $months, $monthlytotal );

$voltsum = 0;
$wattsum = 0;

open(DATAFILE, "@ARGV") ||  die $!;

@months = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );

            while (<DATAFILE>) {
            $line = $_;
            chomp $line;
            @data = split(/\s/,$line);
            $day = $data[0];
            $month = $data[1];
            $date = $data[2];
            $time = $data[3];
            $gmt = $data[4];
            $year = $data[5];
            $volt = $data[6];
            $amp = $data[7];
            $pf = $data[8];
            $watt = $data[9];
            $voltamp = $data[10];

Quiero coincidir con el mes, agregar mis datos, e imprimir el resultado una vez, pero a mi el control de flujo está mal, alguna idea de cómo hacer esto correctamente?

Quiero leer cada línea, prueba de que mes es, agregar similares todos los meses juntos, y devolver el resultado.

    foreach $months(@months) { 
       if ( $months =~ $month  ) {
                  $voltsum += $voltamp;
                  $wattsum += $watt;
            print "$month $year $wattsum $voltsum\n";
    }
            elsif ( $months !~ $month ) {
            $voltsum = 0;
            $wattsum = 0;

}
}

}
close (DATAFILE);



#               print "Month  Year Watts     Vars\n" ;
#               print "--------------------------\n";
#               print " $months $month    $year $wattsum $voltsum\n\n";

Answer 1

Puede beneficiarse de usar un módulo para analizar su marca de tiempo. Sin embargo, una solución simple podría ser hacer algo como esto:

my %sum;
while (<>) {  # instead of open on @ARGV, just use diamond operator
    my ($day, $month, $date, $time, $gmt, $year, $volt, $amp, 
        $pf, $watt, $voltamp) = split;
    $sum{"$year$month"}{'voltamp'} += $voltamp;
    $sum{"$year$month"}{'watt'} += $watt;
    ....
}

No es exactamente impermeable, pero podría satisfacer sus necesidades. Entonces simplemente puede extraer los datos del mes con

for my $month (keys %sum) {
    print "voltamp sum ($month): $sum{$month}{'voltamp'}\n";
    ....
}

Answer 2

La siguiente estructura de datos puede ser más apropiada (perldoc perldsc)

use warnings;
use strict;
use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

my %sums;
while (<DATA>) {
    my @tokens = split;
    $sums{$tokens[1]}{volt   } += $tokens[6];
    $sums{$tokens[1]}{amp    } += $tokens[7];
    $sums{$tokens[1]}{pf     } += $tokens[8];
    $sums{$tokens[1]}{watt   } += $tokens[9];
    $sums{$tokens[1]}{voltamp} += $tokens[10];
}

print Dumper(\%sums);

__DATA__
Mon Apr 04 08:00:00 MDT 2011 120.72 0.3 0.707 25.609 25.609
Mon Apr 04 07:45:00 MDT 2011 119.94 0.3 0.707 25.443 25.443

Imprime:

$VAR1 = {
          'Apr' => {
                     'amp' => '0.6',
                     'pf' => '1.414',
                     'volt' => '240.66',
                     'voltamp' => '51.052',
                     'watt' => '51.052'
                   }
        };

Answer 3

Si desea hacerlo transmitible, como se ve su programa, suponiendo que sus datos estén ordenados, primero debe introducir una variable para verificar el mes, que consiste en un mes+año. Esto es más seguro (abril de 2011 no es abril de 2012).

• Inicializar el "último mes registrado"
• Init suma donde sea necesario y resume.
• Imprimir cuando sea el momento de imprimir

Podría parecer:

my $last_month;

print "Month  Year Watts     Vars\n";
print "--------------------------\n";
while (<DATAFILE>) {
    # ... snip
    $voltamp = $data[10];

    my $current_month = $month . ' ' . $year; # Apr 2011 != Apr 2012
    if (!defined $last_month || $current_month ne $last_month) {
        # month changed
        if (defined $last_month) {
            # print intermediate sum
            print "$last_month $wattsum $voltsum\n";
        }
        $last_month = $current_month;
        $voltsum = 0;
        $wattsum = 0;
    }
    $voltsum += $voltamp;
    $wattsum += $watt;
}
print "$last_month $wattsum $voltsum\n"; # print last sum

Sin embargo, también preferiría resumir en un hash como las 2 respuestas recientes que surgieron mientras escribo esta, así que me salteo mi segunda solución.