Permutaciones generadoras en VBA.

Question

Esta pregunta se ha preguntado antes de , pero no puedo encontrar una respuesta que sea fácilmente aplicable a ExcelVBA.

Básicamente, quiero hacer exactamente lo que ha preguntado este cartel, pero en VBA.Quiero crear una matriz, N x 2 ^ N, donde cada línea representa una permutación diferente de las variables n que pueden ser 0 o 1.

He jugado con esto durante años, y es lo suficientemente fácil de hacer para un conjunto N con cargas de bucles, pero para una variable n no puedo encontrar nada que funcione.

¿Algún código o simplemente sugerencias de formas de hacerlo sobre esto sería muy apreciado!

Answer 1

Esto enumerará el valor en la columna a

Sub EasyAsCounting()
    Dim N As Long, M As Long, K As Long
    N = Application.InputBox(Prompt:="Enter N", Type:=1)
    M = 2 ^ N - 1
    For K = 0 To M
        Cells(K + 1, 1) = "'" & Application.WorksheetFunction.Dec2Bin(K, N)
    Next K
End Sub

Editar # 1

Esto almacena la matriz en vba solo:

Sub EasyAsCounting()
    Dim N As Long, M As Long, K As Long, ary, s As String
    Dim J As Long
    N = Application.InputBox(Prompt:="Enter N", Type:=1)
    M = 2 ^ N - 1
    ReDim ary(1 To M + 1, 1 To N)
    For K = 0 To M
        s = Application.WorksheetFunction.Dec2Bin(K, N)
        For J = 1 To N
            ary(K + 1, J) = Mid(s, J, 1)
        Next J
    Next K
    '
    'display the array
    '
    msg = ""
    For K = 1 To M + 1
        For J = 1 To N
            msg = msg & " " & ary(K, J)
        Next J
        msg = msg & vbCrLf
    Next K
    MsgBox msg
End Sub

Answer 2

Aquí hay uno si no está en Excel y no tiene acceso a las funciones.O si tiene un número mayor que 511.

Sub MakePerms()

    Dim i As Long, j As Long
    Dim n As Long
    Dim aPerms() As Byte
    Dim lCnt As Long
    Dim sOutput As String

    Const lVar As Long = 4

    ReDim aPerms(1 To 2 ^ lVar, 1 To lVar)

    For i = 0 To UBound(aPerms, 1) - 1
        n = i
        lCnt = lVar
        aPerms(i + 1, lCnt) = CByte(n Mod 2)
        n = n \ 2
        Do While n > 0
            lCnt = lCnt - 1
            aPerms(i + 1, lCnt) = CByte(n Mod 2)
            n = n \ 2
        Loop
    Next i

    For i = LBound(aPerms, 1) To UBound(aPerms, 1)
        sOutput = vbNullString
        For j = LBound(aPerms, 2) To UBound(aPerms, 2)
            sOutput = sOutput & Space(1) & aPerms(i, j)
        Next j
        Debug.Print sOutput
    Next i

End Sub