TCL:サブディレクトリを再帰的に検索して、すべての.tclファイルを取得します
-
06-07-2019 - |
質問
メインのTCLプロシージャがあり、他のフォルダおよび後続のサブディレクトリにある他のtclプロシージャを大量に取得しています。たとえば、メインプロシージャでは次のようになります。
source $basepath/folderA/1A.tcl
source $basepath/folderA/2A.tcl
source $basepath/folderA/3A.tcl
source $basepath/folderB/1B.tcl
source $basepath/folderB/2B.tcl
source $basepath/folderB/3B.tcl
そして、私がfolderAとfolderBのすべてを調達することを常に知っているとき、それをそのように行うのは一種の愚かなことのようです。フォルダー全体のすべての.tclファイルを取得できる機能(または簡単な方法)はありますか?
解決
ramanmanの応答に基づいて、組み込みのTCLファイルコマンドを使用して問題に対処し、ディレクトリツリーを再帰的に処理するルーチンを示します。
# findFiles
# basedir - the directory to start looking in
# pattern - A pattern, as defined by the glob command, that the files must match
proc findFiles { basedir pattern } {
# Fix the directory name, this ensures the directory name is in the
# native format for the platform and contains a final directory seperator
set basedir [string trimright [file join [file normalize $basedir] { }]]
set fileList {}
# Look in the current directory for matching files, -type {f r}
# means ony readable normal files are looked at, -nocomplain stops
# an error being thrown if the returned list is empty
foreach fileName [glob -nocomplain -type {f r} -path $basedir $pattern] {
lappend fileList $fileName
}
# Now look for any sub direcories in the current directory
foreach dirName [glob -nocomplain -type {d r} -path $basedir *] {
# Recusively call the routine on the sub directory and append any
# new files to the results
set subDirList [findFiles $dirName $pattern]
if { [llength $subDirList] > 0 } {
foreach subDirFile $subDirList {
lappend fileList $subDirFile
}
}
}
return $fileList
}
他のヒント
tcllibをオンボードで使用すると簡単になります:
package require fileutil
foreach file [fileutil::findByPattern $basepath *.tcl] {
source $file
}
おそらく、もう少しプラットフォームに依存せず、プロセスにパイプする代わりに組み込みコマンドを使用します:
foreach script [glob [file join $basepath folderA *.tcl]] {
source $script
}
folderBに対して繰り返します。
より厳しい選択基準があり、他のプラットフォームでの実行を心配しない場合は、findを使用するとより柔軟になります。
以前の回答に基づいて、このバージョンはシンボリックリンクによって作成されたサイクルを処理し、その過程でシンボリックリンクによる重複ファイルも排除します。
# findFiles
# basedir - the directory to start looking in
# pattern - A pattern, as defined by the glob command, that the files must match
proc findFiles {directory pattern} {
# Fix the directory name, this ensures the directory name is in the
# native format for the platform and contains a final directory seperator
set directory [string trimright [file join [file normalize $directory] { }]]
# Starting with the passed in directory, do a breadth first search for
# subdirectories. Avoid cycles by normalizing all file paths and checking
# for duplicates at each level.
set directories [list]
set parents $directory
while {[llength $parents] > 0} {
# Find all the children at the current level
set children [list]
foreach parent $parents {
set children [concat $children [glob -nocomplain -type {d r} -path $parent *]]
}
# Normalize the children
set length [llength $children]
for {set i 0} {$i < $length} {incr i} {
lset children $i [string trimright [file join [file normalize [lindex $children $i]] { }]]
}
# Make the list of children unique
set children [lsort -unique $children]
# Find the children that are not duplicates, use them for the next level
set parents [list]
foreach child $children {
if {[lsearch -sorted $directories $child] == -1} {
lappend parents $child
}
}
# Append the next level directories to the complete list
set directories [lsort -unique [concat $directories $parents]]
}
# Get all the files in the passed in directory and all its subdirectories
set result [list]
foreach directory $directories {
set result [concat $result [glob -nocomplain -type {f r} -path $directory -- $pattern]]
}
# Normalize the filenames
set length [llength $result]
for {set i 0} {$i < $length} {incr i} {
lset result $i [file normalize [lindex $result $i]]
}
# Return only unique filenames
return [lsort -unique $result]
}
schlenkと同じアイデア:
package require Tclx
for_recursive_glob scriptName $basepath *.tcl {
source $scriptName
}
folderAとfolderBのみが必要で、$ basepathの下の他のフォルダーは必要ない場合:
package require Tclx
for_recursive_glob scriptName [list $basepath/folderA $basepath/folderB] *.tcl {
source $scriptName
}
ここに1つの方法があります:
set includes [open "|find $basedir -name \*.tcl -print" r]
while { [gets $includes include] >= 0 } {
source $include
}
close $includes
Joseph Buiの答えは、初期フォルダーのファイルをスキップすることを除いて、うまく機能します。
変更:
set directories [list]に:
set directories [list $directory]
修正する
所属していません StackOverflow