Como posso lidar com o upload de arquivos HTTP?

StackOverflow https://stackoverflow.com/questions/162677

  •  03-07-2019
  •  | 
  •  

Pergunta

Como eu iria escrever um script CGI Perl que recebe um arquivo através de um post HTTP e salva isso para o sistema de arquivos?

Foi útil?

Solução

Apenas uma nota:. Contudo, você vai escrevê-lo, não salvá-lo em um lugar acessível a partir de seu servidor web

E agora ao ponto: a seguir é um script que eu estava usando por algum tempo para a foto-upload. Ele pode precisar de alguns ajustes, mas deve mostrar o caminho.

Como o is not imagem enviada para o diretório web-acessível, então, temos processo separado verificando-lo, redimensionar, colocar uma marca d'água e colocá-lo onde ele pode ser acessado. 

 #!/usr/bin/perl -wT

use strict;
use CGI;
use CGI::Carp qw ( fatalsToBrowser );
use File::Basename;

$CGI::POST_MAX = 1024 * 5000;
my $safe_filename_characters = "a-zA-Z0-9_.-";
my $upload_dir = "/home/www/upload";

my $query = new CGI;
my $filename = $query->param("photo");
my $email_address = $query->param("email_address");

if ( !$filename )
{
 print $query->header ( );
 print "There was a problem uploading your photo (try a smaller file).";
 exit;
}

my ( $name, $path, $extension ) = fileparse ( $filename, '\..*' );
$filename = $name . $extension;
$filename =~ tr/ /_/;
$filename =~ s/[^$safe_filename_characters]//g;

if ( $filename =~ /^([$safe_filename_characters]+)$/ )
{
 $filename = $1;
}
else
{
 die "Filename contains invalid characters";
}

my $upload_filehandle = $query->upload("photo");

open ( UPLOADFILE, ">$upload_dir/$filename" ) or die "$!";
binmode UPLOADFILE;

while ( <$upload_filehandle> )
{
 print UPLOADFILE;
}

close UPLOADFILE;

print $query->header ( );
print <<END_HTML;
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 <head>
   <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
   <title>Thanks!</title>
 </head>
 <body>
   <p>Thanks for uploading your photo!</p>
 </body>
</html>
END_HTML

Outras dicas

Use a CGI módulo . 

my $fh = $query->upload('upload_field');
while(<$fh>) {
  print SAVE_FILE $_;
}

Eu começaria usando CGI e leitura de Criação de um arquivo UPLOAD CAMPO , e usando aberto para criar um arquivo e impressão para escrever a ele. (E então perto para fechá-la).

Licenciado em: CC-BY-SA com atribuição
Não afiliado a StackOverflow
scroll top