Perl読み取りファイルを読み取り、その後、月にforeachループでデータを追加しようとしています

Question

私は読んでいるスペース区切りのテキストファイルを持っています、そして、月に基づいてデータを追加しようとしています、データは次のようになります。

Mon Apr 04 08:00:00 MDT 2011 120.72 0.3 0.707 25.609 25.609

Mon Apr 04 07:45:00 MDT 2011 119.94 0.3 0.707 25.443 25.443

私は毎月の合計を合計しようとしています：

#!/usr/bin/perl 

use strict;
use warnings;
use diagnostics;
use vars;

my $line;
my @data;
my @months;

my ($day, $month, $date, $time, $gmt, $year, $volt, $amp, $pf, $watt, $voltamp, 
    $voltsum, $wattsum, $count, $months, $monthlytotal );

$voltsum = 0;
$wattsum = 0;

open(DATAFILE, "@ARGV") ||  die $!;

@months = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );

            while (<DATAFILE>) {
            $line = $_;
            chomp $line;
            @data = split(/\s/,$line);
            $day = $data[0];
            $month = $data[1];
            $date = $data[2];
            $time = $data[3];
            $gmt = $data[4];
            $year = $data[5];
            $volt = $data[6];
            $amp = $data[7];
            $pf = $data[8];
            $watt = $data[9];
            $voltamp = $data[10];

月を一致させ、データを追加し、結果を一度印刷したいのですが、フロー制御が間違っています。これを正しく行う方法についての考えはありますか？

各行を読んで、どの月をテストし、同様の月をすべて一緒に追加し、結果を返したいと思います。

    foreach $months(@months) { 
       if ( $months =~ $month  ) {
                  $voltsum += $voltamp;
                  $wattsum += $watt;
            print "$month $year $wattsum $voltsum\n";
    }
            elsif ( $months !~ $month ) {
            $voltsum = 0;
            $wattsum = 0;

}
}

}
close (DATAFILE);



#               print "Month  Year Watts     Vars\n" ;
#               print "--------------------------\n";
#               print " $months $month    $year $wattsum $voltsum\n\n";

Answer 1

モジュールを使用してタイムスタンプを解析することで利益を得るかもしれません。ただし、簡単な修正は、次のようなことをすることかもしれません。

my %sum;
while (<>) {  # instead of open on @ARGV, just use diamond operator
    my ($day, $month, $date, $time, $gmt, $year, $volt, $amp, 
        $pf, $watt, $voltamp) = split;
    $sum{"$year$month"}{'voltamp'} += $voltamp;
    $sum{"$year$month"}{'watt'} += $watt;
    ....
}

正確には防水ではありませんが、ニーズに合っている可能性があります。次に、月のデータを単純に抽出できます

for my $month (keys %sum) {
    print "voltamp sum ($month): $sum{$month}{'voltamp'}\n";
    ....
}

Answer 2

次のデータ構造がより適切かもしれません（perldoc perldsc)

use warnings;
use strict;
use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

my %sums;
while (<DATA>) {
    my @tokens = split;
    $sums{$tokens[1]}{volt   } += $tokens[6];
    $sums{$tokens[1]}{amp    } += $tokens[7];
    $sums{$tokens[1]}{pf     } += $tokens[8];
    $sums{$tokens[1]}{watt   } += $tokens[9];
    $sums{$tokens[1]}{voltamp} += $tokens[10];
}

print Dumper(\%sums);

__DATA__
Mon Apr 04 08:00:00 MDT 2011 120.72 0.3 0.707 25.609 25.609
Mon Apr 04 07:45:00 MDT 2011 119.94 0.3 0.707 25.443 25.443

印刷：

$VAR1 = {
          'Apr' => {
                     'amp' => '0.6',
                     'pf' => '1.414',
                     'volt' => '240.66',
                     'voltamp' => '51.052',
                     'watt' => '51.052'
                   }
        };

Answer 3

プログラムが見えるようにストリーミング可能にしたい場合は、データがソートされていると仮定して、最初に月をチェックする変数を導入する必要があります。これはより安全です（2011年4月は2012年4月ではありません）。

• 「最後のチェック月間」を初期化する
• 必要に応じてinit合計と合計。
• 印刷時に印刷する時が来ました

見えるかもしれません：

my $last_month;

print "Month  Year Watts     Vars\n";
print "--------------------------\n";
while (<DATAFILE>) {
    # ... snip
    $voltamp = $data[10];

    my $current_month = $month . ' ' . $year; # Apr 2011 != Apr 2012
    if (!defined $last_month || $current_month ne $last_month) {
        # month changed
        if (defined $last_month) {
            # print intermediate sum
            print "$last_month $wattsum $voltsum\n";
        }
        $last_month = $current_month;
        $voltsum = 0;
        $wattsum = 0;
    }
    $voltsum += $voltamp;
    $wattsum += $watt;
}
print "$last_month $wattsum $voltsum\n"; # print last sum

ただし、これを書いている間に出てきた最近の2つの回答のようなハッシュで要約することを好むので、2番目のソリューションをスキップします。