AutoIt: Attivare e selezionare gli elementi menu di contesto in ControlTreeView
-
27-09-2019 - |
Domanda
voglio fare l'installazione automatica da AutoIt. Non posso attivare e scegliere il menu elementi sul gradino "selezionare le funzioni". Posso scegliere qualsiasi elemento della "albero". Perché io uso la funzione
ControlTreeView($windowId, "", $h_tree, "Select", "#2")
Come attivare e selezionare il menu di elementi in ControlTreeView?
Soluzione 2
È possibile vedere la risposta alla questione sul sito http://forum.oszone.net /thread-146460.html
#include <GuiMenu.au3>
#include <GuiTreeView.au3>
#Include <SendMessage.au3>
#Include <WindowsConstants.au3>
$WinTitle= "1С:Предприятие 8.1"
$WinText = "Выберите компоненты программы"
WinWait($WinTitle, $WinText)
; ищем элемент окна и последовательно нужный пункт списка
$hDTCtrl = ControlGetHandle($WinTitle, "", "SysTreeView321")
$hDTItem = _GUICtrlTreeView_FindItem($hDTCtrl, "Дополнительные интерфейсы")
$hDTIt_1 = _GUICtrlTreeView_FindItem($hDTCtrl, "Казахский", False, $hDTItem)
; активируем окно
WinActivate($WinTitle, $WinText)
WinWaitActive($WinTitle, $WinText)
; переходим к нужному пункту списка
_GUICtrlTreeView_SelectItem($hDTCtrl, $hDTIt_1, $TVGN_FIRSTVISIBLE)
_GUICtrlTreeView_ClickItem ($hDTCtrl, $hDTIt_1, "left", True)
; вызываем контекстное меню
$aRect = _GUICtrlTreeView_DisplayRect($hDTCtrl, $hDTIt_1, True)
ControlClick($WinTitle, $WinText, $hDTCtrl, "left", 1, $aRect[0]-10, $aRect[1]+5)
WinWait("[CLASS:#32768]")
; выбираем нужный пункт контекстного меню
$hWnd = WinGetHandle("[CLASS:#32768]")
$hMenu = _SendMessage($hWnd, $MN_GETHMENU, 0, 0)
$aRect = _GUICtrlMenu_GetItemRect($hWnd, $hMenu, 0)
MouseClick("left", $aRect[0]+20, $aRect[1]+15, 1, 1)
Altri suggerimenti
Si può farlo con la tastiera.
L'ho fatto in passato con con
send("{down}{space}{down}{down}{enter}")
combinazione. So che questo non può essere il modo migliore per farlo ma funzionerà.
Autorizzato sotto: CC-BY-SA insieme a attribuzione
Non affiliato a StackOverflow