Erlang での URL エンコード

StackOverflow https://stackoverflow.com/questions/114196

  •  02-07-2019
  •  | 
  •  

質問

erlang http:request を使用して、リモート サービスにデータを投稿しています。投稿は機能していますが、投稿の body() 内のデータは URL エンコードなしでそのまま渡されるため、リモート サービスによる解析時に投稿が失敗します。

この目的のために Ruby の CGI.escape に似た関数が Erlang にありますか?

役に立ちましたか？

解決

ここで見つけることができます YAWS url_encode ルーチンと url_decode ルーチン

これらは非常に単純ですが、コメントはエンコードがすべての句読点文字に対して 100% 完了していないことを示しています。

他のヒント

HTTP モジュールにもこの機能がないことに気づきました。

この機能は実際には erlang ディストリビューションで利用できることがわかりました。よく調べてみる必要があります。

> edoc_lib:escape_uri("luca+more@here.com").
"luca%2bmore%40here.com"

これは Ruby の CGI.escape と同じように動作しますが、少し異なる動作をする URI.escape もあります。

> CGI.escape("luca+more@here.com")
 => "luca%2Bmore%40here.com" 
> URI.escape("luca+more@here.com")
 => "luca+more@here.com"

edoc_lib

少なくともR15にはある http_uri:エンコード/1 それが仕事をするのです。また、edoc_lib:escape_uri を使用すると、'=' が %3D ではなく %3d に変換され、問題が発生するため、使用はお勧めしません。

これはその仕事を行う単純な関数です。inets httpc と直接連携するように設計されています。

%% @doc A function to URL encode form data.
%% @spec url_encode(formdata()).

-spec(url_encode(formdata()) -> string()).
url_encode(Data) ->
    url_encode(Data,"").

url_encode([],Acc) ->
    Acc;

url_encode([{Key,Value}|R],"") ->
    url_encode(R, edoc_lib:escape_uri(Key) ++ "=" ++ edoc_lib:escape_uri(Value));
url_encode([{Key,Value}|R],Acc) ->
    url_encode(R, Acc ++ "&" ++ edoc_lib:escape_uri(Key) ++ "=" ++ edoc_lib:escape_uri(Value)).

使用例: 

httpc:request(post, {"http://localhost:3000/foo", [], 
                    "application/x-www-form-urlencoded",
                    url_encode([{"username", "bob"}, {"password", "123456"}])}
             ,[],[]).

私自身の質問に答えるために...ibrowse でこのライブラリを見つけました。

http://www.erlware.org/lib/5.6.3/ibrowse-1.4/ibrowse_lib.html#url_encode-1

url_encode/1

url_encode(Str) -> UrlEncodedStr

Str = string()
UrlEncodedStr = string()

RFC 1738 に基づいて文字列を URL エンコードします。フラットなリストを返します。

これを使用してエンコードを実行し、引き続き http を使用できると思います。

誰かが erlang で utf-8 で動作する URI をエンコードする必要がある場合:

https://gist.github.com/3796470

元。

Eshell V5.9.1  (abort with ^G)

1> c(encode_uri_rfc3986).
{ok,encode_uri_rfc3986}

2> encode_uri_rfc3986:encode("テスト").
"%e3%83%86%e3%82%b9%e3%83%88"

3> edoc_lib:escape_uri("テスト").
"%c3%86%c2%b9%c3%88" # output wrong: ƹÈ

これは、edoc_lib:escape_uri 関数の「フォーク」で、UTF-8 サポートを改善し、バイナリもサポートします。 

escape_uri(S) when is_list(S) ->
    escape_uri(unicode:characters_to_binary(S));
escape_uri(<<C:8, Cs/binary>>) when C >= $a, C =< $z ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C >= $A, C =< $Z ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C >= $0, C =< $9 ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $. ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $- ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $_ ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) ->
    escape_byte(C) ++ escape_uri(Cs);
escape_uri(<<>>) ->
    "".

escape_byte(C) ->
    "%" ++ hex_octet(C).

hex_octet(N) when N =< 9 ->
    [$0 + N];
hex_octet(N) when N > 15 ->
    hex_octet(N bsr 4) ++ hex_octet(N band 15);
hex_octet(N) ->
    [N - 10 + $a].

unicode:characters_to_binary を使用しているため、R13 以降でのみ動作することに注意してください。

私の知る限り、標準ライブラリには URL エンコーダはありません。次のコードを YAWS またはおそらく他の Erlang Web サーバーのいずれかから「借用」したと思います。

% Utility function to convert a 'form' of name-value pairs into a URL encoded
% content string.

urlencode(Form) ->
    RevPairs = lists:foldl(fun({K,V},Acc) -> [[quote_plus(K),$=,quote_plus(V)] | Acc] end, [],Form),
    lists:flatten(revjoin(RevPairs,$&,[])).

quote_plus(Atom) when is_atom(Atom) ->
    quote_plus(atom_to_list(Atom));

quote_plus(Int) when is_integer(Int) ->
    quote_plus(integer_to_list(Int));

quote_plus(String) ->
    quote_plus(String, []).

quote_plus([], Acc) ->
    lists:reverse(Acc);

quote_plus([C | Rest], Acc) when ?QS_SAFE(C) ->
    quote_plus(Rest, [C | Acc]);

quote_plus([$\s | Rest], Acc) ->
    quote_plus(Rest, [$+ | Acc]);

quote_plus([C | Rest], Acc) ->
    <<Hi:4, Lo:4>> = <<C>>,
    quote_plus(Rest, [hexdigit(Lo), hexdigit(Hi), ?PERCENT | Acc]).

revjoin([], _Separator, Acc) ->
    Acc;

revjoin([S | Rest],Separator,[]) ->
    revjoin(Rest,Separator,[S]);

revjoin([S | Rest],Separator,Acc) ->
    revjoin(Rest,Separator,[S,Separator | Acc]).

hexdigit(C) when C < 10 -> $0 + C;
hexdigit(C) when C < 16 -> $A + (C - 10).
ライセンス： CC-BY-SA と 帰属
所属していません StackOverflow
scroll top