Как выводят работу в Haskell?

StackOverflow https://stackoverflow.com/questions/3864647

Вопрос

Алгебраический Типы данных (ADTS) в Haskell может автоматически стать экземплярами некоторых TypeClasse.S (вроде Show, Eq) к выдвижение от них.

data  Maybe a  =  Nothing | Just a
  deriving (Eq, Ord)

Мой вопрос, как это deriving Работа, т.е. как Haskell знает, как реализовать функции производного TypeClass для вытекания ADT?

Кроме того, почему deriving Ограничено только определенные типовые опечатки? Почему я не могу написать свой собственный TypeClass, который может быть получен?

Это было полезно?

Решение

Краткий ответ - это волшебство :-). Это значит сказать, что автоматическое вытекание вытекается в спецификацию Haskell, а каждый компилятор может выбрать его по-своему. Там много работы над тем, как сделать его расширенным, однако.

Выводить это инструмент для Haskell, чтобы позволить вам написать свои собственные механизмы вывода.

GHC используется для предоставления расширительного расширения класса типа Общие классы, но он редко использовал, как это было несколько слабым. Это было выведено, и работа продолжается для интеграции нового генерального происхождения механизма, как описано в этой статье: http://www.dreixel.net/research/pdf/gdmh.pdf.

Для большего на этом см.:

Другие советы

От отчета Haskell 98:

Единственные классы в Prelude, для которых разрешены производные экземпляры, являются уравнением, ордина, enum, ограниченные, шоу и чтение ...

Вот описание того, как вывести эти классы этих типов: http://www.haskell.org/onlinerorport/derive.html#derived-appendix.

Можно использовать Шаблон haskell. генерировать декларации экземпляров аналогичным образом получения пунктов.

Следующий пример бесстыдно украден из Haskell Wiki.:

В этом примере мы используем следующий код HASKELL

$(gen_render ''Body)

Для получения следующего экземпляра:

instance TH_Render Body where
  render (NormalB exp) = build 'normalB exp
  render (GuardedB guards) = build 'guardedB  guards

Функция gen_render выше определяется следующим образом. (Обратите внимание, что этот код должен быть в отдельном модуле из вышеуказанного использования). 

-- Generate an intance of the class TH_Render for the type typName
gen_render :: Name -> Q [Dec]
gen_render typName =
  do (TyConI d) <- reify typName -- Get all the information on the type
     (type_name,_,_,constructors) <- typeInfo (return d) -- extract name and constructors                  
     i_dec <- gen_instance (mkName "TH_Render") (conT type_name) constructors
                      -- generation function for method "render"
                      [(mkName "render", gen_render)]
     return [i_dec]  -- return the instance declaration
             -- function to generation the function body for a particular function
             -- and constructor
       where gen_render (conName, components) vars 
                 -- function name is based on constructor name  
               = let funcName = makeName $ unCapalize $ nameBase conName 
                 -- choose the correct builder function
                     headFunc = case vars of
                                     [] -> "func_out"
                                     otherwise -> "build" 
                      -- build 'funcName parm1 parm2 parm3 ...
                   in appsE $ (varE $ mkName headFunc):funcName:vars -- put it all together
             -- equivalent to 'funcStr where funcStr CONTAINS the name to be returned
             makeName funcStr = (appE (varE (mkName "mkName")) (litE $ StringL funcStr))

Который использует следующие функции и типы.

Сначала некоторые виды синонимов, чтобы сделать код более читаемым.

type Constructor = (Name, [(Maybe Name, Type)]) -- the list of constructors
type Cons_vars = [ExpQ] -- A list of variables that bind in the constructor
type Function_body = ExpQ 
type Gen_func = Constructor -> Cons_vars -> Function_body
type Func_name = Name   -- The name of the instance function we will be creating
-- For each function in the instance we provide a generator function
-- to generate the function body (the body is generated for each constructor)
type Funcs = [(Func_name, Gen_func)]

