Come funziona la derivazione in Haskell?

StackOverflow https://stackoverflow.com/questions/3864647

Domanda

Algebrico Tipi di dati (ADT) in Haskell possono diventare automaticamente istanze di alcuni typeclasss (come Show, Eq) di derivante da loro.

data  Maybe a  =  Nothing | Just a
  deriving (Eq, Ord)

La mia domanda è: come funziona? deriving lavoro, cioècome fa Haskell a sapere come implementare le funzioni della typeclass derivata per l'ADT derivante?

Inoltre, perché lo è deriving limitato solo a determinate classi tipografiche?Perché non posso scrivere la mia typeclass che può essere derivata?

È stato utile?

Soluzione

La risposta breve è: magia :-).Questo per dire che la derivazione automatica è integrata nelle specifiche Haskell e ogni compilatore può scegliere di implementarla a modo suo.C'è comunque molto lavoro su come renderlo estensibile.

Derivare è uno strumento per Haskell che ti consente di scrivere i tuoi meccanismi di derivazione.

GHC forniva un'estensione di classe di tipo derivabile chiamata Classi generiche, ma veniva usato raramente perché era un po' debole.Ora questo è stato eliminato e sono in corso i lavori per integrare un nuovo meccanismo di derivazione generico come descritto in questo documento: http://www.dreixel.net/research/pdf/gdmh.pdf

Per ulteriori informazioni, vedere:

Altri suggerimenti

Dal rapporto Haskell 98:

Le uniche classi nel Preludio per le quali sono consentite istanze derivate sono Eq, Ord, Enum, Bounded, Show e Read...

Ecco la descrizione di come derivare queste classi di tipo: http://www.haskell.org/onlinereport/derived.html#derived-appendice

È possibile utilizzare Modello Haskell per generare dichiarazioni di istanza in modo simile alle clausole-derivanti.

L'esempio seguente è spudoratamente rubato al file Wiki di Haskell:

In questo esempio utilizziamo il seguente codice Haskell

$(gen_render ''Body)

per produrre la seguente istanza:

instance TH_Render Body where
  render (NormalB exp) = build 'normalB exp
  render (GuardedB guards) = build 'guardedB  guards

