HTTP ファイルのアップロードを処理するにはどうすればよいですか?
-
03-07-2019 - |
質問
HTTP ポスト経由でファイルを受信し、それをファイル システムに保存する Perl CGI スクリプトを作成するにはどうすればよいでしょうか?
解決
ちょっとしたメモ:どのように書いても、 しないでください Web サーバーからアクセスできる場所に保存します。
そしてここからが本題です:以下は、私が写真をアップロードするためにしばらく使用していたスクリプトです。多少の調整が必要かもしれませんが、方法は示されているはずです。
画像は Web アクセス可能なディレクトリにアップロードされていないため、別のプロセスで画像をチェックし、サイズ変更し、透かしを入れて、アクセスできる場所に配置します。
#!/usr/bin/perl -wT
use strict;
use CGI;
use CGI::Carp qw ( fatalsToBrowser );
use File::Basename;
$CGI::POST_MAX = 1024 * 5000;
my $safe_filename_characters = "a-zA-Z0-9_.-";
my $upload_dir = "/home/www/upload";
my $query = new CGI;
my $filename = $query->param("photo");
my $email_address = $query->param("email_address");
if ( !$filename )
{
print $query->header ( );
print "There was a problem uploading your photo (try a smaller file).";
exit;
}
my ( $name, $path, $extension ) = fileparse ( $filename, '\..*' );
$filename = $name . $extension;
$filename =~ tr/ /_/;
$filename =~ s/[^$safe_filename_characters]//g;
if ( $filename =~ /^([$safe_filename_characters]+)$/ )
{
$filename = $1;
}
else
{
die "Filename contains invalid characters";
}
my $upload_filehandle = $query->upload("photo");
open ( UPLOADFILE, ">$upload_dir/$filename" ) or die "$!";
binmode UPLOADFILE;
while ( <$upload_filehandle> )
{
print UPLOADFILE;
}
close UPLOADFILE;
print $query->header ( );
print <<END_HTML;
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>Thanks!</title>
</head>
<body>
<p>Thanks for uploading your photo!</p>
</body>
</html>
END_HTML
他のヒント
CGI を使用してファイルアップロードフィールドの作成、および開くでファイルを作成し、 print に書き込みます。 (そして閉じるで閉じます)。
所属していません StackOverflow