Generazione permutazioni in VBA

Question

Questa domanda è stata posta prima , ma non riesco a trovare una risposta che sia facilmente applicabile a ExcelVBA.

Fondamentalmente voglio fare esattamente cosa ha chiesto questo poster, ma in VBA.Voglio creare un array, n x 2 ^ n, dove ogni riga rappresenta una diversa permutazione di n variabili che possono essere 0 o 1.

Ho giocato in giro con questo da secoli, ed è abbastanza facile da fare per un set n con carichi di loop, ma per una variabile n non riesco a trovare nulla che funzioni.

Qualsiasi codice o semplicemente suggerimenti di modi per andare a riguardo questo sarebbe molto apprezzato!

Answer 1

Questo elencherà il valore nella colonna A

Sub EasyAsCounting()
    Dim N As Long, M As Long, K As Long
    N = Application.InputBox(Prompt:="Enter N", Type:=1)
    M = 2 ^ N - 1
    For K = 0 To M
        Cells(K + 1, 1) = "'" & Application.WorksheetFunction.Dec2Bin(K, N)
    Next K
End Sub

.

Modifica # 1

Questo memorizza l'array in VBA Solo:

Sub EasyAsCounting()
    Dim N As Long, M As Long, K As Long, ary, s As String
    Dim J As Long
    N = Application.InputBox(Prompt:="Enter N", Type:=1)
    M = 2 ^ N - 1
    ReDim ary(1 To M + 1, 1 To N)
    For K = 0 To M
        s = Application.WorksheetFunction.Dec2Bin(K, N)
        For J = 1 To N
            ary(K + 1, J) = Mid(s, J, 1)
        Next J
    Next K
    '
    'display the array
    '
    msg = ""
    For K = 1 To M + 1
        For J = 1 To N
            msg = msg & " " & ary(K, J)
        Next J
        msg = msg & vbCrLf
    Next K
    MsgBox msg
End Sub

.

Answer 2

Ecco uno se non sei in Excel e non hai accesso alle funzioni.O se hai un numero maggiore di 511.

Sub MakePerms()

    Dim i As Long, j As Long
    Dim n As Long
    Dim aPerms() As Byte
    Dim lCnt As Long
    Dim sOutput As String

    Const lVar As Long = 4

    ReDim aPerms(1 To 2 ^ lVar, 1 To lVar)

    For i = 0 To UBound(aPerms, 1) - 1
        n = i
        lCnt = lVar
        aPerms(i + 1, lCnt) = CByte(n Mod 2)
        n = n \ 2
        Do While n > 0
            lCnt = lCnt - 1
            aPerms(i + 1, lCnt) = CByte(n Mod 2)
            n = n \ 2
        Loop
    Next i

    For i = LBound(aPerms, 1) To UBound(aPerms, 1)
        sOutput = vbNullString
        For j = LBound(aPerms, 2) To UBound(aPerms, 2)
            sOutput = sOutput & Space(1) & aPerms(i, j)
        Next j
        Debug.Print sOutput
    Next i

End Sub

.