La funzione gen_render sopra è definito come segue.(Nota che questo codice deve essere in un modulo separato dall'utilizzo di cui sopra). 

-- Generate an intance of the class TH_Render for the type typName
gen_render :: Name -> Q [Dec]
gen_render typName =
  do (TyConI d) <- reify typName -- Get all the information on the type
     (type_name,_,_,constructors) <- typeInfo (return d) -- extract name and constructors                  
     i_dec <- gen_instance (mkName "TH_Render") (conT type_name) constructors
                      -- generation function for method "render"
                      [(mkName "render", gen_render)]
     return [i_dec]  -- return the instance declaration
             -- function to generation the function body for a particular function
             -- and constructor
       where gen_render (conName, components) vars 
                 -- function name is based on constructor name  
               = let funcName = makeName $ unCapalize $ nameBase conName 
                 -- choose the correct builder function
                     headFunc = case vars of
                                     [] -> "func_out"
                                     otherwise -> "build" 
                      -- build 'funcName parm1 parm2 parm3 ...
                   in appsE $ (varE $ mkName headFunc):funcName:vars -- put it all together
             -- equivalent to 'funcStr where funcStr CONTAINS the name to be returned
             makeName funcStr = (appE (varE (mkName "mkName")) (litE $ StringL funcStr))

Che utilizza le seguenti funzioni e tipi.

Innanzitutto digita alcuni sinonimi per rendere il codice più leggibile.

type Constructor = (Name, [(Maybe Name, Type)]) -- the list of constructors
type Cons_vars = [ExpQ] -- A list of variables that bind in the constructor
type Function_body = ExpQ 
type Gen_func = Constructor -> Cons_vars -> Function_body
type Func_name = Name   -- The name of the instance function we will be creating
-- For each function in the instance we provide a generator function
-- to generate the function body (the body is generated for each constructor)
type Funcs = [(Func_name, Gen_func)]

La principale funzione riutilizzabile.Gli passiamo l'elenco delle funzioni per generare le funzioni dell'istanza.

-- construct an instance of class class_name for type for_type
-- funcs is a list of instance method names with a corresponding
-- function to build the method body
gen_instance :: Name -> TypeQ -> [Constructor] -> Funcs -> DecQ
gen_instance class_name for_type constructors funcs = 
  instanceD (cxt [])
    (appT (conT class_name) for_type)
    (map func_def funcs) 
      where func_def (func_name, gen_func) 
                = funD func_name -- method name
                  -- generate function body for each constructor
                  (map (gen_clause gen_func) constructors)

Una funzione di supporto di cui sopra.

-- Generate the pattern match and function body for a given method and
-- a given constructor. func_body is a function that generations the
-- function body
gen_clause :: (Constructor -> [ExpQ] -> ExpQ) -> Constructor -> ClauseQ
gen_clause func_body data_con@(con_name, components) = 
      -- create a parameter for each component of the constructor
   do vars <- mapM var components
      -- function (unnamed) that pattern matches the constructor 
      -- mapping each component to a value.
      (clause [(conP con_name (map varP vars))]
            (normalB (func_body data_con (map varE vars))) [])
       -- create a unique name for each component. 
       where var (_, typ) 
                 = newName 
                   $ case typ of 
                     (ConT name) -> toL $ nameBase name
                     otherwise   -> "parm"
               where toL (x:y) = (toLower x):y

unCapalize :: [Char] -> [Char]
unCapalize (x:y) = (toLower x):y

E qualche codice di supporto preso in prestito da Syb III / replib 0.2.

typeInfo :: DecQ -> Q (Name, [Name], [(Name, Int)], [(Name, [(Maybe Name, Type)])])
typeInfo m =
     do d <- m
        case d of
           d@(DataD _ _ _ _ _) ->
            return $ (simpleName $ name d, paramsA d, consA d, termsA d)
           d@(NewtypeD _ _ _ _ _) ->
            return $ (simpleName $ name d, paramsA d, consA d, termsA d)
           _ -> error ("derive: not a data type declaration: " ++ show d)

     where
        consA (DataD _ _ _ cs _)    = map conA cs
        consA (NewtypeD _ _ _ c _)  = [ conA c ]

        {- This part no longer works on 7.6.3
        paramsA (DataD _ _ ps _ _) = ps
        paramsA (NewtypeD _ _ ps _ _) = ps
        -}

        -- Use this on more recent GHC rather than the above
        paramsA (DataD _ _ ps _ _) = map nameFromTyVar ps
        paramsA (NewtypeD _ _ ps _ _) = map nameFromTyVar ps

        nameFromTyVar (PlainTV a) = a
        nameFromTyVar (KindedTV a _) = a


        termsA (DataD _ _ _ cs _) = map termA cs
        termsA (NewtypeD _ _ _ c _) = [ termA c ]

        termA (NormalC c xs)        = (c, map (\x -> (Nothing, snd x)) xs)
        termA (RecC c xs)           = (c, map (\(n, _, t) -> (Just $ simpleName n, t)) xs)
        termA (InfixC t1 c t2)      = (c, [(Nothing, snd t1), (Nothing, snd t2)])

        conA (NormalC c xs)         = (simpleName c, length xs)
        conA (RecC c xs)            = (simpleName c, length xs)
        conA (InfixC _ c _)         = (simpleName c, 2)

        name (DataD _ n _ _ _)      = n
        name (NewtypeD _ n _ _ _)   = n
        name d                      = error $ show d

simpleName :: Name -> Name
simpleName nm =
   let s = nameBase nm
   in case dropWhile (/=':') s of
        []          -> mkName s
        _:[]        -> mkName s
        _:t         -> mkName t
Autorizzato sotto: CC-BY-SA insieme a attribuzione
Non affiliato a StackOverflow
scroll top