AutoIt: Activer et choisissez le menu contextuel des éléments dans ControlTreeView
-
27-09-2019 - |
Question
Je veux faire l'installation automatique par AutoIt. Je ne peux pas activer et choisissez le menu éléments sur l'étape « de sélection des fonctionnalités ». Je peux choisir un élément dans le « arbre ». Pour cela utiliser la fonction
ControlTreeView($windowId, "", $h_tree, "Select", "#2")
Comment activer et choisir le menu éléments dans ControlTreeView?
La solution 2
Vous pouvez voir la réponse à la question sur le site http://forum.oszone.net /thread-146460.html
#include <GuiMenu.au3>
#include <GuiTreeView.au3>
#Include <SendMessage.au3>
#Include <WindowsConstants.au3>
$WinTitle= "1С:Предприятие 8.1"
$WinText = "Выберите компоненты программы"
WinWait($WinTitle, $WinText)
; ищем элемент окна и последовательно нужный пункт списка
$hDTCtrl = ControlGetHandle($WinTitle, "", "SysTreeView321")
$hDTItem = _GUICtrlTreeView_FindItem($hDTCtrl, "Дополнительные интерфейсы")
$hDTIt_1 = _GUICtrlTreeView_FindItem($hDTCtrl, "Казахский", False, $hDTItem)
; активируем окно
WinActivate($WinTitle, $WinText)
WinWaitActive($WinTitle, $WinText)
; переходим к нужному пункту списка
_GUICtrlTreeView_SelectItem($hDTCtrl, $hDTIt_1, $TVGN_FIRSTVISIBLE)
_GUICtrlTreeView_ClickItem ($hDTCtrl, $hDTIt_1, "left", True)
; вызываем контекстное меню
$aRect = _GUICtrlTreeView_DisplayRect($hDTCtrl, $hDTIt_1, True)
ControlClick($WinTitle, $WinText, $hDTCtrl, "left", 1, $aRect[0]-10, $aRect[1]+5)
WinWait("[CLASS:#32768]")
; выбираем нужный пункт контекстного меню
$hWnd = WinGetHandle("[CLASS:#32768]")
$hMenu = _SendMessage($hWnd, $MN_GETHMENU, 0, 0)
$aRect = _GUICtrlMenu_GetItemRect($hWnd, $hMenu, 0)
MouseClick("left", $aRect[0]+20, $aRect[1]+15, 1, 1)
Autres conseils
Vous pouvez le faire avec le clavier.
Je l'ai fait dans le passé avec des
send("{down}{space}{down}{down}{enter}")
combinaison . Je sais que cela ne peut pas être la meilleure façon de le faire, mais cela fonctionnera.
Licencié sous: CC-BY-SA avec attribution
Non affilié à StackOverflow