Основная многоразовая функция. Мы пропускаем его список функций для создания функций экземпляра.

-- construct an instance of class class_name for type for_type
-- funcs is a list of instance method names with a corresponding
-- function to build the method body
gen_instance :: Name -> TypeQ -> [Constructor] -> Funcs -> DecQ
gen_instance class_name for_type constructors funcs = 
  instanceD (cxt [])
    (appT (conT class_name) for_type)
    (map func_def funcs) 
      where func_def (func_name, gen_func) 
                = funD func_name -- method name
                  -- generate function body for each constructor
                  (map (gen_clause gen_func) constructors)

Функция помощника выше.

-- Generate the pattern match and function body for a given method and
-- a given constructor. func_body is a function that generations the
-- function body
gen_clause :: (Constructor -> [ExpQ] -> ExpQ) -> Constructor -> ClauseQ
gen_clause func_body data_con@(con_name, components) = 
      -- create a parameter for each component of the constructor
   do vars <- mapM var components
      -- function (unnamed) that pattern matches the constructor 
      -- mapping each component to a value.
      (clause [(conP con_name (map varP vars))]
            (normalB (func_body data_con (map varE vars))) [])
       -- create a unique name for each component. 
       where var (_, typ) 
                 = newName 
                   $ case typ of 
                     (ConT name) -> toL $ nameBase name
                     otherwise   -> "parm"
               where toL (x:y) = (toLower x):y

unCapalize :: [Char] -> [Char]
unCapalize (x:y) = (toLower x):y

И некоторые заимствованные помощника, взятые из SYB III / Relib 0.2.

typeInfo :: DecQ -> Q (Name, [Name], [(Name, Int)], [(Name, [(Maybe Name, Type)])])
typeInfo m =
     do d <- m
        case d of
           d@(DataD _ _ _ _ _) ->
            return $ (simpleName $ name d, paramsA d, consA d, termsA d)
           d@(NewtypeD _ _ _ _ _) ->
            return $ (simpleName $ name d, paramsA d, consA d, termsA d)
           _ -> error ("derive: not a data type declaration: " ++ show d)

     where
        consA (DataD _ _ _ cs _)    = map conA cs
        consA (NewtypeD _ _ _ c _)  = [ conA c ]

        {- This part no longer works on 7.6.3
        paramsA (DataD _ _ ps _ _) = ps
        paramsA (NewtypeD _ _ ps _ _) = ps
        -}

        -- Use this on more recent GHC rather than the above
        paramsA (DataD _ _ ps _ _) = map nameFromTyVar ps
        paramsA (NewtypeD _ _ ps _ _) = map nameFromTyVar ps

        nameFromTyVar (PlainTV a) = a
        nameFromTyVar (KindedTV a _) = a


        termsA (DataD _ _ _ cs _) = map termA cs
        termsA (NewtypeD _ _ _ c _) = [ termA c ]

        termA (NormalC c xs)        = (c, map (\x -> (Nothing, snd x)) xs)
        termA (RecC c xs)           = (c, map (\(n, _, t) -> (Just $ simpleName n, t)) xs)
        termA (InfixC t1 c t2)      = (c, [(Nothing, snd t1), (Nothing, snd t2)])

        conA (NormalC c xs)         = (simpleName c, length xs)
        conA (RecC c xs)            = (simpleName c, length xs)
        conA (InfixC _ c _)         = (simpleName c, 2)

        name (DataD _ n _ _ _)      = n
        name (NewtypeD _ n _ _ _)   = n
        name d                      = error $ show d

simpleName :: Name -> Name
simpleName nm =
   let s = nameBase nm
   in case dropWhile (/=':') s of
        []          -> mkName s
        _:[]        -> mkName s
        _:t         -> mkName t
Лицензировано под: CC-BY-SA с атрибуция
Не связан с StackOverflow
scroll top