URL codificar em Erlang

Question

Eu estou usando erlang http: pedido para postar alguns dados para um serviço remoto. Eu tenho o posto de trabalho, mas os dados no corpo () do post vem através como é, sem qualquer codificação url que faz com que o post para falhar quando analisado pelo serviço remoto.

Existe uma função em Erlang que é semelhante ao cgi.escape em Ruby para este fim?

Answer 1

Você pode encontrar aqui a bouba url_encode e url_decode rotinas

Eles são bastante simples, embora comentários indicam a codificação não está 100% concluída para todos os caracteres de pontuação.

Answer 2

Eu encontrei a falta desse recurso no HTTP módulos também.

Acontece que esta funcionalidade está realmente disponível na distribuição erlang, você só tem que olhar duro o suficiente.

> edoc_lib:escape_uri("luca+more@here.com").
"luca%2bmore%40here.com"

Este se comporta como cgi.escape em Ruby, há também URI.escape que se comporta de forma ligeiramente diferente:

> CGI.escape("luca+more@here.com")
 => "luca%2Bmore%40here.com" 
> URI.escape("luca+more@here.com")
 => "luca+more@here.com" 

edoc_lib

Answer 3

Pelo menos em R15 existe http_uri: codificação / 1 que faz o trabalho. Eu também não recomendo o uso edoc_lib: escape_uri como traduzir um '=' a um% 3d em vez de uma% 3D que me causou alguns problemas.

Answer 4

Aqui está uma função simples que faz o trabalho. Ele foi projetado para trabalhar diretamente com inets httpc.

%% @doc A function to URL encode form data.
%% @spec url_encode(formdata()).

-spec(url_encode(formdata()) -> string()).
url_encode(Data) ->
    url_encode(Data,"").

url_encode([],Acc) ->
    Acc;

url_encode([{Key,Value}|R],"") ->
    url_encode(R, edoc_lib:escape_uri(Key) ++ "=" ++ edoc_lib:escape_uri(Value));
url_encode([{Key,Value}|R],Acc) ->
    url_encode(R, Acc ++ "&" ++ edoc_lib:escape_uri(Key) ++ "=" ++ edoc_lib:escape_uri(Value)).

Exemplo de utilização:

httpc:request(post, {"http://localhost:3000/foo", [], 
                    "application/x-www-form-urlencoded",
                    url_encode([{"username", "bob"}, {"password", "123456"}])}
             ,[],[]).

Answer 5

Para responder a minha pergunta ... Eu encontrei este lib em IBrowse!

http: //www.erlware .org / lib / 5.6.3 / IBrowse-1.4 / ibrowse_lib.html # url_encode-1

url_encode/1

url_encode(Str) -> UrlEncodedStr

Str = string()
UrlEncodedStr = string()

URL-codifica uma string com base no RFC 1738. retorna uma lista plana.

Eu acho que eu posso usar isso para fazer a codificação e ainda usar http:

Answer 6

Se uri alguém necessidade codificar que funciona com utf-8 em erlang:

https://gist.github.com/3796470

Ex.

Eshell V5.9.1  (abort with ^G)

1> c(encode_uri_rfc3986).
{ok,encode_uri_rfc3986}

2> encode_uri_rfc3986:encode("テスト").
"%e3%83%86%e3%82%b9%e3%83%88"

3> edoc_lib:escape_uri("テスト").
"%c3%86%c2%b9%c3%88" # output wrong: ƹÈ

Answer 7

Aqui está um "fork" do edoc_lib: função escape_uri que melhora com o apoio UTF-8 e também suporta binários.

escape_uri(S) when is_list(S) ->
    escape_uri(unicode:characters_to_binary(S));
escape_uri(<<C:8, Cs/binary>>) when C >= $a, C =< $z ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C >= $A, C =< $Z ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C >= $0, C =< $9 ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $. ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $- ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $_ ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) ->
    escape_byte(C) ++ escape_uri(Cs);
escape_uri(<<>>) ->
    "".

escape_byte(C) ->
    "%" ++ hex_octet(C).

hex_octet(N) when N =< 9 ->
    [$0 + N];
hex_octet(N) when N > 15 ->
    hex_octet(N bsr 4) ++ hex_octet(N band 15);
hex_octet(N) ->
    [N - 10 + $a].

Note-se que, por causa do uso de unicode:. Characters_to_binary ele vai funcionar apenas no R13 ou mais recente

Answer 8

AFAIK não há nenhum codificador URL nas bibliotecas padrão. Acho que eu 'emprestado' o seguinte código de bouba ou talvez um dos outros servidores web Erlang:

% Utility function to convert a 'form' of name-value pairs into a URL encoded
% content string.

urlencode(Form) ->
    RevPairs = lists:foldl(fun({K,V},Acc) -> [[quote_plus(K),$=,quote_plus(V)] | Acc] end, [],Form),
    lists:flatten(revjoin(RevPairs,$&,[])).

quote_plus(Atom) when is_atom(Atom) ->
    quote_plus(atom_to_list(Atom));

quote_plus(Int) when is_integer(Int) ->
    quote_plus(integer_to_list(Int));

quote_plus(String) ->
    quote_plus(String, []).

quote_plus([], Acc) ->
    lists:reverse(Acc);

quote_plus([C | Rest], Acc) when ?QS_SAFE(C) ->
    quote_plus(Rest, [C | Acc]);

quote_plus([$\s | Rest], Acc) ->
    quote_plus(Rest, [$+ | Acc]);

quote_plus([C | Rest], Acc) ->
    <<Hi:4, Lo:4>> = <<C>>,
    quote_plus(Rest, [hexdigit(Lo), hexdigit(Hi), ?PERCENT | Acc]).

revjoin([], _Separator, Acc) ->
    Acc;

revjoin([S | Rest],Separator,[]) ->
    revjoin(Rest,Separator,[S]);

revjoin([S | Rest],Separator,Acc) ->
    revjoin(Rest,Separator,[S,Separator | Acc]).

hexdigit(C) when C < 10 -> $0 + C;
hexdigit(C) when C < 16 -> $A + (C - 10).