TCL: cerca in modo ricorsivo le sottodirectory per trovare tutti i file .tcl
-
06-07-2019 - |
Domanda
Ho un proc TCL principale che genera tonnellate di altri proc tcl in altre cartelle e successive sottodirectory. Ad esempio, nel proc principale ha:
source $basepath/folderA/1A.tcl
source $basepath/folderA/2A.tcl
source $basepath/folderA/3A.tcl
source $basepath/folderB/1B.tcl
source $basepath/folderB/2B.tcl
source $basepath/folderB/3B.tcl
e sembra un po 'stupido farlo in quel modo quando so sempre che avrò origine tutto nella cartella A e nella cartella B. Esiste una funzione (o un modo semplice) che mi consentirà di trovare tutti i file .tcl in un'intera cartella?
Soluzione
Basandosi sulla risposta di Ramanman, ecco una routine che affronta il problema usando i comandi del file TCL integrati e che funziona in modo ricorsivo lungo l'albero delle directory.
# findFiles
# basedir - the directory to start looking in
# pattern - A pattern, as defined by the glob command, that the files must match
proc findFiles { basedir pattern } {
# Fix the directory name, this ensures the directory name is in the
# native format for the platform and contains a final directory seperator
set basedir [string trimright [file join [file normalize $basedir] { }]]
set fileList {}
# Look in the current directory for matching files, -type {f r}
# means ony readable normal files are looked at, -nocomplain stops
# an error being thrown if the returned list is empty
foreach fileName [glob -nocomplain -type {f r} -path $basedir $pattern] {
lappend fileList $fileName
}
# Now look for any sub direcories in the current directory
foreach dirName [glob -nocomplain -type {d r} -path $basedir *] {
# Recusively call the routine on the sub directory and append any
# new files to the results
set subDirList [findFiles $dirName $pattern]
if { [llength $subDirList] > 0 } {
foreach subDirFile $subDirList {
lappend fileList $subDirFile
}
}
}
return $fileList
}
Altri suggerimenti
Diventa banale con tcllib a bordo:
package require fileutil
foreach file [fileutil::findByPattern $basepath *.tcl] {
source $file
}
Forse un po 'più indipendente dalla piattaforma e utilizza i comandi integrati invece di eseguire il piping a un processo:
foreach script [glob [file join $basepath folderA *.tcl]] {
source $script
}
Ripeti per la cartellaB.
Se hai criteri di selezione più rigorosi e non preoccuparti di eseguire su qualsiasi altra piattaforma, l'utilizzo di find potrebbe essere più flessibile.
Sulla base di una risposta precedente, questa versione gestisce i cicli creati da collegamenti simbolici e nel processo elimina anche i file duplicati dovuti a collegamenti simbolici.
# findFiles
# basedir - the directory to start looking in
# pattern - A pattern, as defined by the glob command, that the files must match
proc findFiles {directory pattern} {
# Fix the directory name, this ensures the directory name is in the
# native format for the platform and contains a final directory seperator
set directory [string trimright [file join [file normalize $directory] { }]]
# Starting with the passed in directory, do a breadth first search for
# subdirectories. Avoid cycles by normalizing all file paths and checking
# for duplicates at each level.
set directories [list]
set parents $directory
while {[llength $parents] > 0} {
# Find all the children at the current level
set children [list]
foreach parent $parents {
set children [concat $children [glob -nocomplain -type {d r} -path $parent *]]
}
# Normalize the children
set length [llength $children]
for {set i 0} {$i < $length} {incr i} {
lset children $i [string trimright [file join [file normalize [lindex $children $i]] { }]]
}
# Make the list of children unique
set children [lsort -unique $children]
# Find the children that are not duplicates, use them for the next level
set parents [list]
foreach child $children {
if {[lsearch -sorted $directories $child] == -1} {
lappend parents $child
}
}
# Append the next level directories to the complete list
set directories [lsort -unique [concat $directories $parents]]
}
# Get all the files in the passed in directory and all its subdirectories
set result [list]
foreach directory $directories {
set result [concat $result [glob -nocomplain -type {f r} -path $directory -- $pattern]]
}
# Normalize the filenames
set length [llength $result]
for {set i 0} {$i < $length} {incr i} {
lset result $i [file normalize [lindex $result $i]]
}
# Return only unique filenames
return [lsort -unique $result]
}
Stessa idea di schlenk:
package require Tclx
for_recursive_glob scriptName $basepath *.tcl {
source $scriptName
}
Se si desidera solo la cartella A e la cartella B e non altre cartelle in $ basepath:
package require Tclx
for_recursive_glob scriptName [list $basepath/folderA $basepath/folderB] *.tcl {
source $scriptName
}
Ecco un modo:
set includes [open "|find $basedir -name \*.tcl -print" r]
while { [gets $includes include] >= 0 } {
source $include
}
close $includes
La risposta di Joseph Bui funziona bene tranne per il fatto che salta i file nella cartella iniziale.
Cambio:
set directories [list]A:
set directories [list $directory]
per correggere